STM32啟動過程詳解，必須收藏

本章教程主要跟大家講STM32H7的啟動過程，這裡的啟動過程是指從CPU上電複位執行第1條指令開始（彙編檔案）到進入C程式main()函數入口之間的部分。

啟動過程相對來說還是比較重要的，了解了這個過程，對于以後分析程式還是有些幫助的，要不每次看到這個啟動過程都會跳過，直接去看主程式了。

還有就是以後打算學習RTOS的話，對于這個過程必須有個了解，因為移植的時候涉及到中斷向量表。

對初學者來說，看這個可能有些吃力，不過不要緊，随着自己做過一些簡單的應用之後再來看這章，應該會有很多的幫助，由于我們的V7闆子是基于STM32H7XXX，是以我們這裡主要針對H7系列的啟動過程做一下分析，對于F1，F4系列也是大緻相同的。

1 初學者重要提示

相比F1，F4的啟動方式，H7的啟動方式更靈活些，隻需一個boot引腳即可。但是一個引腳隻能區分出兩個狀态，為了解決這個問題，H7專門配套了兩個option bytes選項位元組來解決此問題。

2 各個版本的啟動檔案介紹

這裡各個版本的意思是指不同的編譯器、不同的H7系列對應的啟動檔案。

2.1 不同編譯器對應的啟動檔案

打開我們為本教程提供的工程檔案，路徑如下：

\Libraries\CMSIS\Device\ST\STM32H7xx\Source\Templates 在這個檔案裡面有ST官方為各個編譯器提供的啟動檔案。

看了上面的截圖，大家會問怎麼沒有KEIL MDK呢？其實已經被放在了檔案夾arm裡面，KEIL公司已經在2005年被ARM公司收購了。開發闆大部分例程都是配套了MDK和IAR兩個版本，這裡重點給大家分析一下MDK的啟動檔案分析，IAR和MDK的大同小異。

2.2 不同H7系列對應的啟動檔案

先來看一下ARM檔案夾裡面的檔案（2018-07-03，目前隻有如下兩個系列，後期ST會增加新的型号，相應的啟動檔案也會添加進來）：

如果是H743系列，就使用startup_stm32h743xx.s檔案，如果是H753系列，就使用startup_stm32h753xx檔案。目前H743和753系列對應的型号如下：

我們再來打開IAR檔案夾裡面的檔案：

多了一個linker檔案夾，用于IAR配置的ICF檔案：

而啟動檔案跟MDK裡面的一樣，一個是用H743系列，另一個是用于H753系列。

3 啟動檔案分析

鑒于V7開發闆使用的是STM32H743XI，下面我們詳細的分析一下啟動檔案startup_stm32h743xx.s。分析前，先掌握一個小技能，遇到不認識的指令或者關鍵詞可以檢索。

• 啟動 MDK軟體，在Help菜單點選 uVision Help

• 點選後彈出如下檔案

在搜尋欄輸入你需要查詢的單詞進行查詢，然後點選“列出主題”按鈕，會将相關的知識點都羅列出來。此功能非常實用，建議熟練掌握。

下面先來看啟動檔案前面的介紹 （固件庫版本：V1.2.0）

;******************** (C) COPYRIGHT 2017 STMicroelectronics ********************
;* File Name          : startup_stm32h743xx.s
;* @author  MCD Application Team
;* version            : V1.2.0
;* Date               : 29-December-2017
;* Description        : STM32H7xx devices vector table for MDK-ARM toolchain. 
;*                      This module performs:
;*                      - Set the initial SP
;*                      - Set the initial PC == Reset_Handler
;*                      - Set the vector table entries with the exceptions ISR address
;*                      - Branches to __main in the C library (which eventually
;*                        calls main()).
;*                      After Reset the Cortex-M processor is in Thread mode,
;*                      priority is Privileged, and the Stack is set to Main.
;* <<< Use Configuration Wizard in Context Menu >>>   
;*******************************************************************************
; 
; Licensed under MCD-ST Liberty SW License Agreement V2, (the "License");
; You may not use this file except in compliance with the License.
; You may obtain a copy of the License at:
; 
;        http://www.st.com/software_license_agreement_liberty_v2
; 
; Unless required by applicable law or agreed to in writing, software 
; distributed under the License is distributed on an "AS IS" BASIS, 
; WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
; See the License for the specific language governing permissions and
; limitations under the License.
; 
;*******************************************************************************           

啟動檔案是字尾為.s的彙編語言文本檔案，每行前面的分号表示此行是注釋行。

啟動檔案主要完成如下工作，即程式執行過程：

- 設定堆棧指針SP = __initial_sp。

- 設定PC指針 = Reset_Handler。

- 設定中斷向量表。

- 配置系統時鐘。

- 配置外部SRAM/SDRAM用于程式變量等資料存儲（這是可選的）。

- 跳轉到C庫中的 __main ，最終會調用使用者程式的main()函數。

Cortex-M核心處理器複位後，處于線程模式，指令權限是特權級别（最進階别），堆棧設定為使用主堆棧MSP。

3.1 複位序列

硬體複位之後，CPU 内的時序邏輯電路首先完成如下兩個工作（程式代碼下載下傳到内部flash為例，flash首位址0x0800 0000）

• 将0x08000000位置存放的堆棧棧頂位址存放到SP中(MSP)。
• 将0x08000004 位置存放的向量位址裝入 PC 程式計數器。

CPU 從 PC 寄存器指向的實體位址取出第 1 條指令開始執行程式，也就是開始執行複位中斷服務程式 Reset_Handler。

複位中斷服務程式會調用SystemInit()函數來配置系統時鐘、配置FMC總線上的外部SRAM/SDRAM，然後跳轉到C 庫中__main 函數。由C庫中的__main 函數完成使用者程式的初始化工作（比如：變量賦初值等），最後由__main 函數調用使用者寫的 main()函數開始執行 C 程式。

13.3.2 代碼分析

• 第1部分代碼分析

下面的代碼實作開辟棧(stack)空間，用于局部變量、函數調用、函數的參數等。

; Amount of memory (in bytes) allocated for Stack
; Tailor this value to your application needs
; <h> Stack Configuration
;   <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>
  
Stack_Size      EQU     0x00000400


                AREA    STACK, NOINIT, READWRITE, ALIGN=3
Stack_Mem       SPACE   Stack_Size
__initial_sp           

第7行：EQU 是表示宏定義的僞指令，類似于 C 語言中的#define。僞指令的意思是指這個“指令”并不會生成二進制程式代碼，也不會引起變量空間配置設定。

0x00000400 表示棧大小，注意這裡是以位元組為機關。

第9行：開辟一段資料空間可讀可寫，段名 STACK，按照 8 位元組對齊。ARER 僞指令表示下面将開始定義一個代碼段或者資料段。此處是定義資料段。ARER 後面的關鍵字表示這個段的屬性。

STACK ：表示這個段的名字，可以任意命名。

NOINIT：表示此資料段不需要填入初始資料。

READWRITE：表示此段可讀可寫。

ALIGN=3 ：表示首位址按照 2 的 3 次方對齊，也就是按照 8 位元組對齊(位址對8求餘數等于0)。

第10行：SPACE 這行指令告訴彙編器給 STACK 段配置設定 0x00000400 位元組的連續記憶體空間。

第11行： __initial_sp 緊接着 SPACE 語句放置，表示了棧頂位址。__initial_sp 隻是一個标号，标号主要用于表示一片記憶體空間的某個位置，等價于 C 語言中的“位址”概念。位址僅僅表示存儲空間的一個位置，從 C 語言的角度來看，變量的位址，數組的位址或是函數的入口位址在本質上并無差別。

• 第2部分代碼分析

下面的代碼實作開辟堆(heap)空間，主要用于動态記憶體配置設定，也就是說用 malloc，calloc, realloc等函數配置設定的變量空間是在堆上。

1.    ; <h> Heap Configuration
2.    ;   <o>  Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
3.    ; </h>
4.    
5.    Heap_Size       EQU     0x00000200
6.    
7.                    AREA    HEAP, NOINIT, READWRITE, ALIGN=3
8.    __heap_base
9.    Heap_Mem        SPACE   Heap_Size
10.    __heap_limit           

這幾行語句和上面第1部分代碼類似。配置設定一片連續的記憶體空間給名字叫 HEAP 的段，也就是配置設定堆空間。堆的大小為 0x00000200。

__heap_base 表示堆的開始位址。

__heap_limit 表示堆的結束位址。

• 第3部分代碼分析

1.                    PRESERVE8
2.                    THUMB
3.    
4.    
5.    ; Vector Table Mapped to Address 0 at Reset
6.                    AREA    RESET, DATA, READONLY
7.                    EXPORT  __Vectors
8.                    EXPORT  __Vectors_End
9.                    EXPORT  __Vectors_Size           

第1行：PRESERVE8 指定目前檔案保持堆棧八位元組對齊。

第2行：THUMB表示後面的指令是THUMB指令集 ，CM7采用的是THUMB - 2指令集。

第6行：AREA定義一塊代碼段，隻讀，段名字是 RESET。READONLY 表示隻讀，預設就表示代碼段了。

第7-9行：3 行EXPORT語句将 3 個标号申明為可被外部引用， 主要提供給連結器用于連接配接庫檔案或其他檔案。

• 第4部分代碼分析

1.    __Vectors       DCD     __initial_sp                      ; Top of Stack
2.                    DCD     Reset_Handler                     ; Reset Handler
3.                    DCD     NMI_Handler                       ; NMI Handler
4.                    DCD     HardFault_Handler                 ; Hard Fault Handler
5.                    
6.                    中間部分省略未寫
7.    
8.                    DCD     0                                 ; Reserved                                    
9.                    DCD     WAKEUP_PIN_IRQHandler             ; Interrupt for all 6 wake-up pins 
10.                    
11.    
12.    __Vectors_End
13.    
14.    __Vectors_Size  EQU  __Vectors_End - __Vectors           

上面的這段代碼是建立中斷向量表，中斷向量表定位在代碼段的最前面。具體的實體位址由連結器的配置參數（IROM1 的位址）決定。如果程式在 Flash 運作，則中斷向量表的起始位址是 0x08000000。

以MDK為例，就是如下配置選項：

DCD 表示配置設定 1 個 4 位元組的空間。每行 DCD 都會生成一個 4 位元組的二進制代碼。中斷向量表存放的實際上是中斷服務程式的入口位址。當異常（也即是中斷事件）發生時，CPU 的中斷系統會将相應的入口位址指派給 PC 程式計數器，之後就開始執行中斷服務程式。

• 第5部分代碼分析

1.                    AREA    |.text|, CODE, READONLY
2.    
3.    ; Reset handler
4.    Reset_Handler    PROC
5.                     EXPORT  Reset_Handler                    [WEAK]
6.            IMPORT  SystemInit
7.            IMPORT  __main
8.    
9.                     LDR     R0, =SystemInit
10.                     BLX     R0
11.                     LDR     R0, =__main
12.                     BX      R0
13.                     ENDP           

第1行：AREA 定義一塊代碼段，隻讀，段名字是 .text 。READONLY 表示隻讀。

第4行：利用 PROC、ENDP 這一對僞指令把程式段分為若幹個過程，使程式的結構加清晰。

嵌入式物聯網需要學的東西真的非常多，千萬不要學錯了路線和内容，導緻工資要不上去！

無償分享大家一個資料包，差不多150多G。裡面學習内容、面經、項目都比較新也比較全！某魚上買估計至少要好幾十。

長按連結搜尋 https://s.pdb2.com/l/CMIsoKcnATFIF4M

第5行：WEAK 聲明其他的同名标号優先于該标号被引用,就是說如果外面聲明了的話會調用外面的。 這個聲明很重要，它讓我們可以在C檔案中任意地方放置中斷服務程式，隻要保證C函數的名字和向量表中的名字一緻即可。

第6行：IMPORT：僞指令用于通知編譯器要使用的标号在其他的源檔案中定義。但要在目前源檔案中引用，而且無論目前源檔案是否引用該标号，該标号均會被加入到目前源檔案的符号表中。

第9行：SystemInit 函數在檔案system_stm32h7xx.c 裡面，主要實作RCC相關寄存器複位和中斷向量表位置設定。

第11行：__main 标号表示C/C++标準實時庫函數裡的一個初始化子程式__main 的入口位址。該程式的一個主要作用是初始化堆棧(跳轉__user_initial_stackheap 标号進行初始化堆棧的，下面會講到這個标号)，并初始化映像檔案，最後跳轉到 C 程式中的 main函數。這就解釋了為何所有的 C 程式必須有一個 main 函數作為程式的起點。因為這是由 C/C++标準實時庫所規，并且不能更改。

• 第6部分代碼分析

代碼如下：

1.    ; Dummy Exception Handlers (infinite loops which can be modified)
2.    
3.    NMI_Handler     PROC
4.                    EXPORT  NMI_Handler                      [WEAK]
5.                    B       .  
6.                    ENDP
7.    HardFault_Handler\
8.                    PROC
9.                    EXPORT  HardFault_Handler                [WEAK]
10.                    B       .
11.                    ENDP
12.    
13.                    中間部分省略未寫
14.    Default_Handler PROC                                      
15.    
16.                    EXPORT  WWDG_IRQHandler                   [WEAK]                                       
17.                    EXPORT  PVD_AVD_IRQHandler                [WEAK]                         
18.                    EXPORT  TAMP_STAMP_IRQHandler             [WEAK]
19.                    中間部分省略未寫
20.    SAI4_IRQHandler      
21.    WAKEUP_PIN_IRQHandler
22.    
23.                    B       .
24.    
25.                    ENDP
26.    
27.                    ALIGN           

第5行：死循環，使用者可以在此實作自己的中斷服務程式。不過很少在這裡實作中斷服務程式，一般多是在其它的C檔案裡面重新寫一個同樣名字的中斷服務程式，因為這裡是WEEK弱定義的。如果沒有在其它檔案中寫中斷伺服器程式，且使能了此中斷，進入到這裡後，會讓程式卡在這個地方。

第14行：預設中斷服務程式（開始）

第23行：死循環，如果使用者使能中斷服務程式，而沒有在C檔案裡面寫中斷服務程式的話，都會進入到這裡。比如在程式裡面使能了序列槽1中斷，而沒有寫中斷服務程式USART1_IRQHandle，那麼序列槽中斷來了，會進入到這個死循環。

第25行：預設中斷服務程式（結束）。

• 第7部分代碼分析

啟動代碼的最後一部分：

1.    ;*******************************************************************************
2.    ; User Stack and Heap initialization
3.    ;*******************************************************************************
4.                     IF      :DEF:__MICROLIB
5.                    
6.                     EXPORT  __initial_sp
7.                     EXPORT  __heap_base
8.                     EXPORT  __heap_limit
9.                    
10.                     ELSE
11.                    
12.                     IMPORT  __use_two_region_memory
13.                     EXPORT  __user_initial_stackheap
14.                     
15.    __user_initial_stackheap
16.    
17.                     LDR     R0, =  Heap_Mem
18.                     LDR     R1, =(Stack_Mem + Stack_Size)
19.                     LDR     R2, = (Heap_Mem +  Heap_Size)
20.                     LDR     R3, = Stack_Mem
21.                     BX      LR
22.    
23.                     ALIGN
24.    
25.                     ENDIF
26.    
27.                     END           

第4行：簡單的彙編語言實作IF…….ELSE…………語句。如果定義了MICROLIB，那麼程式是不會執行ELSE分支的代碼。__MICROLIB可能大家并不陌生，就在MDK的Target Option裡面設定。

第5行：__user_initial_stackheap将由__main函數進行調用。

• MicroLib

MicroLib是MDK裡面帶的微庫，針對嵌入式應用，MicroLIB做了深度優化，比使用C标準庫所需的RAM和FLASH空間都大大減小比如調用：

<math.h>，<stdlib.h>，<stdio.h>，<string.h>

更多相關知識可以位址：http://www.keil.com/arm/microlib.asp。另外注意microlib隻有庫，沒有源檔案。下圖是标準庫和微庫生成代碼的比較。

4 BOOT啟動模式

相比F1，F4的啟動方式，H7的啟動方式更靈活些，隻需一個boot引腳即可。但是一個引腳隻能區分出兩個狀态，為了解決這個問題，H7專門配套了兩個option bytes選項位元組配置，如此以來就可以友善設定各種存儲器位址了。

BOOT_ADD0和BOOT_ADD1對應32位位址到高16位，這點要特别注意。通過這兩個選項位元組，所有0x0000 0000到0x3FFF 0000的存儲器位址都可以設定，包括：

• 所有Flash位址空間。
• 所有RAM位址空間，ITCM，DTCM和SRAM。

設定了選項位元組後，掉電不會丢失，下次上電或者複位後，會根據BOOT引腳狀态從BOOT_ADD0，或BOOT_ADD1所設定的位址進行啟動。

使用BOOT功能，注意以下幾個問題：

• 如果使用者不慎，設定的位址範圍不在有效的存儲器位址，那麼BOOT = 0時，會從Flash首位址0x0800 0000啟動，BOOT = 1時，會從ITCM首位址0x0000 0000啟動。
• 如果使用者使能了Flash Level 2保護，那麼隻能從Flash位址空間進行啟動。

• F1,F4的啟動方式

作為對比，這裡補充F1，F4的啟動方式，由BOOT0和BOOT1引腳共同決定。

5 總結

本章節講解的啟動過程分析還是比較重要的，忘初學者務必掌握。

文章連結：https://mp.weixin.qq.com/s/HXEwnAlx6wGrQ8F7BIe2eg

轉載自：李肖遙 技術讓夢想更偉大

文章來源：STM32啟動過程詳解，必須收藏

文章連結：https://www.cnblogs.com/armfly/p/10678069.html

版權聲明：本文來源網絡，免費傳達知識，版權歸原作者所有。如涉及作品版權問題，請聯系我進行删除。

‧‧‧‧‧‧‧‧‧‧‧‧‧‧‧‧ END ‧‧‧‧‧‧‧‧‧‧‧‧‧‧