将陸續上傳本人寫的新書《自己動手寫CPU》，今天是第26篇，我盡量每周四篇
China-pub的預售位址如下（有目錄、内容簡介、前言）：
http://product.china-pub.com/3804025
亞馬遜的預售位址如下，歡迎大家圍觀呵！
http://www.amazon.cn/dp/b00mqkrlg8/ref=cm_sw_r_si_dp_5kq8tb1gyhja4
為了實作簡單算術指令，需要修改譯碼階段的ID子產品、執行階段的EX子產品，上一篇博文中已經介紹了對譯碼階段ID子產品的修改過程，本文繼續介紹執行階段EX子產品的修改過程。
7.3.2 修改執行階段的EX子產品
譯碼階段的結果會傳遞到執行階段，執行階段的EX子產品會據此進行運算，是以需要修改執行階段EX子產品的代碼，主要修改内容如下，完整代碼可以參考本書附帶CD光牒Code\Chapter7_1目錄下的ex.v檔案。
module ex(
......
);
reg[`RegBus] logicout;
reg[`RegBus] shiftres;
reg[`RegBus] moveres;
reg[`RegBus] HI;
reg[`RegBus] LO;
// 新定義了一些變量
wire ov_sum; // 儲存溢出情況
wire reg1_eq_reg2; // 第一個操作數是否等于第二個操作數
wire reg1_lt_reg2; // 第一個操作數是否小于第二個操作數
reg[`RegBus] arithmeticres; // 儲存算術運算的結果
wire[`RegBus] reg2_i_mux; // 儲存輸入的第二個操作數reg2_i的補碼
wire[`RegBus] reg1_i_not; // 儲存輸入的第一個操作數reg1_i取反後的值
wire[`RegBus] result_sum; // 儲存加法結果
wire[`RegBus] opdata1_mult; // 乘法操作中的被乘數
wire[`RegBus] opdata2_mult; // 乘法操作中的乘數
wire[`DoubleRegBus] hilo_temp; // 臨時儲存乘法結果，寬度為64位
reg[`DoubleRegBus] mulres; // 儲存乘法結果，寬度為64位
......
/****************************************************************
*********** 第一段：計算以下5個變量的值 *********
*****************************************************************/
//（1）如果是減法或者有符号比較運算，那麼reg2_i_mux等于第二個操作數
// reg2_i的補碼，否則reg2_i_mux就等于第二個操作數reg2_i
assign reg2_i_mux = ((aluop_i == `EXE_SUB_OP) ||
(aluop_i == `EXE_SUBU_OP) ||
(aluop_i == `EXE_SLT_OP)) ?
(~reg2_i)+1 : reg2_i;
//（2）分三種情況：
// A、如果是加法運算，此時reg2_i_mux就是第二個操作數reg2_i，
// 是以result_sum就是加法運算的結果
// B、如果是減法運算，此時reg2_i_mux是第二個操作數reg2_i的補碼，
// 是以result_sum就是減法運算的結果
// C、如果是有符号比較運算，此時reg2_i_mux也是第二個操作數reg2_i
// 的補碼，是以result_sum也是減法運算的結果，可以通過判斷減法
// 的結果是否小于零，進而判斷第一個操作數reg1_i是否小于第二個操
// 作數reg2_i
assign result_sum = reg1_i + reg2_i_mux;
//（3）計算是否溢出，加法指令add、addi、減法指令sub執行的時候，
// 需要判斷是否溢出，滿足以下兩種情況之一時，有溢出：
// A、reg1_i為正數，reg2_i_mux為正數，但是兩者之和為負數
// B、reg1_i為負數，reg2_i_mux為負數，但是兩者之和為正數
assign ov_sum = ((!reg1_i[31] && !reg2_i_mux[31]) && result_sum[31])
||((reg1_i[31] && reg2_i_mux[31]) && (!result_sum[31]));
//（4）計算操作數1是否小于操作數2，分兩種情況：
// A、aluop_i為EXE_SLT_OP表示有符号比較運算，此時又分3種情況
// A1、reg1_i為負數、reg2_i為正數，顯然reg1_i小于reg2_i
// A2、reg1_i為正數、reg2_i為正數，并且reg1_i減去reg2_i的值小于0
// （即result_sum為負），此時也有reg1_i小于reg2_i
// A3、reg1_i為負數、reg2_i為負數，并且reg1_i減去reg2_i的值小于0
// （即result_sum為負），此時也有reg1_i小于reg2_i
// B、無符号數比較的時候，直接使用比較運算符比較reg1_i與reg2_i
assign reg1_lt_reg2 = ((aluop_i == `EXE_SLT_OP))?
((reg1_i[31] && !reg2_i[31]) ||
(!reg1_i[31] && !reg2_i[31] && result_sum[31])||
(reg1_i[31] && reg2_i[31] && result_sum[31]))
:(reg1_i < reg2_i);
//（5）對操作數1逐位取反，賦給reg1_i_not
assign reg1_i_not = ~reg1_i;
/****************************************************************
**** 第二段：依據不同的算術運算類型，給arithmeticres變量指派 ****
*****************************************************************/
always @ (*) begin
if(rst == `RstEnable) begin
arithmeticres <= `ZeroWord;
end else begin
case (aluop_i) // aluop_i就是運算類型
`EXE_SLT_OP, `EXE_SLTU_OP: begin
arithmeticres <= reg1_lt_reg2 ; // 比較運算
end
`EXE_ADD_OP, `EXE_ADDU_OP, `EXE_ADDI_OP, `EXE_ADDIU_OP:
begin
arithmeticres <= result_sum; // 加法運算
end
`EXE_SUB_OP, `EXE_SUBU_OP: begin
arithmeticres <= result_sum; // 減法運算
end
`EXE_CLZ_OP: begin // 計數運算clz
arithmeticres <= reg1_i[31] ? 0 : reg1_i[30] ? 1 :
reg1_i[29] ? 2 : reg1_i[28] ? 3 :
reg1_i[27] ? 4 : reg1_i[26] ? 5 :
reg1_i[25] ? 6 : reg1_i[24] ? 7 :
reg1_i[23] ? 8 : reg1_i[22] ? 9 :
reg1_i[21] ? 10 : reg1_i[20] ? 11 :
reg1_i[19] ? 12 : reg1_i[18] ? 13 :
reg1_i[17] ? 14 : reg1_i[16] ? 15 :
reg1_i[15] ? 16 : reg1_i[14] ? 17 :
reg1_i[13] ? 18 : reg1_i[12] ? 19 :
reg1_i[11] ? 20 : reg1_i[10] ? 21 :
reg1_i[9] ? 22 : reg1_i[8] ? 23 :
reg1_i[7] ? 24 : reg1_i[6] ? 25 :
reg1_i[5] ? 26 : reg1_i[4] ? 27 :
reg1_i[3] ? 28 : reg1_i[2] ? 29 :
reg1_i[1] ? 30 : reg1_i[0] ? 31 : 32 ;
end
`EXE_CLO_OP: begin // 計數運算clo
arithmeticres <= (reg1_i_not[31] ? 0 :
reg1_i_not[29] ? 2 :
reg1_i_not[28] ? 3 :
reg1_i_not[27] ? 4 :
reg1_i_not[26] ? 5 :
reg1_i_not[25] ? 6 :
reg1_i_not[24] ? 7 :
reg1_i_not[23] ? 8 :
reg1_i_not[22] ? 9 :
reg1_i_not[21] ? 10 :
reg1_i_not[20] ? 11 :
reg1_i_not[19] ? 12 :
reg1_i_not[18] ? 13 :
reg1_i_not[17] ? 14 :
reg1_i_not[16] ? 15 :
reg1_i_not[15] ? 16 :
reg1_i_not[14] ? 17 :
reg1_i_not[13] ? 18 :
reg1_i_not[12] ? 19 :
reg1_i_not[11] ? 20 :
reg1_i_not[10] ? 21 :
reg1_i_not[9] ? 22 :
reg1_i_not[8] ? 23 :
reg1_i_not[7] ? 24 :
reg1_i_not[6] ? 25 :
reg1_i_not[5] ? 26 :
reg1_i_not[4] ? 27 :
reg1_i_not[3] ? 28 :
reg1_i_not[2] ? 29 :
reg1_i_not[1] ? 30 :
reg1_i_not[0] ? 31 : 32) ;
end
default: begin
arithmeticres <= `ZeroWord;
end
endcase
end
end
/****************************************************************
************ 第三段：進行乘法運算 *************
*****************************************************************/
//（1）取得乘法運算的被乘數，如果是有符号乘法且被乘數是負數，那麼取補碼
assign opdata1_mult=(((aluop_i==`EXE_MUL_OP)||(aluop_i==`EXE_MULT_OP))
&& (reg1_i[31] == 1'b1)) ? (~reg1_i + 1) : reg1_i;
//（2）取得乘法運算的乘數，如果是有符号乘法且乘數是負數，那麼取補碼
assign opdata2_mult=(((aluop_i==`EXE_MUL_OP)||(aluop_i==`EXE_MULT_OP))
&& (reg2_i[31] == 1'b1)) ? (~reg2_i + 1) : reg2_i;
//（3）得到臨時乘法結果，儲存在變量hilo_temp中
assign hilo_temp = opdata1_mult * opdata2_mult;
//（4）對臨時乘法結果進行修正，最終的乘法結果儲存在變量mulres中，主要有兩點：
// A、如果是有符号乘法指令mult、mul，那麼需要修正臨時乘法結果，如下：
// A1、如果被乘數與乘數，兩者一正一負，那麼需要對臨時乘法結果
// hilo_temp求補碼，作為最終的乘法結果，賦給變量mulres。
// A2、如果被乘數與乘數同号，那麼hilo_temp的值就作為最終的
// 乘法結果，賦給變量mulres。
// B、如果是無符号乘法指令multu，那麼hilo_temp的值就作為最終的乘法結果,
// 賦給變量mulres。
always @ (*) begin
if(rst == `RstEnable) begin
mulres <= {`ZeroWord,`ZeroWord};
end else if ((aluop_i == `EXE_MULT_OP)||(aluop_i == `EXE_MUL_OP))
begin
if(reg1_i[31] ^ reg2_i[31] == 1'b1) begin
mulres <= ~hilo_temp + 1;
end else begin
mulres <= hilo_temp;
end
end else begin
mulres <= hilo_temp;
end
end
/****************************************************************
*********** 第四段：确定要寫入目的寄存器的資料 ************
*****************************************************************/
always @ (*) begin
wd_o <= wd_i;
// 如果是add、addi、sub、subi指令，且發生溢出，那麼設定wreg_o為
// WriteDisable，表示不寫目的寄存器
if(((aluop_i == `EXE_ADD_OP) || (aluop_i == `EXE_ADDI_OP) ||
(aluop_i == `EXE_SUB_OP)) && (ov_sum == 1'b1)) begin
wreg_o <= `WriteDisable;
end else begin
wreg_o <= wreg_i;
end
case ( alusel_i )
`EXE_RES_LOGIC: begin
wdata_o <= logicout;
end
`EXE_RES_SHIFT: begin
wdata_o <= shiftres;
end
`EXE_RES_MOVE: begin
wdata_o <= moveres;
end
`EXE_RES_ARITHMETIC: begin //除乘法外的簡單算術操作指令
wdata_o <= arithmeticres;
end
`EXE_RES_MUL: begin //乘法指令mul
wdata_o <= mulres[31:0];
end
default: begin
wdata_o <= `ZeroWord;
end
endcase
end
/****************************************************************
*********** 第五段：确定對HI、LO寄存器的操作資訊 ************
*****************************************************************/
always @ (*) begin
if(rst == `RstEnable) begin
whilo_o <= `WriteDisable;
hi_o <= `ZeroWord;
lo_o <= `ZeroWord;
end else if((aluop_i == `EXE_MULT_OP) ||
(aluop_i == `EXE_MULTU_OP)) begin //mult、multu指令
whilo_o <= `WriteEnable;
hi_o <= mulres[63:32];
lo_o <= mulres[31:0];
end else if(aluop_i == `EXE_MTHI_OP) begin
whilo_o <= `WriteEnable;
hi_o <= reg1_i;
lo_o <= LO;
end else if(aluop_i == `EXE_MTLO_OP) begin
whilo_o <= `WriteEnable;
hi_o <= HI;
lo_o <= reg1_i;
end else begin
whilo_o <= `WriteDisable;
hi_o <= `ZeroWord;
lo_o <= `ZeroWord;
end
end
endmodule
上面的代碼可以分為五段，大部分代碼的含義都在注釋中給出了詳細解釋，以下隻做簡要補充。
（1）第一段代碼計算出如下幾個變量的值。
- reg2_i_mux：如果是減法或者有符号比較運算，那麼reg2_i_mux等于第二個操作數reg2_i的補碼，否則reg2_i_mux就等于第二個操作數reg2_i。
- result_sum：加、減法的結果。
- ov_sum：訓示加、減法是否溢出。
- reg1_lt_reg2：操作數1是否小于操作數2。
- reg1_i_not：操作數1各位取反後的值。
（2）第二段代碼依據不同的算術運算類型，給變量arithmeticres指派，此處隻解釋clz、clo指令的運算過程，其餘指令的運算過程請參考程式注釋。
- clz指令的作用是從最高位開始計數，直到遇到第一個1，是以在實作的時候就從最高位開始依次判斷是否為1，如果為1，就給出目前已經數過的位數，如果沒有為1的位，那麼輸出32。
- clo指令的作用是從最高位開始計數，直到遇到第一個0，效果等同于先将操作數取反，然後從最高位開始計數，直到遇到第一個1，是以在實作的時候就先對操作數取反，然後從最高位開始依次判斷是否為1，如果為1，就給出目前已經數過的位數，如果沒有為1的位，那麼輸出32。
（3）第三段代碼進行乘法運算。對于有符号乘法，要先求補碼，再相乘，最後進行乘法結果的修正。乘法結果儲存在變量mulres中。
（4）第四段代碼确定要寫目的寄存器的情況，有以下兩點說明。
- 如果是add、addi、sub、subi指令，且發生溢出，那麼設定wreg_o為WriteDisable，這樣就不會寫目的寄存器。
- 如果是乘法指令以外的簡單算術操作指令，那麼将arithmeticres作為要寫入目的寄存器的值。
- 如果是乘法指令mul，那麼将乘法結果的低32位作為要寫入目的寄存器的值。
（5）第五段代碼确定對HI、LO寄存器的寫資訊。如果是乘法指令mult、multu，那麼需要寫HI、LO寄存器，是以設定whilo_o為WriteEnable，寫入HI寄存器的值為乘法結果的高32位，寫入LO寄存器的值為乘法結果的低32位。
下一步将驗證簡單算術指令的實作效果，敬請關注！
![Jericho Html Parser初探[圖]](data:image/gif;base64,R0lGODlhAQABAIAAAP///wAAACwAAAAAAQABAAACAkQBADs=)