前言

提起弱引用，大家都知道它的作用：

（1）不会添加引用计数（2）当所引用的对象释放后，引用者的指针自动置为nil

那么，围绕它背后的实现，是怎么样的呢？在许多公司面试时，都会问到这个问题。那么，今天就带大家一起分析一下weak引用是怎么实现的，希望能够搞清楚每一个细节。

Store as weak

当我们要weak引用一个对象，我们可以这么做：

int main(int argc, char * argv[]) {
    @autoreleasepool {
        NSObject *obj = [[NSObject alloc] init];
        __weak NSObject *weakObj = obj;
    }
}

创建了一个NSObject对象

obj

，然后用

weakObj

对obj做弱引用。

当我们对一个对象做weak引用的时候，其背后是通过

runtime

来支持的。当把一个对象做weak引用时，会调用runtime方法

objc_initWeak

：

objc_initWeak

id objc_initWeak(id *location, id newObj)
{
    if (!newObj) {
        *location = nil;
        return nil;
    }

    return storeWeak<DontHaveOld, DoHaveNew, DoCrashIfDeallocating>
        (location, (objc_object*)newObj);
}

该方法接受两个参数：

id *location ：__weak指针的地址，即例子中的weak指针取地址： &weakObj 。它是一个指针的地址。之所以要存储指针的地址，是因为最后我们要讲__weak指针指向的内容置为 nil ，如果仅存储指针的话，是不能够完成这个功能的。
id newObj ：所引用的对象。即例子中的 obj 。

有一个返回值

id

：会返回obj自身，但其值已经做了更改（isa_t中的weak_ref位置1），参见Objective-C runtime机制(5)——iOS 内存管理

objc_initWeak

实质是调用了

storeWeak

方法。看这个方法的名字，就可以猜到是将weak引用存到某个地方，没错，实际上苹果就是这么做的。

storeWeak

storeWeak

方法有点长，这也是weak引用的核心实现部分。其实核心也就实现了两个功能：

将weak指针的地址location存入到obj对应的 weak_entry_t 的数组（链表）中，用于在obj析构时，通过该数组（链表）找到所有其weak指针引用，并将指针指向的地址（location）置为 nil 。关于 weak_entry_t ，在上一篇中已有介绍。
如果启用了isa优化，则将obj的 isa_t 的 weakly_referenced 位置1。置位1的作用主要是为了标记obj被weak引用了，当dealloc时，runtime会根据 weakly_referenced 标志位来判断是否需要查找obj对应的 weak_entry_t ，并将引用置为 nil 。

// Template parameters.
enum HaveOld { DontHaveOld = false, DoHaveOld = true };
enum HaveNew { DontHaveNew = false, DoHaveNew = true };
enum CrashIfDeallocating {
    DontCrashIfDeallocating = false, DoCrashIfDeallocating = true
};

template <HaveOld haveOld, HaveNew haveNew,
          CrashIfDeallocating crashIfDeallocating>
static id 
storeWeak(id *location, objc_object *newObj)
{
    assert(haveOld  ||  haveNew);
    if (!haveNew) assert(newObj == nil);

    Class previouslyInitializedClass = nil;
    id oldObj;
    SideTable *oldTable;
    SideTable *newTable;

    // Acquire locks for old and new values.
    // Order by lock address to prevent lock ordering problems. 
    // Retry if the old value changes underneath us.
 retry:
    if (haveOld) { // 如果weak ptr之前弱引用过一个obj，则将这个obj所对应的SideTable取出，赋值给oldTable
        oldObj = *location;
        oldTable = &SideTables()[oldObj];
    } else {
        oldTable = nil; // 如果weak ptr之前没有弱引用过一个obj，则oldTable = nil
    }
    if (haveNew) { // 如果weak ptr要weak引用一个新的obj，则将该obj对应的SideTable取出，赋值给newTable
        newTable = &SideTables()[newObj];
    } else {
        newTable = nil; // 如果weak ptr不需要引用一个新obj，则newTable = nil
    }
    
    // 加锁操作，防止多线程中竞争冲突
    SideTable::lockTwo<haveOld, haveNew>(oldTable, newTable);

    // location 应该与 oldObj 保持一致，如果不同，说明当前的 location 已经处理过 oldObj 可是又被其他线程所修改
    if (haveOld  &&  *location != oldObj) {
        SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
        goto retry;
    }

    // Prevent a deadlock between the weak reference machinery
    // and the +initialize machinery by ensuring that no 
    // weakly-referenced object has an un-+initialized isa.
    if (haveNew  &&  newObj) {
        Class cls = newObj->getIsa();
        if (cls != previouslyInitializedClass  &&  
            !((objc_class *)cls)->isInitialized())  // 如果cls还没有初始化，先初始化，再尝试设置weak
        {
            SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);
            _class_initialize(_class_getNonMetaClass(cls, (id)newObj));

            // If this class is finished with +initialize then we're good.
            // If this class is still running +initialize on this thread 
            // (i.e. +initialize called storeWeak on an instance of itself)
            // then we may proceed but it will appear initializing and 
            // not yet initialized to the check above.
            // Instead set previouslyInitializedClass to recognize it on retry.
            previouslyInitializedClass = cls; // 这里记录一下previouslyInitializedClass， 防止改if分支再次进入

            goto retry; // 重新获取一遍newObj，这时的newObj应该已经初始化过了
        }
    }

    // Clean up old value, if any.
    if (haveOld) {
        weak_unregister_no_lock(&oldTable->weak_table, oldObj, location); // 如果weak_ptr之前弱引用过别的对象oldObj，则调用weak_unregister_no_lock，在oldObj的weak_entry_t中移除该weak_ptr地址
    }

    // Assign new value, if any.
    if (haveNew) { // 如果weak_ptr需要弱引用新的对象newObj
        // (1) 调用weak_register_no_lock方法，将weak ptr的地址记录到newObj对应的weak_entry_t中
        newObj = (objc_object *)
            weak_register_no_lock(&newTable->weak_table, (id)newObj, location, 
                                  crashIfDeallocating);
        // weak_register_no_lock returns nil if weak store should be rejected
        
        // (2) 更新newObj的isa的weakly_referenced bit标志位
        // Set is-weakly-referenced bit in refcount table.
        if (newObj  &&  !newObj->isTaggedPointer()) {
            newObj->setWeaklyReferenced_nolock();
        }

        // Do not set *location anywhere else. That would introduce a race.
        // （3）*location 赋值，也就是将weak ptr直接指向了newObj。可以看到，这里并没有将newObj的引用计数+1
        *location = (id)newObj; // 将weak ptr指向object
    }
    else {
        // No new value. The storage is not changed.
    }
    
    // 解锁，其他线程可以访问oldTable, newTable了
    SideTable::unlockTwo<haveOld, haveNew>(oldTable, newTable);

    return (id)newObj; // 返回newObj，此时的newObj与刚传入时相比，weakly-referenced bit位置1
}

下面我们就一起来分析下

storeWeak

方法。

storeWeak

方法实质上接受5个参数，其中

HaveOld haveOld, HaveNew haveNew, CrashIfDeallocating crashIfDeallocating

这三个参数是以模板枚举的方式传入的，其实这是三个bool参数，分别表示：weak ptr之前是否已经指向了一个弱引用，weak ptr是否需要指向一个新引用，如果被弱引用的对象正在析构，此时再弱引用该对象，是否应该crash。

具体到

objc_initWeak

，这三个参数的值分别为

false

，

true

，

true

。

storeWeak

另外两个参数是

id *location

objc_object *newObj

，这两个参数和

objc_initWeak

是一样的，分别代表weak 指针的地址，以及被weak引用的对象。

接下来函数体里的内容，大家可以结合注释，应该能够看个明白。

这里涉及到两个关键的函数：

weak_unregister_no_lock  // 将 weak ptr地址 从obj的weak_entry_t中移除
weak_register_no_lock   // 将 weak ptr地址 注册到obj对应的weak_entry_t中

这里我们先看注册函数：

weak_register_no_lock

id 
weak_register_no_lock(weak_table_t *weak_table, id referent_id, 
                      id *referrer_id, bool crashIfDeallocating)
{
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;

    // 如果referent为nil 或 referent 采用了TaggedPointer计数方式，直接返回，不做任何操作
    if (!referent  ||  referent->isTaggedPointer()) return referent_id;

    // 确保被引用的对象可用（没有在析构，同时应该支持weak引用）
    bool deallocating;
    if (!referent->ISA()->hasCustomRR()) {
        deallocating = referent->rootIsDeallocating();
    }
    else {
        BOOL (*allowsWeakReference)(objc_object *, SEL) = 
            (BOOL(*)(objc_object *, SEL))
            object_getMethodImplementation((id)referent, 
                                           SEL_allowsWeakReference);
        if ((IMP)allowsWeakReference == _objc_msgForward) {
            return nil;
        }
        deallocating =
            ! (*allowsWeakReference)(referent, SEL_allowsWeakReference);
    }
    // 正在析构的对象，不能够被弱引用
    if (deallocating) {
        if (crashIfDeallocating) {
            _objc_fatal("Cannot form weak reference to instance (%p) of "
                        "class %s. It is possible that this object was "
                        "over-released, or is in the process of deallocation.",
                        (void*)referent, object_getClassName((id)referent));
        } else {
            return nil;
        }
    }

    // now remember it and where it is being stored
    // 在 weak_table中找到referent对应的weak_entry,并将referrer加入到weak_entry中
    weak_entry_t *entry;
    if ((entry = weak_entry_for_referent(weak_table, referent))) { // 如果能找到weak_entry,则讲referrer插入到weak_entry中
        append_referrer(entry, referrer); 	// 将referrer插入到weak_entry_t的引用数组中
    } 
    else { // 如果找不到，就新建一个
        weak_entry_t new_entry(referent, referrer);  
        weak_grow_maybe(weak_table);
        weak_entry_insert(weak_table, &new_entry);
    }

    // Do not set *referrer. objc_storeWeak() requires that the 
    // value not change.

    return referent_id;
}

注意看开头的地方：

// 如果referent为nil 或 referent 采用了TaggedPointer计数方式，直接返回，不做任何操作
    if (!referent  ||  referent->isTaggedPointer()) return referent_id;

这里再次出现了taggedPointer的身影，若引用计数使用了taggedPointer，则不会做任何引用计数。

接着，会判断

referent_id

是否能够被weak 引用。这里主要判断

referent_id

是否正在被析构以及

referent_id

是否支持weak引用。如果

referent_id

不能够被weak引用，则直接返回nil。

接下来，如果

referent_id

能够被weak引用，则将

referent_id

对应的

weak_entry_t

从

weak_table

的weak_entry_t哈希数组中找出来,并将若

entry = weak_entry_for_referent(weak_table, referent)

如果

entry

不存在，则会新建一个

referent_id

所对应的

weak_entry_t

：

else { // 如果找不到，就新建一个
        weak_entry_t new_entry(referent, referrer);  // 创建一个新的weak_entry_t ，并将referrer插入到weak_entry_t的引用数组中
        weak_grow_maybe(weak_table);  // weak_table的weak_entry_t 数组是否需要动态增长，若需要，则会扩容一倍
        weak_entry_insert(weak_table, &new_entry); // 将weak_entry_t插入到weak_table中
    }

将referrer插入到对应的weak_entry_t的引用数组后，我们的weak工作基本也就结束了。

最后，只需要返回被引用的对象即可：

return referent_id;

关于referrer是如何插入到weak_entry_t中的，其hash算法是怎么样的，利用函数

append_referrer

static void append_referrer(weak_entry_t *entry, objc_object **new_referrer)
{
    if (! entry->out_of_line()) { // 如果weak_entry 尚未使用动态数组，走这里
        // Try to insert inline.
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            if (entry->inline_referrers[i] == nil) {
                entry->inline_referrers[i] = new_referrer;
                return;
            }
        }
        
        // 如果inline_referrers的位置已经存满了，则要转型为referrers，做动态数组。
        // Couldn't insert inline. Allocate out of line.
        weak_referrer_t *new_referrers = (weak_referrer_t *)
            calloc(WEAK_INLINE_COUNT, sizeof(weak_referrer_t));
        // This constructed table is invalid, but grow_refs_and_insert
        // will fix it and rehash it.
        for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
            new_referrers[i] = entry->inline_referrers[i];
        }
        entry->referrers = new_referrers;
        entry->num_refs = WEAK_INLINE_COUNT;
        entry->out_of_line_ness = REFERRERS_OUT_OF_LINE;
        entry->mask = WEAK_INLINE_COUNT-1;
        entry->max_hash_displacement = 0;
    }

    // 对于动态数组的附加处理：
    assert(entry->out_of_line()); // 断言： 此时一定使用的动态数组

    if (entry->num_refs >= TABLE_SIZE(entry) * 3/4) { // 如果动态数组中元素个数大于或等于数组位置总空间的3/4，则扩展数组空间为当前长度的一倍
        return grow_refs_and_insert(entry, new_referrer); // 扩容，并插入
    }
    
    // 如果不需要扩容，直接插入到weak_entry中
    // 注意，weak_entry是一个哈希表，key：w_hash_pointer(new_referrer) value: new_referrer
    
    // 细心的人可能注意到了，这里weak_entry_t 的hash算法和 weak_table_t的hash算法是一样的，同时扩容/减容的算法也是一样的
    size_t begin = w_hash_pointer(new_referrer) & (entry->mask); // '& (entry->mask)' 确保了 begin的位置只能大于或等于 数组的长度
    size_t index = begin;  // 初始的hash index
    size_t hash_displacement = 0;  // 用于记录hash冲突的次数，也就是hash再位移的次数
    while (entry->referrers[index] != nil) {
        hash_displacement++;
        index = (index+1) & entry->mask;  // index + 1, 移到下一个位置，再试一次能否插入。（这里要考虑到entry->mask取值，一定是：0x111, 0x1111, 0x11111, ... ，因为数组每次都是*2增长，即8， 16， 32，对应动态数组空间长度-1的mask，也就是前面的取值。）
        if (index == begin) bad_weak_table(entry); // index == begin 意味着数组绕了一圈都没有找到合适位置，这时候一定是出了什么问题。
    }
    if (hash_displacement > entry->max_hash_displacement) { // 记录最大的hash冲突次数, max_hash_displacement意味着: 我们尝试至多max_hash_displacement次，肯定能够找到object对应的hash位置
        entry->max_hash_displacement = hash_displacement;
    }
    // 将ref存入hash数组，同时，更新元素个数num_refs
    weak_referrer_t &ref = entry->referrers[index];
    ref = new_referrer;
    entry->num_refs++;
}

weak_unregister_no_lock

如果

weak ptr

在指向obj之前，已经weak引用了其他的对象，则需要先将

weak ptr

从其他对象的

weak_entry_t

的hash数组中移除。在

storeWeak

方法中，会调用

weak_unregister_no_lock

来做移除操作：

if (haveOld) {
        weak_unregister_no_lock(&oldTable->weak_table, oldObj, location); // 如果weak_ptr之前弱引用过别的对象oldObj，则调用weak_unregister_no_lock，在oldObj的weak_entry_t中移除该weak_ptr地址
    }

weak_unregister_no_lock

的实现如下：

void
weak_unregister_no_lock(weak_table_t *weak_table, id referent_id, 
                        id *referrer_id)
{
    objc_object *referent = (objc_object *)referent_id;
    objc_object **referrer = (objc_object **)referrer_id;

    weak_entry_t *entry;

    if (!referent) return;

    if ((entry = weak_entry_for_referent(weak_table, referent))) { // 查找到referent所对应的weak_entry_t
        remove_referrer(entry, referrer);  // 在referent所对应的weak_entry_t的hash数组中，移除referrer
       
        // 移除元素之后， 要检查一下weak_entry_t的hash数组是否已经空了
        bool empty = true;
        if (entry->out_of_line()  &&  entry->num_refs != 0) {
            empty = false;
        }
        else {
            for (size_t i = 0; i < WEAK_INLINE_COUNT; i++) {
                if (entry->inline_referrers[i]) {
                    empty = false; 
                    break;
                }
            }
        }

        if (empty) { // 如果weak_entry_t的hash数组已经空了，则需要将weak_entry_t从weak_table中移除
            weak_entry_remove(weak_table, entry);
        }
    }

weak_unregister_no_lock

的实现逻辑比较简单。

首先，它会在weak_table中找出referent对应的weak_entry_t
在weak_entry_t中移除referrer
移除元素后，判断此时weak_entry_t中是否还有元素（empty==true？）
如果此时weak_entry_t已经没有元素了，则需要将weak_entry_t从weak_table中移除

OK，上面的所有就是当我们将一个obj作weak引用时，所发生的事情。那么，当obj释放时，所有weak引用它的指针又是如何自动设置为nil的呢？接下来我们来看一下obj释放时，所发生的事情。

Dealloc

当对象引用计数为0时，runtime会调用

_objc_rootDealloc

方法来析构对象，实现如下：

void
_objc_rootDealloc(id obj)
{
    assert(obj);

    obj->rootDealloc();
}

它会调用

objc_object

的

rootDealloc

方法：

inline void
objc_object::rootDealloc()
{
    if (isTaggedPointer()) return;  // fixme necessary?

    if (fastpath(isa.nonpointer  &&  
                 !isa.weakly_referenced  &&  
                 !isa.has_assoc  &&  
                 !isa.has_cxx_dtor  &&  
                 !isa.has_sidetable_rc))
    {
        assert(!sidetable_present());
        free(this);
    } 
    else {
        object_dispose((id)this);
    }
}

rootDealloc的实现逻辑如下：

判断object是否采用了Tagged Pointer计数，如果是，则不进行任何析构操作。关于这一点，我们可以看出，用Tagged Pointer计数的对象，是不会析构的。Tagged Pointer计数的对象在内存中应该是类似于字符串常量的存在，多个对象指针其实会指向同一块内存地址。虽然官方文档中并没有提及，但可以推测，Tagged Pointer计数的对象的内存位置很有可以就位于字符串常量区。
接下来判断对象是否采用了优化的isa计数方式（ isa.nonpointer ）。如果是，则判断是否能够进行快速释放（ free(this) 用C函数释放内存）。可以进行快速释放的前提是：对象没有被weak引用 !isa.weakly_referenced ，没有关联对象 !isa.has_assoc ，没有自定义的C++析构方法 !isa.has_cxx_dtor ，没有用到sideTable来做引用计数 !isa.has_sidetable_rc 。
其余的，则进入 object_dispose((id)this) 慢释放分支。

如果obj被weak引用了，应该进入

object_dispose((id)this)

分支：

id 
object_dispose(id obj)
{
    if (!obj) return nil;

    objc_destructInstance(obj);    
    free(obj);

    return nil;
}

object_dispose

方法中，会先调用

objc_destructInstance(obj)

来析构

obj

，再用

free(obj)

来释放内存。

objc_destructInstance

的实现如下：

void *objc_destructInstance(id obj) 
{
    if (obj) {
        // Read all of the flags at once for performance.
        bool cxx = obj->hasCxxDtor();
        bool assoc = obj->hasAssociatedObjects();

        // This order is important.
        if (cxx) object_cxxDestruct(obj); // 调用C++析构函数
        if (assoc) _object_remove_assocations(obj); // 移除所有的关联对象，并将其自身从Association Manager的map中移除
        obj->clearDeallocating(); // 清理相关的引用
    }
    return obj;
}

在

objc_destructInstance

中，会清理相关的引用：

obj->clearDeallocating()

：

inline void 
objc_object::clearDeallocating()
{
    if (slowpath(!isa.nonpointer)) {
        // Slow path for raw pointer isa.
        sidetable_clearDeallocating();
    }
    else if (slowpath(isa.weakly_referenced  ||  isa.has_sidetable_rc)) {
        // Slow path for non-pointer isa with weak refs and/or side table data.
        clearDeallocating_slow();
    }

    assert(!sidetable_present());
}

clearDeallocating中有两个分支，先判断obj是否采用了优化isa引用计数。没有，则要清理obj存储在sideTable中的引用计数等信息，这个分支在当前64位设备中应该不会进入，不必关系。

如果启用了isa优化，则判断是否使用了sideTable，使用的原因是因为做了weak引用（

isa.weakly_referenced

）或使用了sideTable的辅助引用计数（

isa.has_sidetable_rc

）。符合这两种情况之一，则进入慢析构路径：

// Slow path for non-pointer isa with weak refs and/or side table data.
        clearDeallocating_slow();

NEVER_INLINE void
objc_object::clearDeallocating_slow()
{
    assert(isa.nonpointer  &&  (isa.weakly_referenced || isa.has_sidetable_rc));

    SideTable& table = SideTables()[this]; // 在全局的SideTables中，以this指针为key，找到对应的SideTable
    table.lock();
    if (isa.weakly_referenced) { // 如果obj被弱引用
        weak_clear_no_lock(&table.weak_table, (id)this); // 在SideTable的weak_table中对this进行清理工作
    }
    if (isa.has_sidetable_rc) { // 如果采用了SideTable做引用计数
        table.refcnts.erase(this); // 在SideTable的引用计数中移除this
    }
    table.unlock();
}

这里调用了

weak_clear_no_lock

来做weak_table的清理工作，同时将所有weak引用该对象的ptr置为

nil

：

void 
weak_clear_no_lock(weak_table_t *weak_table, id referent_id) 
{
    objc_object *referent = (objc_object *)referent_id;

    weak_entry_t *entry = weak_entry_for_referent(weak_table, referent); // 找到referent在weak_table中对应的weak_entry_t
    if (entry == nil) {
        /// XXX shouldn't happen, but does with mismatched CF/objc
        //printf("XXX no entry for clear deallocating %p\n", referent);
        return;
    }

    // zero out references
    weak_referrer_t *referrers;
    size_t count;
    
    // 找出weak引用referent的weak 指针地址数组以及数组长度
    if (entry->out_of_line()) {
        referrers = entry->referrers;
        count = TABLE_SIZE(entry);
    } 
    else {
        referrers = entry->inline_referrers;
        count = WEAK_INLINE_COUNT;
    }
    
    for (size_t i = 0; i < count; ++i) {
        objc_object **referrer = referrers[i]; // 取出每个weak ptr的地址
        if (referrer) {
            if (*referrer == referent) { // 如果weak ptr确实weak引用了referent，则将weak ptr设置为nil，这也就是为什么weak 指针会自动设置为nil的原因
                *referrer = nil;
            }
            else if (*referrer) { // 如果所存储的weak ptr没有weak 引用referent，这可能是由于runtime代码的逻辑错误引起的，报错
                _objc_inform("__weak variable at %p holds %p instead of %p. "
                             "This is probably incorrect use of "
                             "objc_storeWeak() and objc_loadWeak(). "
                             "Break on objc_weak_error to debug.\n", 
                             referrer, (void*)*referrer, (void*)referent);
                objc_weak_error();
            }
        }
    }
    
    weak_entry_remove(weak_table, entry); // 由于referent要被释放了，因此referent的weak_entry_t也要移除出weak_table
}

OK，上面就是为什么当对象析构时，所有弱引用该对象的指针都会被设置为

nil

的原因。

总结

纵观weak引用的底层实现，其实原理很简单。就是将所有弱引用obj的指针地址都保存在obj对应的

weak_entry_t

中。当obj要析构时，会遍历

weak_entry_t

中保存的弱引用指针地址，并将弱引用指针指向

nil

，同时，将weak_entry_t移除出weak_table。

这里涉及到runtime 四个重要的数据结构：

SideTables

，

SideTable

，

weak_table

，

weak_entry_t

关于它们，我们在Objective-C runtime机制(5)——iOS 内存管理中已有涉及。

为了加深对runtime的理解，在接下来的一章中，我们会依次分析这四个数据结构。

补充

在文章的开头，我们举的例子：

int main(int argc, char * argv[]) {
    @autoreleasepool {
        NSObject *obj = [[NSObject alloc] init];
        __weak NSObject *weakObj = obj;
    }
}

它底层会调用

objc_initWeak

方法，并最终会调用

storeWeak<DontHaveOld, DoHaveNew, DoCrashIfDeallocating>
        (location, (objc_object*)newObj);

这是，传入storeWeak的参数中，haveOld被设置为false，表明weakObj之前并没有weak指向其他的对象。

那么，什么时候storeWeak的参数haveOld被设置为true呢？当我们的weakObj已经指向一个weak对象，又要指向新的weak对象时，storeWeak的haveOld参数会被置为true：

int main(int argc, char * argv[]) {
    @autoreleasepool {
        NSObject *obj = [[NSObject alloc] init];
        __weak NSObject *weakObj = obj; // 这里会调用objc_initWeak方法，storeWeak的haveOld == false
        NSObject *obj2 = [[NSObject alloc] init];
        weakObj = obj2;  // 这里会调用objc_storeWeak方法，storeWeak的haveOld == true，会将之前的引用先移除
    }
}

objc_storeWeak

方法的实现如下：

/** 
 * This function stores a new value into a __weak variable. It would
 * be used anywhere a __weak variable is the target of an assignment.
 * 
 * @param location The address of the weak pointer itself
 * @param newObj The new object this weak ptr should now point to
 * 
 * @return \e newObj
 */
id
objc_storeWeak(id *location, id newObj)
{
    return storeWeak<DoHaveOld, DoHaveNew, DoCrashIfDeallocating>
        (location, (objc_object *)newObj);
}

Objective-C runtime机制(6)——weak引用的底层实现原理前言Store as weakDealloc总结补充

前言

Store as weak

objc_initWeak

storeWeak

weak_register_no_lock

weak_unregister_no_lock

Dealloc

总结

补充

继续阅读

PAT (Advanced Level) Practise 1135 Is It A Red-Black Tree (30)

UVA 348 Optimal Array Multiplication Sequence

PAT (Advanced Level) Practise 1066 Root of AVL Tree (25)

CSU 1806 Toll

CodeChef PALPROB Palindromeness

ZOJ 1032 Area 2

UVA 590 Always on the run

FZU 1978 Repair the brackets

UVA 10344- 23 out of 5

POJ 2115 C Looooops

ZOJ 3700 Ever Dream

UVA 620 Cellular Structure

swift资料合集

苹果审核 Guideline 2.1 - Information Needed

EGORefreshTableHeaderView 解读代码解读 ELTableViewController 的使用写在最后

今日头条iOS客户端启动速度优化技术调研实测数据