startup_head.s
作為頭檔案，定義了 ARM 闆的初始設定
比如堆棧基址，FCLK:HCLK:PCLK 分頻，USB 頻率等參數
;input frequency 12.00 MHz
;MPLL的分頻配置 ; MPLL=(2*m*Fin)/(p*2^s)
M_MDIV EQU 127 ;m=(MDIV+8)
M_PDIV EQU 2 ;p=(PDIV+2)
M_SDIV EQU 1 ;s=SDIV
; output frequency 405.00 MHz
; hdivn,pdivn FCLK:HCLK:PCLK
; 0,0 1:1:1
; 0,1 1:1:2
; 1,0 1:2:2
; 1,1 1:2:4
M_HDIVN EQU 1 ;HDIVN=01 代表 HCLK=FCLK/2
M_PDIVN EQU 1 ;PDIVN=1 代表PCLK=HCLK/2
;是以FCLK:HCLK:PCLK=4:2:1
;Fin=12.0MHz
;UPLL的分頻配置 ; UPLL=(m*Fin)/(p*2^s)
U_MDIV EQU 56 ;m=(MDIV+8)
U_PDIV EQU 2 ;p=(PDIV+2)
U_SDIV EQU 2 ;s=SDIV
;Fout=48.0MHz
R1_I EQU (1<<12) ;Rx_y 這一系列是在定義變量，分别代表R1寄存器上的不同位
R1_C EQU (1<<2)
R1_A EQU (1<<1)
R1_M EQU (1)
R1_iA EQU (1<<31)
R1_nF EQU (1<<30)
STACK_SIZE EQU 128 ;定義變量棧大小
SUB_STACK_SIZE EQU 128 ;定義變量子棧大小
STACK_BASE EQU (0x00001000) ;定義棧的基址
IRQStack_BASE EQU STACK_BASE ;定義IRQ棧的基址
UsrStack_BASE EQU (STACK_BASE - SUB_STACK_SIZE) ;定義使用者棧的基址
END 複制
uart_fifo.s
這是主彙程式設計式,定義了中斷向量表,進行了各種初始化
GET s3c2410_SFR.s ;GET僞指令将s3c2410_SFR.s包含到此檔案中,s3c2410_SFR.s是寄存器位址的宏定義
GET startup_head.s ;GET僞指令将startup_head.s包含到此檔案中,startup_head.s是初始化配置
IMPORT main ;IMPORT僞指令訓示編譯器目前的符号不是在本源檔案中定義的,而是在其它源檔案中定義的,在本源檔案中可能引用該符号,main定義在c源檔案中
IMPORT Handle_UART0 ;Handle_UART0定義在c源檔案中
AREA RESET, CODE, READONLY ;定義一個名為RESET的隻讀代碼段
CODE32 ;CODE32僞指令訓示彙編編譯器後面的指令為32位的ARM指令
ENTRY ;ENTRY僞指令用于指定程式的入口點,一個程式(可以包含多個源檔案)中至少要有一個ENTRY,可以有多個ENTRY，但一個源檔案中最多隻有一個ENTRY
_Startup ;這隻是一個普通标号
EXPORT VectorBase ;EXPORT聲明一個符号VectorBase可以被其它檔案引用
VectorBase ;向量基址,下面是自定義的向量集
B HandlerReset ;直接跳轉到HandlerReset處進行處理
LDR PC, (Vect_Table + 4) ;将(Vect_Table + 4)中的位址加載到PC中,也就是跳轉到(Vect_Table + 4)中的位址處進行處理
LDR PC, (Vect_Table + 8) ;SWI,将(Vect_Table + 8)中的位址加載到PC中,也就是跳轉到(Vect_Table + 8)中的位址處進行處理
LDR PC, (Vect_Table +12) ;Prefetch Abort,将(Vect_Table + 12)中的位址加載到PC中,也就是跳轉到(Vect_Table + 12)中的位址處進行處理
LDR PC, (Vect_Table +16) ;Data Abort,将(Vect_Table + 16)中的位址加載到PC中,也就是跳轉到(Vect_Table + 16)中的位址處進行處理
B . ;Not Assigned,什麼事也不做,相當于while(1)
LDR PC, (Vect_Table +24) ;IRQ,将(Vect_Table + 24)中的位址加載到PC中,也就是跳轉到(Vect_Table + 24)中的位址處進行處理
LDR PC, (Vect_Table +28) ;FIQ,将(Vect_Table + 28)中的位址加載到PC中,也就是跳轉到(Vect_Table + 28)中的位址處進行處理
Vect_Table ;中斷向量表,DCD用于配置設定一片連續的字(4個位元組)存儲單元并用指定的資料初始化(有點像int型數組)
DCD HandlerReset ;相當于(Vect_Table + 0),并且将HandlerReset的值加載到其中
DCD HandlerUndef ;相當于(Vect_Table + 4),并且将HandlerUndef的值加載到其中
DCD HandlerSWI ;相當于(Vect_Table + 8),并且将HandlerSWI的值加載到其中
DCD HandlerPabort ;相當于(Vect_Table + 12),并且将HandlerPabort的值加載到其中
DCD HandlerDabort ;相當于(Vect_Table + 16),并且将HandlerDabort的值加載到其中
DCD . ;相當于(Vect_Table + 20),并且将.的值加載到其中
DCD IRQ_Handler ;相當于(Vect_Table + 24),并且将IRQ_Handler的值加載到其中
DCD HandlerFIQ ;相當于(Vect_Table + 28),并且将HandlerFIQ的值加載到其中
DCD main ;相當于(Vect_Table + 32),并且将main的值加載到其中
EXPORT VectorEnd ;EXPORT聲明一個符号VectorEnd可以被其它檔案引用
VectorEnd
LTORG ;聲明文字池儲存以上向量表(這條指令的實際效用還是有點不是很清楚)
AREA RESET, CODE, READONLY ;定義一個名為RESET的隻讀代碼段
HandlerReset ;定義一個HandlerReset标簽(指代了此處的位址)
;/***************************************/
;/* disable interrupt */
;/***************************************/
MRS R0, cpsr ;将狀态寄存器cpsr中的值讀到R0中
ORR R0, R0, #0xc0 ;将R0與(1100 0000)進行或操作,結果放到R0中,這個過程其實是保持其它位不變，将第6(FIQ)位和7(IRQ)位置1，就是禁止所有中斷
MSR cpsr_c, R0 ;将R0重新存回,也就是關閉了所有中斷
;/***************************************/
;/* disable watchdog */
;/***************************************/
LDR R0, =WTCON ;看門狗配置寄存器位址加載到R0中
LDR R1, =0x0 ;将0加載到R1中
STR R1, [R0] ;将看門狗配置寄存器中的值置0,也就是關閉看門狗
;/****************************************/
;/* config interrupt */
;/****************************************/
LDR R0, =INTMSK ;中斷配置寄存器位址加載到R0中
LDR R1, =0xFFFFFFFF ;将全1加載到R1中
STR R1, [R0] ;将全1加載到中斷配置寄存器中，讓所有中斷屏蔽掉
LDR R0, =INTSUBMSK ;子中斷配置寄存器位址加載到R0中
LDR R1, =0x000007FF ;将(0111 1111 1111)加載到R1中
STR R1, [R0] ;将全(0111 1111 1111)加載到子中斷配置寄存器中，讓所有子中斷屏蔽掉
LDR R0, =INTPND ;中斷未決寄存器位址加載到R0中
LDR R1, =0xFFFFFFFF ;将全1加載到R1中
STR R1, [R0] ;通過寫1的方式來清理中斷未決寄存器
LDR R0, =SRCPND ;源未決寄存器位址加載到R0中
LDR R1, =0xFFFFFFFF ;将全1加載到R1中
STR R1, [R0] ;通過寫1的方式來清理源未決寄存器
;/****************************************/
;/* config pll */
;/****************************************/
LDR R0, =LOCKTIME ;鎖定時間計數寄存器位址加載到R0中
LDR R1, =0x00FFFFFF ;将0x00FFFFFF加載到R1中
STR R1, [R0] ;将R1加載到鎖定時間計數寄存器中(U_LTIME 為0x00FF,M_LTIME 為0xFFFF)
LDR R0, =CLKDIVN ;時鐘分頻控制寄存器位址加載到R0中
LDR R1, =((M_HDIVN << 1) | M_PDIVN) ;将((M_HDIVN << 1) | M_PDIVN)加載到R1中，M_HDIVN 和 M_PDIVN 定義在另一個頭檔案中
STR R1, [R0] ;進行配置
;/****************************************/
;/* config mmu */
;/****************************************/
MRC p15, 0, R0, c1, c0, 0
ORR R0, R0, #R1_nF:OR:R1_iA
MCR p15,0,R0,c1,c0,0
MRC p15, 0, R0, c1, c0, 0
BIC R0, R0, #R1_M
MCR p15, 0, R0, c1, c0, 0
MRC p15, 0, R0, c1, c0, 0
ORR R0, R0, #R1_I
MCR p15, 0, R0, c1, c0, 0
MRC p15, 0, R0, c1, c0, 0
ORR R0, R0, #R1_C
MCR p15, 0, R0, c1, c0, 0
;/****************************************/
;/* config pll */
;/****************************************/
LDR R0, =CLKCON ;時鐘發生器控制寄存器位址加載到R0中
LDR R1, =0x0007FFF0 ;将0x0007FFF0加載到R1中，相應的位置1，就是設定有效，哪些外設要進行有效處理，得查文檔
STR R1, [R0] ;進行設定
LDR R0, =CLKSLOW ;減慢時鐘控制寄存器位址加載到R0中
LDR R1, =0x00000004 ;将0x00000004加載到R1中
STR R1, [R0] ;進行設定
LDR R0, =UPLLCON ;UPLL配置寄存器位址加載到R0中 ,USB的PLL就在此配置
LDR R1, =((U_MDIV << 12) + (U_PDIV << 4) + U_SDIV) ;将((U_MDIV << 12) + (U_PDIV << 4) + U_SDIV)加載到R1中 ;Fin=12MHz, Fout=48MHz
STR R1, [R0] ;進行設定
NOP ;NOP為空操作僞指令，NOP僞指令在彙編時将會被代替成ARM中的空操作，比如 MOV R0,R0
NOP
NOP
NOP
NOP
NOP
NOP
LDR R0, =MPLLCON ;MPLL配置寄存器位址加載到R0中
LDR R1, =((M_MDIV << 12) + (M_PDIV << 4) + M_SDIV) ;将((M_MDIV << 12) + (M_PDIV << 4) + M_SDIV)加載到R1中
STR R1, [R0] ;進行設定
NOP
NOP
;/****************************************/
;/* config stack */
;/****************************************/
MSR CPSR_c, #0x0d2 ;将(1101 0010)加載到CPSR_c中(代表禁止所有中斷,使用ARM模式,進入中斷模式)
LDR SP, =IRQStack_BASE ;IRQStack_BASE在另一個檔案中定義,将中斷模式中的堆棧指針SP指到IRQStack_BASE處
MSR CPSR_c, #0x05f ;将(0101 1111)加載到CPSR_c中(代表開啟IRQ中斷禁止FIQ中斷,使用ARM模式,進入系統模式)
LDR SP, =UsrStack_BASE ;UsrStack_BASE在另一個檔案中定義,将系統模式中的堆棧指針SP指到UsrStack_BASE處
;/***************************************/
;/* enable interrupt */
;/***************************************/
MRS R0, cpsr ;cpsr加載到R0中
BIC R0, R0, #0x80 ;BIC将R0中的第7位置0,(将R0跟(1000 0000)的反碼(0111 1111)進行與操作,就是對第7位清零)
MSR cpsr_c, R0 ;将R0結果儲存回cpsr_c中
;/****************************************/
;/* go to c main */
;/****************************************/
LDR PC, (Vect_Table + 32) ; 這裡進行跳轉，相當于 goto main(由此可知c語言中的main函數之是以叫main,也是類似這樣的地方定義的,如果取别的名字比如xxx,那C的代碼就都會從xxx函數開始執行)
NOP
NOP
NOP
NOP
;/****************************************/
;/* Undefined Instruction interrupt entry*/
;/****************************************/
HandlerUndef ;定義一個HandlerUndef,并且啥也不幹
B .
;/****************************************/
;/* SWI interrupt entry */
;/****************************************/
HandlerSWI ;定義一個HandlerSWI,并且啥也不幹
B .
;/****************************************/
;/* Prefetch Abort interrupt entry */
;/****************************************/
HandlerPabort ;定義一個HandlerPabort,并且啥也不幹
B .
;/****************************************/
;/* Data Abort interrupt entry */
;/****************************************/
HandlerDabort ;定義一個HandlerDabort,并且啥也不幹
B .
;/****************************************/
;/* FIQ interrupt entry */
;/****************************************/
HandlerFIQ ;定義一個HandlerFIQ,并且啥也不幹
B .
;/****************************************/
;/* default irq entry */
;/****************************************/
EXPORT Default_IRQ_ISR ;EXPORT聲明一個符号Default_IRQ_ISR可以被其它檔案引用
Default_IRQ_ISR ;定義一個Default_IRQ_ISR,并且啥也不幹
B .
PRESERVE8 ;保證堆棧8位元組對齊
IRQ_Vecotr ;中斷向量表
EINT0_Handle B Default_IRQ_ISR ;B Default_IRQ_ISR代表啥都不幹(因為上面對Default_IRQ_ISR中的操作定義就是啥都沒幹)
EINT1_Handle B Default_IRQ_ISR
EINT2_Handle B Default_IRQ_ISR
EINT3_Handle B Default_IRQ_ISR
EINT4_7_Handle B Default_IRQ_ISR
EINT8_23_Handle B Default_IRQ_ISR
CAM_Handle B Default_IRQ_ISR
BATFLT_Handle B Default_IRQ_ISR
TICK_Handle B Default_IRQ_ISR
WDT_AC97_Handle B Default_IRQ_ISR
ISR_TIMER0_Handle B Default_IRQ_ISR
ISR_TIMER1_Handle B Default_IRQ_ISR
ISR_TIMER2_Handle B Default_IRQ_ISR
ISR_TIMER3_Handle B Default_IRQ_ISR
ISR_TIMER4_Handle B Default_IRQ_ISR
ISR_UART2_Handle B Default_IRQ_ISR
ISR_LCD_Handle B Default_IRQ_ISR
ISR_DMA0_Handle B Default_IRQ_ISR
ISR_DMA1_Handle B Default_IRQ_ISR
ISR_DMA2_Handle B Default_IRQ_ISR
ISR_DMA3_Handle B Default_IRQ_ISR
ISR_SDI_Handle B Default_IRQ_ISR
ISR_SPI0_Handle B Default_IRQ_ISR
ISR_UART1_Handle B Default_IRQ_ISR
ISR_NFCON_Handle B Default_IRQ_ISR
ISR_USBD_Handle B Default_IRQ_ISR
ISR_USBH_Handle B Default_IRQ_ISR
ISR_IIC_Handle B Default_IRQ_ISR
ISR_UART0_Handle B Handle_UART0 ;收到ISR_UART0_Handle中斷會跳轉到Handle_UART0進行處理
ISR_SPI1_Handle B Default_IRQ_ISR
ISR_RTC_Handle B Default_IRQ_ISR
ISR_ADC_Handle B Default_IRQ_ISR
IRQ_Handler PROC
EXPORT IRQ_Handler [WEAK] ;EXPORT聲明一個符号IRQ_Handler可以被其它檔案引用，[WEAK] 指定該選項後，如果symbol在所有的源程式中都沒有被定義，編譯器也不會産生任何錯誤資訊，同時編譯器也不會到目前沒有被INCLUDE進來的庫中去查找該标号
SUB LR, LR, #4 ;LR連接配接寄存器(Link Register, LR)，在ARM體系結構中LR的特殊用途有兩種：一是用來儲存子程式傳回位址；二是當異常發生時，LR中儲存的值等于異常發生時PC的值減4(或者減2),是以在各種異常模式下可以根據LR的值傳回到異常發生前的相應位置繼續執行
STMDB SP!, {R0-R12,LR} ;保護現場,将{R0-R12,LR}作壓棧處理,順序是寄存器從大到小，SP!意思是每次操作完将SP更新的值還是存回SP
LDR R0, =INTOFFSET ;将中斷偏移寄存器的位址存到R0中
LDR R0, [R0] ;将R0中位址(中斷偏移寄存器位址)所代表的寄存器的值存到R0中
LDR R1, =IRQ_Vecotr ;将中斷向量表的基址存到R1中
ADD R1, R1, R0, LSL #2 ;将R0邏輯左移2位,加上R1,結果放到R1中,其實就是R1=R1+R0*4,為什麼要乘4呢,因為向量表是4位元組對其的,是以結果就是相應中斷跳轉的位置
LDR LR, =int_return ;LR中儲存int_return作為傳回位址
MOV PC, R1 ;将R1的值(中斷入口位址)儲存到PC中,即相當于直接跳轉到中斷處,開始執行中斷服務程式
int_return ;傳回位址
LDMIA SP!,{R0-R12, PC}^ ;進行現場恢複,将之前壓棧的環境變量從堆棧中讀出,覆寫到目前的寄存器中,在LDM指令的寄存器清單中包含有PC時使用'^',那麼除了正常的多寄存器傳送外,将SPSR拷貝到CPSR中,這可用于異常處理傳回,使用'^'字尾進行資料傳送且寄存器清單不包含PC時,加載/存儲的是使用者模式的寄存器,而不是目前模式的寄存器
ENDP
END 複制