Shader學習之能量場效果

從效果上看，該球體是半透明的，邊緣部分泛藍光，球體表面與其他物體相交的部分會高亮，處在球體内部的其他物體形狀抖動變化。

首先，邊緣部分泛藍光，根據觀察方向繪制，使用UnityWorldSpaceViewDir；

其次，相交部分高亮，計算場景内物體深度和球體深度內插補點，相交部分的內插補點為0，設定相機的depthTextureMode即可生成深度圖，在shader中使用_CameraDepthTexture通路深度圖，LinearEyeDepth，SAMPLE_DEPTH_TEXTURE_PROJ，UNITY_PROJ_COORD這三個方法和宏的用法我也比較模糊，希望有柳暗花明的一天；

最後，形狀抖動變化，變化相機的GrabTexure的uv，使用GrabPass擷取GrabTexure。

Shader "chenjd/MyForceField"
{
	Properties
	{
		_Color("Color", Color) = (0, 1, 0, 1)
		_Power("Power", Range(0, 4)) = 1
		_NoiseTexture("NoiseTexture", 2D) = "white" {}
		_DistortStrength("DistortStrength", Range(0,1)) = 0.2
		_DistortTimeFactor("DistortTimeFactor", Range(0,1)) = 0.2
	}
	SubShader
	{
		//ZWrite Off
		Cull Off
		Blend SrcAlpha OneMinusSrcAlpha
		Tags {
			"RenderType"="Transparent"
			"Queue"="Transparent"
		}

		GrabPass
		{
			"_GrabTempTex"
		}

		Pass
		{
			CGPROGRAM
			#pragma target 3.0
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"

			struct appdata
			{
				float4 vertex : POSITION;
				float2 uv : TEXCOORD0;
				float3 normal : NORMAL;
			};

			struct v2f
			{
				float4 vertex : SV_POSITION;
				float3 normal : NORMAL;
				float4 screenPos : TEXCOORD1;
				float3 viewDir : TEXCOORD3;
				float2 uv :TEXCOORD0;
				float4 grabPos : TEXCOORD2;
			};

			fixed4 _Color;
			float _Power;
			sampler2D _CameraDepthTexture;
			sampler2D _NoiseTexture;
			float4 _NoiseTexture_ST;
			sampler2D _GrabTempTex;
			float4 _GrabTempTex_ST;
			float _DistortTimeFactor;
			float _DistortStrength;
			
			v2f vert (appdata v)
			{
				v2f o;

				o.vertex = UnityObjectToClipPos(v.vertex);
				o.uv = TRANSFORM_TEX(v.uv, _NoiseTexture);
				
				o.normal = UnityObjectToWorldNormal(v.normal);
				o.viewDir = normalize(UnityWorldSpaceViewDir(mul(unity_ObjectToWorld, v.vertex)));

				o.screenPos = ComputeScreenPos(o.vertex);
				COMPUTE_EYEDEPTH(o.screenPos.z);

				o.grabPos = ComputeGrabScreenPos(o.vertex);

				return o;
			}
			
			fixed4 frag (v2f i) : SV_Target
			{
				float rim = pow(1 - abs(dot(i.viewDir, i.normal)), _Power);

				float sceneZ = LinearEyeDepth(SAMPLE_DEPTH_TEXTURE_PROJ(_CameraDepthTexture, UNITY_PROJ_COORD(i.screenPos)));
				float delta = sceneZ - i.screenPos.z;
				float intersection = (1 - delta) * 2;

				float4 offset = tex2D(_NoiseTexture, i.uv - _Time.xy) * _DistortTimeFactor;
				i.grabPos.xy -= offset.xy * _DistortStrength;
				
				float4 col = tex2Dproj(_GrabTempTex, i.grabPos);
				col = col + _Color * max(rim, intersection);

				return col;
			}
			ENDCG
		}
	}
}
           

學習自https://www.cnblogs.com/murongxiaopifu/p/7050233.html。