Arduino ESP32 深度睡眠與外部喚醒（EXT0）

使用10K下拉電阻連接配接到按鈕 GPIO 4和GND之間，防止其他雜波信号幹擾，在3.3V和GPIO4之間接按鍵，用來觸發EXT0，接線示意圖：

執行個體代碼

/*
  深度睡眠與外部喚醒（這裡使用10K下拉按鈕到 GPIO 4）
*/

#define BUTTON_PIN_BITMASK 0x200000000 // 2^33 十六進制

RTC_DATA_ATTR int bootCount = 0;

//列印 ESP32 從深度睡眠中醒來的原因
void print_wakeup_reason(){
  esp_sleep_wakeup_cause_t wakeup_reason;

  wakeup_reason = esp_sleep_get_wakeup_cause();

  switch(wakeup_reason)
  {
    case ESP_SLEEP_WAKEUP_EXT0 : Serial.println("使用 RTC_IO 的外部信号引起的喚醒"); break;
    case ESP_SLEEP_WAKEUP_EXT1 : Serial.println("使用 RTC_CNTL 的外部信号引起的喚醒"); break;
    case ESP_SLEEP_WAKEUP_TIMER : Serial.println("定時器引起的喚醒"); break;
    case ESP_SLEEP_WAKEUP_TOUCHPAD : Serial.println("觸摸闆引起的喚醒"); break;
    case ESP_SLEEP_WAKEUP_ULP : Serial.println("ULP 程式引起的喚醒"); break;
    default : Serial.printf("喚醒不是由深度睡眠引起的: %d\n", wakeup_reason); break;
  }
}

void setup(){
  Serial.begin(115200);
  delay(1000); //花一些時間打開串行螢幕
  //增加引導編号并在每次重新開機時列印
  ++bootCount;
  Serial.println("Boot number: " + String(bootCount));

  //也列印 ESP32 和觸摸闆的喚醒原因
  print_wakeup_reason();

  /*
  First we configure the wake up source
  We set our ESP32 to wake up for an external trigger.
  There are two types for ESP32, ext0 and ext1 .
  ext0 uses RTC_IO to wakeup thus requires RTC peripherals
  to be on while ext1 uses RTC Controller so doesnt need
  peripherals to be powered on.
  Note that using internal pullups/pulldowns also requires
  RTC peripherals to be turned on.
  */
  esp_sleep_enable_ext0_wakeup(GPIO_NUM_4,1); //1 = High, 0 = Low

  //If you were to use ext1, you would use it like
  //esp_sleep_enable_ext1_wakeup(BUTTON_PIN_BITMASK,ESP_EXT1_WAKEUP_ANY_HIGH);

  //将進入睡眠
  Serial.println("要休眠了");
  esp_deep_sleep_start();
  Serial.println("這永遠不會被列印");
}

void loop(){
}
           

• 序列槽列印喚醒原因