标準直齒圓柱輪模組化
- 1.漸開線基礎
- 2.完整指令
- 3.結果圖
1.漸開線基礎
（一）基本參數關系：
可惜需要會員了：齒輪參數原文位址
不過不要緊，上面的内容是我精心挑出來的，對于模組化也足夠了，而且網上關于齒輪的資料也多的是。
2.完整指令
/clear,start
rm1 = 40 !齒輪軸孔半徑
b1 = 50 !齒輪厚度
z1= 20 !齒輪齒數
m = 8 !模數
ha = 1 !齒頂高系數
c = 0.25 !頂隙系數
!========================
!齒輪模組化
z = z1
ang = 360/z !每個齒的圓心角
ang1 = ang/2 !半個齒的圓心角
r = m*z/2
rf = (z-2*ha-2*c)*m/2 !齒根圓半徑
ra = (z+2*ha)*m/2 !齒頂圓半徑
r1 = m*c !齒更倒角半徑
pi=3.1415926
s=pi*m/2 !分度圓的齒厚
inva=0.014904 !漸開線函數的值
*afun,deg !設定角度計算的機關為度
rb=r*cos(20) !計算基圓半徑
*afun,rad !設定角度計算機關為弧度
n=12
*dim,x,,n !定義兩個數組用來存放生成的點
*dim,y,,n
*if,rf,gt,rb,then !如果齒根圓大于基圓，計算齒根圓上的壓力角
af=acos(rb/rf) !齒根圓上的壓力角
invaf=tan(af)-af
phi=s/r-2*(invaf-inva) !計算齒根圓齒厚對應的圓心角
x(1)=rf*cos(phi/2) !計算齒根圓的坐标值
y(1)=rf*sin(phi/2)
detar=(ra-rf)/(n-1)
*do,i,1,n-1 !進行循環計算任意圓上的坐标
ri=rf+i*detar
j=i+1
ai=acos(rb/ri) !計算任意圓上的壓力角
invai = tan(ai)-ai
phi = s/r-2*(invai-inva) !計算齒根圓齒厚對應的圓心角
x(j)=rf*cos(phi/2) !任意圓對應曲線的x坐标值
y(j)=rf*sin(phi/2) !任意圓對應曲線的y坐标值
*enddo
*else !齒根圓小于基圓的情況，取af=0
phi=s/r+2*inva !計算齒根圓齒厚對應的圓心角
x(1)=rf*cos(phi/2) !計算齒根圓的坐标值
y(1)=rf*sin(phi/2)
x(2)=rb*cos(phi/2) !計算基圓圓的坐标值
y(2)=rb*sin(phi/2)
detar = (ra-rb)/(n-2)
*do,i,1,n-2 !進行循環計算任意圓上的坐标
ri=rb+i*detar
j=i+2
ai=acos(rb/ri) !計算任意圓上的壓力角
invai = tan(ai)-ai
phi = s/r-2*(invai-inva) !任意圓對應齒厚的圓心角
x(j)=ri*cos(phi/2) !任意圓對應曲線的x坐标值
y(j) = ri*sin(phi/2) !任意圓對應曲線的y坐标值
*enddo
*endif
/prep7 !進入ansys前處理器
*do,i,1,n !生成n=12個關鍵點
k,i,x(i),y(i)
*enddo
!=======================================
k,n+1,ra,0 !生成齒頂圓上的關鍵點
lstr,n,n+1 !直線連接配接近似替代齒頂圓圓弧
bsplin,n,n-1,n-2,n-3,n-4,n-5 !樣條拟合生成齒廓
bsplin,n-5,n-6,n-7,n-8,n-9,n-10
bsplin,n-10,n-11
lcomb,2,3,0 !将前面的樣條曲線合并
lcomb,2,4,0
cyl4,,,rm1,0,rf,ang1 !生成一個圓環
adele,1 !删除生成的圓環面
ldele,3 !删除一條與齒廓相連的線
lstr,2,13 !生成兩條線
lstr,7,1
lcomb,3,6,0 !線相加
lfillt,7,2,r1 !對齒根進行倒角
lang,3,16,90 !由倒角半徑上的一點生成一條垂線
kl,4,0.1 !線上上按比率生成一個關鍵點
lang,8,18,90 !由該關鍵點生成一條垂線
lsbl,4,11,,delete,keep !通過生成的垂線對另一條線進行分割
al,3,1,2,9 !形成一個齒形面
al,6,7,12,11,8,9
al,13,5,10,11
!==========================================
!========鏡像生成一個齒廓部分====================
csys,4 !将工作坐标系作為激活坐标系
arsym,y,all,,,,0,0 !對xz平面進行鏡像操作
csys,1 !激活柱坐标系
agen,z,all,,,,ang,,,0
csys,0 !激活直角坐标系
allsel,all
vext,all,,,0,0,b1,0,0,0 !通過給定偏移量，由面生成體
vadd,all
numcmp,all !壓縮實體的編号
!=====根據需要建立鍵槽部分========
block,-11,11,31,45.4,0,60
*get,vmax,volu,,num,max
vsbv,1,vmax
allsel,all
vgen,,all,,,,,-b1/2,,,1 !将齒輪移至中心
3.結果圖