<b>dos批处理高级教程</b>
前言
本教程主要引用伤脑筋版主的系列文章，同时参考引用[英雄]教程等其他批处理教程，本文将这些文章合并在一起，并尽量修改得详细而且简单易懂，修改整理也是学习过程，主要目的是方便自己以后查阅。
本教程很长啊，需要一定的耐心才能看完，能够看完的话，差不多就是批处理高手了，即使不是高手也是熟手了。本教程还在不断补充之中，当有比较典型的应用技巧时，本教材会将其收入相关的章节之中。本教程适合对dos有一定基础的人慢慢学习或查阅。
查阅方法：复制目录中的条目，搜索即可。
整理者邮箱：[email protected]，如果你要全文或有好的dos使用经验，请你发email给我，谢谢！
目录
第一章 批处理基础
第一节 常用批处理内部命令简介
1、rem 和 ::
2、echo 和 @
3、pause 暂停
4、errorlevel
5、title 设置cmd窗口的标题
6、color 设置cmd窗口前景和背景颜色
7、mode 配置系统设备
8、goto 和 :
9、find 在文件中搜索字符串
10、start 调用外部程序并任其在新窗口自行运行
11、assoc 和 ftype
12、pushd 和 popd
13、call 调用批处理程序或命令并等待其执行完毕
14、shift
15、if
16、setlocal 与 变量延迟
17、attrib 显示或更改文件属性
18、findstr 在文件中搜索字符串（find增强版）
19、date /t 和 time /t
第二节 常用特殊符号
1、@ 命令行回显屏蔽符
2、% 批处理变量引导符
3、> 输出重定向符
4、>> 输出重定向符
5、<、>&、<& 重定向符
6、| 命令管道符
7、^ 转义字符
8、& 组合命令（顺序执行）
9、&& 组合命令（前面指令成功，才执行后面指令）
10、|| 组合命令（前面指令失败，才执行后面指令）
11、"" 字符串界定符
12、, 逗号
13、; 分号
14、() 括号
15、! 感叹号
16、批处理中可能会见到的其它特殊标记符: （略）
cr(0d) 命令行结束符
escape(1b) ansi转义字符引导符
space(20) 常用的参数界定符
tab(09) ; = 不常用的参数界定符
+ copy命令文件连接符
* ? 文件通配符
/ 参数开关引导符
: 批处理标签引导符
第二章 for命令详解
一、基本格式
二、参数 /d 主要搜索匹配目录
三、参数 /r 搜索指定目录树中的匹配文件
四、参数 /l 按数字序列(start,step,end)循环
五、参数 /f 处理命令输出、字符串及文件内容
第三章 for命令中的变量
一、 ~i - 删除任何引号(")，扩展 %i
二、 %~fi - 将 %i 扩展到一个完全合格的路径名
三、 %~di - 仅将 %i 扩展到一个驱动器号
四、 %~pi - 仅将 %i 扩展到一个路径
五、 %~ni - 仅将 %i 扩展到一个文件名
六、 %~xi - 仅将 %i 扩展到一个文件扩展名
七、 %~si - 扩展的路径只含有短名
八、 %~ai - 将 %i 扩展到文件的文件属性
九、 %~ti - 将 %i 扩展到文件的日期/时间
十、 %~zi - 将 %i 扩展到文件的大小
十一、 %~$path:i
第四章 批处理中的变量
一、系统变量
二、自定义变量
第五章 set命令详解
一、用set命令设置自定义变量
二、用set命令进行简单计算
三、用set命令进行字符串处理
1、字符串替换
2、字符串截取
第六章 if命令讲解
第一种用法：if [not] errorlevel number command
第二种用法：if [not] string1==string2 command
第三种用法：if [not] exist filename command
第四种用法：if增强的用法
第七章 dos编程高级技巧
一、交互界面设计
二、if…else…条件语句
三、循环语句
四、子程序
五、用ftp命令实现自动下载
六、用7-zip实现命令行压缩和解压功能
七、调用vbscript程序
八、将批处理转化为可执行文件
九、时间延迟
1、利用ping命令延时
2、利用for命令延时
3、利用vbs延迟函数，精确度毫秒，误差1000毫秒内
4、仅用批处理命令实现任意时间延迟，精确度10毫秒，误差50毫秒内
十、模拟进度条
十一、特殊字符的输入及应用
十二、随机数（%random%）的应用技巧
十三、变量嵌套 与 命令嵌套
十四、文件内容筛选（type和findstr命令结合使用）
全文：http://xiangkg.blog.163.com
1、更正了所有的错别字，适当排版，增加条理性。
2、运行改善所有例子，并纠正了一些语法错误。
3、补充了一些不完全的地方。
4、第一章参考了网上许多教程汇编而成。
5、20080229补充了变量延迟的问题。
6、20080305修改了参数usebackq的说明
7、20080310增加了特殊字符的输入及应用
8、20080311修改了子程序部分
9、20080313修改了echo说明，归纳了9个应用方法
10、20080320增加任意时间延迟方法
11、20080321增加了set计算中十进制与八进制混淆问题的说明
12、20080325修正dos数值计算范围：-2147483648至2147483647，即-2^31～2^31-1
13、20080326增加随机数的应用
14、20080327修改了“if增强用法”中的defined语句说明
15、20080402增加变量嵌套与命令嵌套，重要技巧之一。
不断学习中，不断更新中。
======================================================================
批处理定义：顾名思义，批处理文件是将一系列命令按一定的顺序集合为一个可执行的文本文件，其扩展名为bat或者cmd。这些命令统称批处理命令。
小知识：可以在键盘上按下ctrl+c组合键来强行终止一个批处理的执行过程。
了解了大概意思后,我们正式开始学习.先看一个简单的例子!
@echo off
echo "欢迎来到非常bat!"
pause
把上面的3条命令保存为文件test.bat或者test.cmd然后执行,
他就会在屏幕上显示以下二行话:
欢迎来到非常bat!
请按任意键继续. . .
这就是一个简单批处理文件了，这个批处理文件一共就用了2条命令 "echo" 和"pause" 还有一个特殊符号"@"
从上面这个简单的批处理中,我们可以发现其实批处理就是运用一些含有特殊意义的符号和一些完成指定功能的命令组合而成,那么在批处理中有多少这样的特殊符号和功能命令呢？我们现在就来仔细了解一下一些最常用的!
(以下内容来源网络,请各位仔细阅读,好进入下节的实例说明)
==========================================================================
介绍命令
1、rem 和 ::
rem为注释命令，一般用来给程序加上注解，该命令后的内容不被执行，但能回显。
:: 也可以起注释作用, 而且更简洁有效; 但有两点需要注意：
①任何以冒号:开头的字符行, 在批处理中都被视作标号, 而直接忽略其后的所有内容。而标号分为有效和无效两种。
有效标号：冒号后紧跟一个以字母数字开头的字符串，goto语句可以识别。
无效标号：冒号后紧跟一个非字母数字的一个特殊符号，goto无法识别的标号。
无效可以起到注释作用，所以 :: 常被用作注释符号，其实 :+ 也可起注释作用。
②与rem 不同的是, ::后的字符行在执行时不会回显, 无论是否用echo on打开命令行回显状态, 因为命令解释器不认为他是一个有效的命令行, 就此点来看, rem 在某些场合下将比 :: 更为适用; 另外, rem 可以用于 config.sys 文件中。
行内注释格式：%注释内容% （不常用，容易引起语法错误，慎用少用）
2、echo 和 @
@字符放在命令前将关闭该命令回显，无论此时echo是否为打开状态。
echo命令的作用列举如下：
（1）打开回显或关闭回显功能
格式:echo [{ on|off }]
如果想关闭“echo off”命令行自身的显示，则需要在该命令行前加上“@”。
（2）显示当前echo设置状态
格式:echo
（3）输出提示信息
格式：echo 信息内容
上述是echo命令常见的三种用法，也是大家熟悉和会用的，但作为dos命令淘金者你还应该知道下面的技巧：
（4）关闭dos命令提示符
在dos提示符状态下键入echo off，能够关闭dos提示符的显示使屏幕只留下光标，直至键入echo on，提示符才会重新出现。
（5）输出空行，即相当于输入一个回车
格式：echo．
值得注意的是命令行中的“．”要紧跟在echo后面中间不能有空格，否则“．”将被当作提示信息输出到屏幕。另外“．”可以用，：；”／[\]＋等任一符号替代。
命令echo．输出的回车，经dos管道转向可以作为其它命令的输入，比如echo.|time即相当于在time命令执行后给出一个回车。所以执行时系统会在显示当前时间后，自动返回到dos提示符状态
（6）答复命令中的提问
格式：echo 答复语|命令文件名
上述格式可以用于简化一些需要人机对话的命令（如：chkdsk／f；format drive:；del *.*）的操作，它是通过dos管道命令把echo命令输出的预置答复语作为人机对话命令的输入。下面的例子就相当于在调用的命令出现人机对话时输入“y”回车：
c:>echo y|chkdsk/f
c:>echo y|del a :*.*
（7）建立新文件或增加文件内容
格式：echo 文件内容>文件名
echo 文件内容>>文件名
例如：
c:>echo @echo off>autoexec.bat 建立自动批处理文件
c:>echo c:\cpav\bootsafe>>autoexec.bat 向自动批处理文件中追加内容
（8）向打印机输出打印内容或打印控制码
格式：echo 打印机控制码>prn
echo 打印内容>prn
用得很少，了解就可以了
下面的例子是向m－1724打印机输入打印控制码。＜alt＞156是按住alt键在小键盘键入156，类似情况依此类推：
c:>echo +156+42+116>prn（输入下划线命令fs＊t）
c:>echo prn">+155@>prn（输入初始化命令esc@）
c:>echo.>prn（换行）
（9）使喇叭鸣响
c:>echo ^g
“^g”是在dos窗口中用ctrl＋g或alt＋007输入，输入多个^g可以产生多声鸣响。使用方法是直接将其加入批处理文件中或做成批处理文件调用。
这里的“^g”属于特殊符号的使用，请看本文后面的章节
3、pause 暂停
pause，玩游戏的人都知道，暂停的意思
在这里就是停止系统命令的执行并显示下面的内容。
例：
运行显示：
要显示其他提示语，可以这样用：
echo 其他提示语 & pause > nul
4、errorlevel 程序返回码
echo %errorlevel%
每个命令运行结束，可以用这个命令行格式查看返回码
用于判断刚才的命令是否执行成功
默认值为0，一般命令执行出错会设 errorlevel 为1
5、title 设置cmd窗口的标题
设置cmd窗口的标题，批处理编程常用。
title 新标题 #可以看到cmd窗口的标题栏变了
6、color 设置cmd窗口前景和背景颜色
设置默认的控制台前景和背景颜色。批处理编程常用。
color [attr]
attr 指定控制台输出的颜色属性
颜色属性由两个十六进制数字指定 -- 第一个为背景，第二个则为
前景。每个数字可以为以下任何值之一:
0 = 黑色 8 = 灰色
1 = 蓝色 9 = 淡蓝色
2 = 绿色 a = 淡绿色
3 = 湖蓝色 b = 淡浅绿色
4 = 红色 c = 淡红色
5 = 紫色 d = 淡紫色
6 = ××× e = 淡×××
7 = 白色 f = 亮白色
如果没有给定任何参数，该命令会将颜色还原到 cmd.exe 启动时
的颜色。这个值来自当前控制台窗口、/t 开关或
defaultcolor 注册表值。
如果用相同的前景和背景颜色来执行 color 命令，color 命令
会将 errorlevel 设置为 1。
例如: "color fc" 在亮白色上产生亮红色
7、mode 配置系统设备
配置系统设备。
串行口: mode comm[:] [baud=b] [parity=p] [data=d] [stop=s]
[to=on|off] [xon=on|off] [odsr=on|off]
[octs=on|off] [dtr=on|off|hs]
[rts=on|off|hs|tg] [idsr=on|off]
设备状态: mode [device] [/status]
打印重定向: mode lptn[:]=comm[:]
选定代码页: mode con[:] cp select=yyy
代码页状态: mode con[:] cp [/status]
显示模式: mode con[:] [cols=c] [lines=n]
击键率: mode con[:] [rate=r delay=d]
例：设置dos窗口和颜色
mode con cols=113 lines=15 & color 9f
此命令设置dos窗口大小：15行，113列
8、goto 和 :
goto会点编程的朋友就会知道这是跳转的意思。
在批处理中允许以“:xxx”来构建一个标号，然后用goto xxx跳转到标号:xxx处，然后执行标号后的命令。
if {%1}=={} goto noparms
if "%2"=="" goto noparms
标签的名字可以随便起，但是最好是有意义的字符串啦，前加个冒号用来表示这个字符串是标签，goto命令就是根据这个冒号（:）来寻找下一步跳到到那里。最好有一些说明这样你别人看起来才会理解你的意图啊。
:start
set /a var+=1
echo %var%
if %var% leq 3 goto start
1
2
3
4
休息一下
----------------------------
遭遇失事的外星人
来无影去无踪的ufo困扰了人类很长时间。可现在人们发现，功能特异的外星人也会有失事的时候。前苏联科学家杜朗诺克博士曾透露，1987年11月，一支前苏联沙漠考察队在沙漠里发现了一个直径22.87米的碟状飞行器。飞碟引擎保持完好，里面有14具已经风干成木乃伊的外星人遗体。1947年7月6日夜，美国新墨西哥州小镇罗兹维尔附近风雨大作，电闪雷鸣。第二天天睛后，人们发现了一个圆形的东西躺在草丛里。驻扎在附近的空军迅速赶来，封锁了现场。负责人马赛尔上尉详细地检查了该物体的状况。它直径足有10米，分为内、外两个舱。令他大吃一惊的是，舱内的座椅上竟然有4具类人生物的尸体。它们身高仅有1米左右，皮肤白而细腻，头很大，鼻子很长，嘴很小。手上只有4个指头，指间有蹼相连。它们身穿黑色有金属光泽的外套，但是质地很柔软。这一发现震惊了军方，五角大楼立即下令封锁消息，但消息灵通的记者已经将此新闻发布了出去。许多当地人都证实确实有飞碟在罗兹维尔附近坠毁。
————选自《世界未解之谜》
9、find 在文件中搜索字符串
在文件中搜索字符串。
find [/v] [/c] [/n] [/i] [/off[line]] "string" [[drive:][path]filename[ ...]]
/v 显示所有未包含指定字符串的行。
/c 仅显示包含字符串的行数。
/n 显示行号。
/i 搜索字符串时忽略大小写。
/off[line] 不要跳过具有脱机属性集的文件。
"string" 指定要搜索的文字串，
[drive:][path]filename
指定要搜索的文件。
如果没有指定路径，find 将搜索键入的或者由另一命令产生的文字。
find常和type命令结合使用
type [drive:][path]filename | find "string" [>tmpfile] #挑选包含string的行
type [drive:][path]filename | find /v "string" #剔除文件中包含string的行
type [drive:][path]filename | find /c #显示文件行数
以上用法将去除find命令自带的提示语（文件名提示）
echo 111 >test.txt
echo 222 >>test.txt
find "111" test.txt
运行显示如下：
---------- test.txt
111
type test.txt|find "111"
学习久了，容易瞌睡，清醒清醒，请看：
月球上有轰炸机吗
1987年3月，前苏联的一颗人造卫星拍摄到的月球照片上，出现了一架第二次世界大战时期的英国轰炸机。这架飞机机身和机翼上有明显的英国空军标志，飞机有些地方已被陨石损坏，但机体完整，机身上布满青苔。它停放在月球的火山口上。照片清晰，令人不容置疑。消息传出后，立即成为轰动世界的头号新闻。但是，正当科学家们紧锣密鼓地展开研究时，1988年7月22日，负责观察的人报告说：这架轰炸机失踪，在原来的地方没有发现它的影子。轰炸机的突然出现，又忽然间消失得无影无踪，引起了科学家们的种种猜测。有人开始怀疑前苏联人造卫星拍到的照片上根本没有什么轰炸机，但是拿来照片重新细看，它明明清清楚楚地呈现在人们面前，到底是不是真事？那么现在它又在哪里？这给本来就很神秘的这架轰炸机又增添了更为神秘的色彩。
10、start 调用外部程序并任其在新窗口自行运行
批处理中调用外部程序的命令（该外部程序在新窗口中运行，批处理程序继续往下执行，不理会外部程序的运行状况），如果直接运行外部程序则必须等外部程序完成后才继续执行剩下的指令
例：start explorer d:\
调用图形界面打开d盘
11、assoc 和 ftype
文件关联，不常用。
assoc 设置'文件扩展名'关联，关联到'文件类型'
ftype 设置'文件类型'关联，关联到'执行程序和参数'
当你双击一个.txt文件时，windows并不是根据.txt直接判断用 notepad.exe 打开
而是先判断.txt属于 txtfile '文件类型'
再调用 txtfile 关联的命令行 txtfile=%systemroot%\system32\notepad.exe %1
可以在"文件夹选项"→"文件类型"里修改这2种关联
assoc #显示所有'文件扩展名'关联
assoc .txt #显示.txt代表的'文件类型'，结果显示 .txt=txtfile
assoc .doc #显示.doc代表的'文件类型'，结果显示 .doc=word.document.8
assoc .exe #显示.exe代表的'文件类型'，结果显示 .exe=exefile
ftype #显示所有'文件类型'关联
ftype exefile #显示exefile类型关联的命令行，结果显示 exefile="%1" %*
assoc .txt=word.document.8
设置.txt为word类型的文档，可以看到.txt文件的图标都变了
assoc .txt=txtfile
恢复.txt的正确关联
ftype exefile="%1" %*
恢复 exefile 的正确关联
如果该关联已经被破坏，可以运行 command.com ，再输入这条命令
12、pushd 和 popd
pushd [path | ..] 保存当前目录，然后切换到另一个指定的目录path。
popd 将当前目录恢复为pushd命令保存的目录
c: & cd\ & md mp3 #在 c:\ 建立 mp3 文件夹
md d:\mp4 #在 d:\ 建立 mp4 文件夹
cd /d d:\mp4 #更改当前目录为 d:\mp4，cd命令的/d参数可改变盘符。
pushd c:\mp3 #保存当前目录，并切换当前目录为 c:\mp3
popd #恢复当前目录为刚才保存的 d:\mp4
一般用处不大，在当前目录名不确定时，会有点帮助。（dos编程中很有用）
13、call 调用批处理程序或命令并等待其执行完毕
call命令可以在批处理执行过程中调用另一个批处理，当另一个批处理执行完后，再继续执行原来的批处理
call command
调用一条批处理命令，和直接执行命令效果一样，特殊情况下很有用，比如变量的多级嵌套，见教程后面。在批处理编程中，可以根据一定条件生成命令字符串，用call可以执行该字符串，见例子。
call [drive:][path]filename [batch-parameters]
调用的其它批处理程序。filename 参数必须具有 .bat 或 .cmd 扩展名。
call :label arguments
调用本文件内命令段，相当于子程序。被调用的命令段以标签:label开头
以命令goto :eof结尾。
另外，批脚本文本参数参照(%0、%1、等等)已如下改变:
批脚本里的 %* 指出所有的参数(如 %1 %2 %3 %4 %5 ...)
批参数(%n)的替代已被增强。您可以使用以下语法:（看不明白的直接运行后面的例子）
%~1 - 删除引号(")，扩充 %1
%~f1 - 将 %1 扩充到一个完全合格的路径名
%~d1 - 仅将 %1 扩充到一个驱动器号
%~p1 - 仅将 %1 扩充到一个路径
%~n1 - 仅将 %1 扩充到一个文件名
%~x1 - 仅将 %1 扩充到一个文件扩展名
%~s1 - 扩充的路径指含有短名
%~a1 - 将 %1 扩充到文件属性
%~t1 - 将 %1 扩充到文件的日期/时间
%~z1 - 将 %1 扩充到文件的大小
%~$path : 1 - 查找列在 path 环境变量的目录，并将 %1
扩充到找到的第一个完全合格的名称。如果环境
变量名未被定义，或者没有找到文件，此组合键会
扩充到空字符串
可以组合修定符来取得多重结果:
%~dp1 - 只将 %1 扩展到驱动器号和路径
%~nx1 - 只将 %1 扩展到文件名和扩展名
%~dp$path:1 - 在列在 path 环境变量中的目录里查找 %1，
并扩展到找到的第一个文件的驱动器号和路径。
%~ftza1 - 将 %1 扩展到类似 dir 的输出行。
在上面的例子中，%1 和 path 可以被其他有效数值替换。
%~ 语法被一个有效参数号码终止。%~ 修定符不能跟 %*使用
注意：参数扩充时不理会参数所代表的文件是否真实存在，均以当前目录进行扩展
要理解上面的知识，下面的例子很关键。
echo 产生一个临时文件 > tmp.txt
rem 下行先保存当前目录，再将c:\windows设为当前目录
pushd c:\windows
call :sub tmp.txt
rem 下行恢复前次的当前目录
popd
del tmp.txt
exit
:sub
echo 删除引号： %~1
echo 扩充到路径： %~f1
echo 扩充到一个驱动器号： %~d1
echo 扩充到一个路径： %~p1
echo 扩充到一个文件名： %~n1
echo 扩充到一个文件扩展名： %~x1
echo 扩充的路径指含有短名： %~s1
echo 扩充到文件属性： %~a1
echo 扩充到文件的日期/时间： %~t1
echo 扩充到文件的大小： %~z1
echo 扩展到驱动器号和路径：%~dp1
echo 扩展到文件名和扩展名：%~nx1
echo 扩展到类似 dir 的输出行：%~ftza1
echo.
goto :eof
set aa=123456
set cmdstr=echo %aa%
echo %cmdstr%
call %cmdstr%
本例中如果不用call，而直接运行%cmdstr%，将显示结果%aa%，而不是123456
14、shift
更改批处理文件中可替换参数的位置。
shift [/n]
如果命令扩展名被启用，shift 命令支持/n 命令行开关；该命令行开关告诉
命令从第 n 个参数开始移位；n 介于零和八之间。例如:
shift /2
会将 %3 移位到 %2，将 %4 移位到 %3，等等；并且不影响 %0 和 %1。
枯燥的学习让人烦躁，休息一下，请看：
----------------
神奇的“海底人”
几十年来，高级生物在地球各大水域出现的传闻层出不穷，一些科学家推测，海底可能有高度文明的生物存在，即在海洋深处的某些地方可能生活着一些智力高度发达的生命体——“海底人”。在众多传闻之中，最令人惊奇的是1959年初，在波兰丁尼亚港发现的海底人。当时他正筋疲力尽地走在沙滩上，人们把他送到附近的学校医院进行治疗时，发现这古怪的病人穿着没有开口的金属衣裳，此人的手指和脚趾与普通人不同，他的血液循环系统和器官并非人类所有。当人们打算对他进一步研究时，这个怪人突然之间杳如黄鹤，一去不复返。
15、if
if 条件判断语句，语法格式如下：
if [not] errorlevel number command
if [not] string1==string2 command
if [not] exist filename command
下面逐一介绍，更详细的分析请看后面章节。
(1) if [not] errorlevel number command
if errorlevel这个句子必须放在某一个命令的后面，执行命令后由if errorlevel 来判断命令的返回值。
number的数字取值范围0~255，判断时值的排列顺序应该由大到小。返回的值大于等于指定的值时，条件成立
dir c:
rem退出代码为>=1就跳至标题1处执行，>=0就跳至标题0处执行
if errorlevel 1 goto 1
if errorlevel 0 goto 0
rem 上面的两行不可交换位置，否则失败了也显示成功。
:0
echo 命令执行成功！
rem 程序执行完毕跳至标题exit处退出
goto exit
:1
echo 命令执行失败！
:exit
运行显示：命令执行成功！
(2) if [not] string1==string2 command
string1和string2都为字符的数据，英文内字符的大小写将看作不同，这个条件中的等于号必须是两个（绝对相等的意思），条件成立即执行后面的command
检测当前变量的值做出判断，为了防止字符串中含有空格，可用以下格式
if [not] {string1}=={string2} command
if [not] [string1]==[string2] command
if [not] "string1"=="string2" command
这种写法实际上将括号或引号当成字符串的一部分了，只要等号左右两边一致就行了，比如下面的写法就不行：
if {string1}==[string2] command
(3) if [not] exist filename command
exist filename为文件或目录存在的意思
echo off
if exist autoexec.bat echo 文件存在！
if not exist autoexec.bat echo 文件不存在！
这个批处理大家可以放在c盘和d盘分别执行，看看效果
16、setlocal 与 变量延迟
本条内容引用[英雄出品]的批处理教程：
要想进阶，变量延迟是必过的一关！所以这一部分希望你能认真看。
为了更好的说明问题，我们先引入一个例子。
例1:
@echo off
set a=4
set a=5 & echo %a%
pause
结果：4
解说：为什么是4而不是5呢？在echo之前明明已经把变量a的值改成5了？
让我们先了解一下批处理运行命令的机制：
批处理读取命令时是按行读取的（另外例如for命令等，其后用一对圆括号闭合的所有语句也当作一行），在读取某行命令时，如果其中有变量，则变量值应该取上一行的值。所以在读取命令“set a=5 & echo %a%”时，dos将其预处理为“set a=5 & echo 4”，然后执行。而其中的a=5所做的数值变更，只能在下一命令行才能体现了。
而为了能够及时感知环境变量的动态变化，批处理设计了变量延迟。简单来说，在读取了一条完整的语句之后，不立即对该行的变量赋值，而会在某个单条语句执行之前再进行赋值，也就是说“延迟”了对变量的赋值。
那么如何开启变量延迟呢？变量延迟又需要注意什么呢？举个例子说明一下：
例2:
setlocal enabledelayedexpansion
set a=5 & echo !a!
pause
结果：5
解说：启动了变量延迟，得到了正确答案。变量延迟的启动语句是“setlocal enabledelayedexpansion”，并且变量要用一对叹号“!!”括起来（注意要用英文的叹号），否则就没有变量延迟的效果。
分析一下例2，首先“setlocal enabledelayedexpansion”开启变量延迟，然后“set a=4”先给变量a赋值为4，“set a=5 & echo !a!”这句是给变量a赋值为5并输出（由于启动了变量延迟，所以批处理能够感知到动态变化，即不是先给该行变量赋值，而是在运行过程中给变量赋值，因此此时a的值就是5了）。
再举一个例子巩固一下。
例3:
for /l %%i in (1,1,5) do (
set a=%%i
echo !a!
)
结果：
5
解说：本例开启了变量延迟并用“!!”将变量扩起来，因此得到我们预期的结果。如果不用变量延迟会出现什么结果呢？结果是这样的：
echo 处于关闭状态。
即没有感知到for语句中的动态变化。
提示：在没有开启变量延迟的情况下，某条命令行中的变量改变，必须到下一条命令才能体现。这一点也可以加以利用，看例子。
例4：交换两个变量的值，且不用中间变量
::交换两个变量的值，但是不使用临时变量
set var1=abc
set var2=123
echo 交换前： var1=%var1% var2=%var2%
set var1=%var2%& set var2=%var1%
echo 交换后： var1=%var1% var2=%var2%
交换前： var1=abc var2=123
交换后： var1=123 var2=abc
在代码中，使用 setlocal enabledelayedexpansion 语句来启用变量延迟之后，有得有失：
优点：
(a)、可以在同一语句内部直接使用上一次改变后的变量；
(b)、在echo特殊字符的时候，无须用引号括起来，比如变量的值含有<、>、|等字符的时候，直接使用 echo !str! 就可以了；
缺点：
(a)、会把文本中所有的感叹号抛弃；
(b)、增加代码的复杂度，有时容易出错。
17、attrib 显示或更改文件属性
attrib [+r|-r] [+a|-a] [+s|-s] [+h|-h] [[drive:] [path] filename] [/s [/d]]
+ 设置属性。
- 清除属性。
r 只读文件属性。
a 存档文件属性。
s 系统文件属性。
h 隐藏文件属性。
[drive:][path][filename]
指定要处理的文件属性。
/s 处理当前文件夹及其子文件夹中的匹配文件。
/d 也处理文件夹。
md autorun
attrib +a +s +h autorun
上面的命令将建立文件夹autorun，然后将其设为存档、系统、隐藏属性
18、findstr 在文件中搜索字符串（find增强版）
find命令不能处理文件中超过1024个字符的数据行，此时可用findstr命令。
findstr [/b] [/e] [/l] [/r] [/s] [/i] [/x] [/v] [/n] [/m] [/o] [/f:file]
[/c:string] [/g:file] [/d:dir list] [/a:color attributes] [/off[line]]
strings [[drive:][path]filename[ ...]]
/b 在一行的开始配对模式。
/e 在一行的结尾配对模式。
/l 按字使用搜索字符串。
/r 将搜索字符串作为一般表达式使用。
/s 在当前目录和所有子目录中搜索
匹配文件。
/i 指定搜索不分大小写。
/x 打印完全匹配的行。
/v 只打印不包含匹配的行。
/n 在匹配的每行前打印行数。
/m 如果文件含有匹配项，只打印其文件名。
/o 在每个匹配行前打印字符偏移量。
/p 忽略有不可打印字符的文件。
/off[line] 不跳过带有脱机属性集的文件。
/a:attr 指定有十六进位数字的颜色属性。请见 "color /?"
/f:file 从指定文件读文件列表 (/ 代表控制台)。
/c:string 使用指定字符串作为文字搜索字符串。
/g:file 从指定的文件获得搜索字符串。 (/ 代表控制台)。
/d:dir 查找以分号为分隔符的目录列表
strings 要查找的文字。
指定要查找的文件。
除非参数有 /c 前缀，请使用空格隔开搜索字符串。
例如: 'findstr "hello there" x.y' 在文件 x.y 中寻找 "hello" 或
"there" 。 'findstr /c:"hello there" x.y' 文件 x.y 寻找
"hello there"。
一般表达式的快速参考:
. 通配符: 任何字符
* 重复: 以前字符或类别出现零或零以上次数
^ 行位置: 行的开始
$ 行位置: 行的终点
[class] 字符类别: 任何在字符集中的字符
[^class] 补字符类别: 任何不在字符集中的字符
[x-y] 范围: 在指定范围内的任何字符
\x escape: 元字符 x 的文字用法
\<xyz 字位置: 字的开始
xyz\> 字位置: 字的结束
有关 findstr 常见表达法的详细情况，请见联机命令参考。
大自然中的很多神奇现象令人惊叹不已：
神奇的龙卷风
龙卷风外貌奇特，它上部是一块乌黑或浓灰的积雨云，下部是下垂着的形如大象鼻子的漏斗状云柱，具有小、快、猛、短的特点。龙卷风通常是极其迅速的，风速一般每秒50米至100米，有时可达每秒300米，甚至超过声速（340米/秒）。它像一个巨大的吸尘器，经过地面，地面的一切都要被它卷走；经过水库、河流，常卷起冲天水柱，有时连水库、河流的底部都露了出来。同时，龙卷风维持时间一般很短，往往只有几分钟或几十分钟，最多几小时，一般移动10米到10千米，便“寿终正寝”了。龙卷风还有一些“古怪行为”，使人难以捉摸。它席卷城镇，捣毁房屋，把碗橱从一个地方刮到另一个地方，却没有打碎碗橱里的一个碗；吓呆了的人们常常被它抬向高空，然后又被它平平安安地送回地面；有时它拔去一只鸡一侧的毛，而另一侧却完好无损；它将百年古松吹倒并拧成麻花状，而近旁的小杨树连一根枝条都未受到折损。人们对龙卷风的形成及后果进行了多年的研究，但还有很多谜底没有被揭开。
19、date /t 和 time /t
date /t 直接显示当前日期，可用来提取或显示日期。
time /t 直接显示当前时间，可用来提取或显示时间。
第二节 常用特殊符号
1、@ 命令行回显屏蔽符
2、% 批处理变量引导符
3、> 输出重定向符
4、>> 输出重定向符
5、<、>&、<& 重定向符
6、| 命令管道符
7、^ 转义字符
8、& 组合命令（顺序执行）
9、&& 组合命令（前面指令成功，才执行后面指令）
10、|| 组合命令（前面指令失败，才执行后面指令）
11、"" 字符串界定符
12、, 逗号
13、; 分号
14、() 括号
15、! 感叹号
16、批处理中可能会见到的其它特殊标记符: （略）
cr(0d) 命令行结束符
escape(1b) ansi转义字符引导符
space(20) 常用的参数界定符
tab(09) ; = 不常用的参数界定符
+ copy命令文件连接符
* ? 文件通配符
/ 参数开关引导符
: 批处理标签引导符
废话少说，开讲了
1、@ 命令行回显屏蔽符
这个字符在批处理中的意思是关闭当前行的回显。我们从前几课知道
echo off可以关闭掉整个批处理命令的回显，但不能关掉echo off这个命令，现在我们在echo off这个命令前加个@，就可以达到所有命令均不回显的要求
2、% 批处理变量引导符
这个百分号严格来说是算不上命令的，它只是批处理中的参数而已（多个%一起使用的情况除外，以后还将详细介绍）。
引用变量用%var%，调用程序外部参数用%1至%9等等
%0 %1 %2 %3 %4 %5 %6 %7 %8 %9 %*为命令行传递给批处理的参数
%0 批处理文件本身，包括完整的路径和扩展名
%1 第一个参数
%9 第九个参数
%* 从第一个参数开始的所有参数
参数%0具有特殊的功能，可以调用批处理自身，以达到批处理本身循环的目的，也可以复制和删除文件自身等等。
例：最简单的复制文件自身的方法
copy %0 d:\wind.bat
小技巧：添加行内注释
%注释内容%（可以用作行内注释，不能出现重定向符号和管道符号）
为什么这样呢？此时“注释内容”其实被当作变量，其值是空的，故只起注释作用，不过这种用法容易出现语法错误，一般不用。
3、> 输出重定向符
输出重定向命令
这个字符的意思是传递并且覆盖，他所起的作用是将运行的结果传递到后面的范围（后边可以是文件，也可以是默认的系统控制台）
在nt系列命令行中，重定向的作用范围由整个命令行转变为单个命令语句，受到了命令分隔符&,&&,||和语句块的制约限制。
比如：
使用命令：echo hello >1.txt将建立文件1.txt，内容为”hello “（注意行尾有一空格）
使用命令：echo hello>1.txt将建立文件1.txt，内容为”hello“（注意行尾没有空格）
4、>> 输出重定向符
这个符号的作用和>有点类似，但他们的区别是>>是传递并在文件的末尾追加，而>是覆盖
用法同上
同样拿1.txt做例子
使用命令：
echo hello > 1.txt
echo world >>1.txt
这时候1.txt 内容如下:
hello
world
5、<、>&、<& 重定向符
这三个命令也是管道命令，但>&、<&一般不常用，你只需要知道一下就ok了，当然如果想仔细研究的话，可以自己查一下资料。(本人已查过，网上也查不到相关资料)
<，输入重定向命令，从文件中读入命令输入，而不是从键盘中读入。
echo 2005-05-01>temp.txt
set /p today=<temp.txt
echo %today%
del temp.txt
2005-05-01
>&，将一个句柄的输出写入到另一个句柄的输入中。
<&，刚好和>&相反，从一个句柄读取输入并将其写入到另一个句柄输出中。
常用句柄：0、1、2，未定义句柄：3—9
1>nul 表示禁止输出正确的信息
2>nul 表示禁止输出错误信息。
其中的1与2都是代表某个数据流输入输出的地址（nt cmd 称之为句柄，msdos称之为设备）。
句柄0：标准输入stdin，键盘输入
句柄1：标准输出stdout，输出到命令提示符窗口（console，代码为con）
句柄2：标准错误stderr，输出到命令提示符窗口（console，代码为con）
其中的stdin可被<重定向，stdout可被>、>>重定向。
我们已经知道读取文本中的内容可以用for命令，但如果只需要读取第一行用for命令就有点麻烦。简单的办法如下:
set /p str=<%0
echo %str%
运行显示批处理文件自身的第一行：@echo off
![常见DOS命令1[图]](data:image/gif;base64,R0lGODlhAQABAIAAAP///wAAACwAAAAAAQABAAACAkQBADs=)