neo4j之cypher使用文檔

Cypher是圖形資料庫Neo4j的聲明式查詢語言。

Cypher語句規則和具備的能力:

Cypher通過模式比對圖資料庫中的節點和關系，來提取資訊或者修改資料。

Cypher語句中允許使用變量，用來表示命名、綁定元素和參數。

Cypher語句可以對節點、關系、标簽和屬性進行建立、更新和删除操作。

Cypher語句可以管理索引和限制。

運算符

正常運算 DISTINCT, ., []

算數運算 +, -, *, /, %, ^

比較運算 =, <>, <, >, <=, >=, IS NULL, IS NOT NULL

邏輯運算 AND, OR, XOR, NOT

字元串操作 +

List操作 +, IN, [x], [x .. y]

正則操作 =~

字元串比對 STARTS WITH, ENDS WITH, CONTAINS

語句

1.建立節點語句

例子1:建立節點并給節點配置設定一個屬性

CREATE (n {name:"張三"})

例子2:批量建立節點并且配置設定屬性

UNWIND [{name:"李四"},{name:"張三"}] AS mynodes CREATE (n) SET n = mynodes

例3:建立節點時配置設定屬性和标簽

CREATE ( n:Person{name:"李四"} )

例4:建立一個關系，給兩個節點建立關系指定關系類型、方向和綁定一個變量。

CREATE ({name:"李四"})-[r:have]->({bookname:"設計模式"})

例5:建立兩個節點同時建立一個關系，給兩個節點建立關系指定關系類型、方向和屬性。

CREATE ({name:"李四"})-[:LOVES{since:"2017"}]->({name:"小花"})

例6:給已經存在的兩個節點建立一個關系。

MATCH (a:Person),(b:Person) WHERE a.name = '張三' AND b.name = 李四' CREATE (a)-[r:FRIEND]->(b) RETURN r

2.比對語句

Cypher的MATCH語句和SQL的SELECT語句類似,都是查詢資料的表達式.而Cypher語句中的WHERE和SQL語句中的WHERE語句由這相同的作用,其作用是用來過濾比對結的,在Cypher語句中WHERE是在MATCH、OPTIONAL MATCH、WITH或START語句中使用的過濾限定語句

比對語句結構

[MATCH WHERE]

[OPTIONAL MATCH WHERE]

[WITH [ORDER BY] [SKIP] [LIMIT]]

RETURN [ORDER BY] [SKIP] [LIMIT]

例1:根據屬性比對節點資訊。

MATCH (n{name:"張三"}) RETURN n

例2:根據标簽和屬性比對節點資訊。

MATCH (n:Person{name:"李四"}}) RETURN n

例3:任意比對，傳回任意節點資訊。

Cypher語句允許任意比對，任意比對可以比對任何與cypher表達式相符合的所有節點.

1.比對任意節點

//該語句會比對任意節點，并傳回

MATCH (n) RETURN n

2.任意關系

//該語句是比對出有任意關系的兩個節點

MATCH p = (n)-[r]->(m) RETURN p

3.可選比對

//比對結果集中如果有丢的部分，則會用null來補充

OPTIONAL MATCH (n)-[r]->(m) RETURN m

例4:比對節點時指定标簽、屬性和關系類型

MATCH (n:Person)-[:FRIEND]->(m:Person) WHERE n.name = '張三'

例5:根據标簽過濾

//從圖資料庫中,過濾出Person标簽

MATCH (n) WHERE n:Person RETURN n

例6:根據節點屬性過濾

MATCH (n) WHERE n.name = "李思思" RETURN n

例7:根據關系屬性過濾

MATCH (n)-[k:KNOWS]->(f) WHERE k.since < 2000 RETURN f

例8:字元串比對

字元串首尾可以使用STARTS WITH 和 ENDS WITH,去比對定位字元串，字元串比對還可以使用AONTAINS來比對字元串中包含的自字元串。

1.比對字元串的開頭

比對圖中的所有節點，傳回節點中包含name屬性，且屬性值以”張”開頭的所有節點

MATCH (n) WHERE n.name STARTS WITH '張' RETURN n

2.比對字元串的末尾

比對圖中的所有節點，傳回節點中包含name屬性，且屬性值以”三”開頭的所有節點

MATCH (n) WHERE n.name ENDS WITH '三' RETURN n

3.比對字元串的包含比對

比對圖中的所有節點，傳回節點中包含name屬性，且屬性值中任意位置包含”小”字元串的節點

MATCH (n) WHERE n.name CONTAINS '三' RETURN n

4.字元串排除比對

在字元串比對的時候可以使用NOT關鍵字來排除比對到的結果，得到相反的結果

//比對圖中的所有節點，傳回節點中包含name屬性，且不是姓張的所有節點

MATCH (n) WHERE NOT n.name STARTS WITH '張' RETURN n

例9:字元串正規表達式

Cypher支援使用正規表達式進行過濾。 正規表達式文法從Java正規表達式繼承過來的。這包括支援改變字元串比對的标志，包括不區分大小寫(?i)，多行(?m)和逗點(?s),在這裡正規表達式使用的解析符号是=~。

1.模糊比對，類似sql語句中的like

//類似like ‘%小%’

MATCH (n) WHERE n.name =~ '.*小.*' RETURN n

2.不去分大小寫正則比對

//不區分大小寫比對，名字中以”ANDR”開頭的節點

MATCH (n) WHERE n.name =~ '(?i)ANDR.*' RETURN n

例10:WHERE句子中使用路徑比對

1.使用邏輯運算符号和路徑作為過濾條件

//在圖中比對名稱為”李四”或”王五”與”張三”有任何關系的節點，并傳回符合比對條件的節點資訊

MATCH (n { name: '張三' }),(m) WHERE m.name IN ['李四', '王五'] AND (n)<--(m) RETURN m

2.關系比對使用NOT邏輯運算符号

//比對和張三沒有關系的人

MATCH (persons),(zhangsan { name: '張三' }) WHERE NOT (persons)-->(zhangsan) RETURN persons

3.關系類型比對，并使用正規表達式

//在圖中比對張三節點和所有節點的關系類型以F開頭的所有關系

MATCH (n)-[r]->() WHERE n.name='張三' AND type(r)=~ 'F.*' RETURN r

例11:使用”或”邏輯比對關系

//傳回任意關系為KNOWS和LOVES的所有節點關系

MATCH p=(n)-[:KNOWS|:LOVES]->(m) RETURN p

例12:關系深度比對

1.比對從n到m，任意關系，深度1到5的節點

MATCH p=(n)-[*1..5]->(m) RETURN p

2.比對從n到m，任意關系、任意深度的節點

MATCH p=(n)-[*]->(m) RETURN p

例13:比對分頁傳回

MATCH (n) WHERE n.productName='蘋果' RETURN n SKIP 10 LIMIT 10

例14:比對去重傳回

MATCH (n) WHERE n.productName='蘋果' RETURN DISTINCT n

例15:比對分組傳回值

MATCH (n) WHERE n.productName='蘋果' RETURN n ORDER BY n.price DESC

例16:别名傳回

MATCH (n) WHERE n.productName=~'.*蘋果.*' RETURN n.productName AS name

例17:WITH語句使用使用示例

WITH語句是将第一部分比對的輸出作為下一部分比對的輸入。

1.查找有十個以上朋友的張姓男子

MATCH (user)-[:FRIEND]-(friend) WHERE user.name =~ '張.*' WITH user, count(friend) AS friends WHERE friends > 10 RETURN user

2.WITH語句中使用ORDER BY、SKIP 和 LIMIT 語句示例。

MATCH (user)-[:FRIEND]-(friend) WITH user, count(friend) AS friends ORDER BY friends DESC SKIP 1 LIMIT 3 RETURN user

例17:UNION語句使用使用示例

1.使用UNION結果去重，求并集

MATCH (a)-[:KNOWS]->(b) RETURN b.name UNION MATCH (a)-[:LOVES]->(b) RETURN b.name

2.使用UNION ALL結果不去重, 求和集

MATCH (a)-[:KNOWS]->(b) RETURN b.name UNION ALL MATCH (a)-[:LOVES]->(b) RETURN b.name

例17:start語句比對節點資訊

1.比對所有節點

START n=node(*) RETURN n

2.根據節點的具體id比對

//在node函數中的值，是節點在圖中的id

START n=node(1) RETURN n

3.節點更新和删除

例1:更新和添加一個屬性

//1.建立一個節點，隻有一個屬性name=’張三’

CREATE ({name:'張三'})

//2.給建立的”張三”節點，添加一個屬性age=20，修改name屬性值為”李四”

MATCH (n {name:'張三'}) SET n.name='李四' SET n.age=20 RETURN n

例2: 修改節點資訊,覆寫節點屬性

//該語句會直接删除掉name屬性，新增age屬性

MATCH (n {name:'張三'}) SET n={age:20}

例3:修改節點資訊,新增節點屬性

//該語句不會删除掉name屬性，而是在節點中新增age屬性

MATCH (n {name:'張三'}) SET n += {age:20} RETURN n

例4:删除節點屬性

MATCH (n{name:'張三'}) remove n.age RETURN n

例5:為節點添加新标簽

//添加一個标簽

MATCH (n{name:'張三'}) SET n:Person RETURN n

//添加多個标簽

MATCH (n{name:'張三'}) SET n:Person:Student RETURN n

例6:删除節點标簽

MATCH (n{name:'張三'}) REMOVE n:Person RETURN n

例7:為已經存在的兩個節點添加關系

MATCH (a:Person {name: "張三"}), (b:Person {name: "李四"}) MERGE (a)-[r:FRIENDS]->(b)

例8:比對一個節點，更新屬性如果屬性不存在則建立該屬性

MERGE (n:Person {name: "張三"}) ON CREATE SET n.created = timestamp() ON MATCH SET n.counter = coalesce(n.counter, 0) + 1, n.accessTime = timestamp()

例9:比對一個節點為他建立一個新的關系

//如果沒有”王五”節點則建立一個新的

MATCH (a:Person {name: "張三"}) MERGE (a)-[r:KNOWS]->(b:Person {name: "王五"})

例10:删除一個節和關系

MATCH (a)-[r:KNOWS]->(b) DELETE r,b

例11:級聯删除

//删除”王五”節點之後，将與王五節點建立關系也删除掉

MATCH (n{name: "王五"}) DETACH DELETE n

4.索引和限制

例1:建立索引

//為”Person”标簽的name屬性建立索引

CREATE INDEX ON :Person(name)

例2:删除索引

//删除”Person”标簽的name屬性的索引

DROP INDEX ON :Person(name)

例3:比對條件中使用索引

MATCH (n:Person) WHERE n.name = 'Andres' RETURN n

例4:建立節點屬性唯一限制

建立一個唯一限制保證圖資料庫中同一個标簽内的節點的屬性值不重複。

注意：不可以為已經建立索引的屬性建立唯一限制

CREATE CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE

例5:建立節點屬性唯一限制

DROP CONSTRAINT ON (n:Person) ASSERT n.name IS UNIQUE