spring boot項目打包的腳步，安裝、打包、釋出工具.bat

@ECHO OFF&PUSHD %~DP0 &TITLE 安裝、打包、釋出工具
:: mode con cols=200 lines=40
:: color 2F

:Menu
Cls
@ echo.
@ echo.  菜單選項：
@ echo.
@ echo.   1.清理
@ echo.
@ echo.   2.安裝本地倉庫
@ echo.
@ echo.   3.打包
@ echo.  
@ echo.   4.生成javadoc(應用在工具類)
@ echo. 
@ echo.   5.釋出(釋出是應用在工具類、核心jar、基礎子產品)
@ echo. 
@ echo.   6.更新版本
@ echo. 
@ echo. 
@ echo.   提示：執行選項報錯請先檢查maven環境變量是否配置正确，請mvn -version檢查maven是否正确安裝，謝謝!
@ echo. 
@ echo.   提示：釋出失敗請檢查是否配置私服釋出的賬号在settings.xml中
@ echo.  
@ echo.  
@ echo.
@ echo.  
@ echo.
set /p xj= 輸入數字按回車：
if /i "%xj%"=="1" Goto Clean
if /i "%xj%"=="2" Goto Install
if /i "%xj%"=="3" Goto Package
if /i "%xj%"=="4" Goto Javadoc
if /i "%xj%"=="5" Goto Deploy
if /i "%xj%"=="6" Goto Version
@ echo.
echo 　　    選擇無效...請重新輸入...
ping -n 2 127.1>nul
goto menu

:: 清除
:Clean
@ echo.
echo  正在清理生成檔案...
call mvn clean -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  清理完成
@ echo.
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu

:: 安裝
:Install
@ echo.
echo  正在清理原生成檔案...
call mvn clean -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  正在清理中，請稍等...
@ echo.
echo  開始安裝到本地倉庫中，請稍等...
call mvn install -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  安裝到本地倉庫完成
@ echo.
@ echo. 
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu

:: 打包
:Package
@ echo.
echo  正在清理原生成檔案...
call mvn clean -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  正在清理中，請稍等...
@ echo.
echo  開始打包生成檔案中，請稍等...
call mvn package -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  打包生成檔案完成
@ echo.
@ echo. 
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu

:: 生成Javadoc文檔
:Javadoc
@ echo.
echo  開始生成Javadoc文檔...
call mvn clean source:jar javadoc:javadoc install -Dmaven.test.skip=false -Dmaven.javadoc.skip=false
@ echo.
echo  生成Javadoc文檔完成
@ echo.
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu

:: 釋出
:Deploy
@ echo.
echo  正在清理原生成檔案...
call mvn clean -Dmaven.test.skip=true -Dmaven.javadoc.skip=true
@ echo.
echo  正在清理中，請稍等...
@ echo.
echo  開始釋出到中央倉庫中，請稍等...
call mvn deploy -Dmaven.test.skip=true -Dmaven.javadoc.skip=false
@ echo.
echo  釋出到中央倉庫完成
@ echo.
@ echo. 
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu


:: 更新版本
:Version
@ echo.
set /p version=請輸入版本号:
echo 提示：需要更新的新版本号為：%version%
call mvn versions:set -DnewVersion=%version%
set /p var=請确認是否更新到 %version% 版本(y:确認、n:撤回):
if %var% EQU y (
echo 開始送出版本号為%version%
@ echo.
call mvn versions:commit
@ echo.
echo 已送出版本号為%version%
)
if %var% EQU n (
echo 開始撤回到原版本号
@ echo.
call mvn versions:revert
@ echo.
echo 已撤回到原版本号
)
echo  請按鍵任意鍵傳回菜單選項
pause > nul
ping -n 2 140.1>nul
goto menu
           

打包的批處理，可以互相學習。