目錄
- 啟動流程
- 代碼詳解
- 啟動檔案使用的 ARM 彙編指令彙總
- 關于與啟動檔案有關的一些問題思考
下面是F1固件庫V3.5.0的啟動檔案startup_stm32f10x_hd.s,以此為例做解析,其餘的型号的啟動檔案都差不多,主要差別在于因片上外設不同,支援的中斷就不一樣,是以在啟動檔案的中斷向量表不同型号會有差别。
啟動流程
啟動檔案由彙編編寫,是系統上電複位後第一個執行的程式。主要做了以下工作:
1、初始化堆棧指針 SP=_initial_sp
2、初始化 PC指針=Reset_Handler
3、初始化中斷向量表
4、配置系統時鐘
5、調用 C庫函數_main 初始化使用者堆棧,進而最終調用 main 函數去到 C的世界
代碼詳解
下面是用于KEIL中啟動檔案,加入了較詳細的注釋:
; 配置設定給堆棧的記憶體量(以位元組為機關)
; 根據應用程式的需要定制此值
; <h> Stack Configuration 棧配置
; <o> Stack Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>
Stack_Size EQU 0x00000400 ;類似于:#define Stack_Size 0x00000400
AREA STACK, NOINIT, READWRITE, ALIGN=3 ;僞指令AREA,表示名字為 STACK,NOINIT 即不初始化,可讀可寫,8(2^3)位元組對齊。
Stack_Mem SPACE Stack_Size ;開辟一段大小為Stack_Size的記憶體空間作為棧,Stack_Size已經定義為了0x00000400(1KB)
__initial_sp ;标号__initial_sp緊挨着SPACE語句放置,表示棧的結束位址,即棧頂位址,棧是由高向低生長的。
; <h> Heap Configuration 堆配置
; <o> Heap Size (in Bytes) <0x0-0xFFFFFFFF:8>
; </h>
Heap_Size EQU 0x00000200 ;類似于:#define Heap_Size 0x00000200
AREA HEAP, NOINIT, READWRITE, ALIGN=3 ;僞指令AREA,表示名字為 HEAP,NOINIT即不初始化,可讀可寫,8(2^3)位元組對齊
__heap_base ; __heap_base 表示對的起始位址
Heap_Mem SPACE Heap_Size ;開辟堆的大小為 0X00000200(512位元組)
__heap_limit ; __heap_limit 表示堆的結束位址。堆是由低向高生長的,跟棧的生長方向相反
PRESERVE8 ; 指定目前檔案的堆棧按照 8位元組對齊
THUMB ; 表示後面指令相容 THUMB 指令,THUBM 是 ARM 以前的指令集, 16bit,現在 Cortex-M 系列的都使用 THUMB-2 指令集, THUMB-2 是 32 位的,相容 16 位和 32 位的指令,是 THUMB 的超集。
; Vector Table Mapped to Address 0 at Reset
AREA RESET, DATA, READONLY ;定義一個資料段,名字為 RESET,可讀。
EXPORT __Vectors ;聲明 __Vectors、__Vectors_End 和__Vectors_Size這三個标号具有全局屬性,可供外部的檔案調用。
EXPORT __Vectors_End ;EXPORT :聲明一個标号可被外部的檔案使用,使标号具有全局屬性。
EXPORT __Vectors_Size
;__Vectors 為向量表起始位址 DCD: 以字為機關配置設定記憶體,要求 4位元組對齊,并要求初始化這些記憶體
__Vectors DCD __initial_sp ; Top of Stack 棧頂位址MSP
DCD Reset_Handler ; Reset Handler 複位程式位址
DCD NMI_Handler ; NMI Handler
DCD HardFault_Handler ; Hard Fault Handler
DCD MemManage_Handler ; MPU Fault Handler
DCD BusFault_Handler ; Bus Fault Handler
DCD UsageFault_Handler ; Usage Fault Handler
DCD 0 ; Reserved 0表示保留
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD 0 ; Reserved
DCD SVC_Handler ; SVCall Handler
DCD DebugMon_Handler ; Debug Monitor Handler
DCD 0 ; Reserved
DCD PendSV_Handler ; PendSV Handler
DCD SysTick_Handler ; SysTick Handler
; External Interrupts 以下是外部中斷
DCD WWDG_IRQHandler ; Window Watchdog
DCD PVD_IRQHandler ; PVD through EXTI Line detect
DCD TAMPER_IRQHandler ; Tamper
DCD RTC_IRQHandler ; RTC
DCD FLASH_IRQHandler ; Flash
DCD RCC_IRQHandler ; RCC
DCD EXTI0_IRQHandler ; EXTI Line 0
DCD EXTI1_IRQHandler ; EXTI Line 1
DCD EXTI2_IRQHandler ; EXTI Line 2
DCD EXTI3_IRQHandler ; EXTI Line 3
DCD EXTI4_IRQHandler ; EXTI Line 4
DCD DMA1_Channel1_IRQHandler ; DMA1 Channel 1
DCD DMA1_Channel2_IRQHandler ; DMA1 Channel 2
DCD DMA1_Channel3_IRQHandler ; DMA1 Channel 3
DCD DMA1_Channel4_IRQHandler ; DMA1 Channel 4
DCD DMA1_Channel5_IRQHandler ; DMA1 Channel 5
DCD DMA1_Channel6_IRQHandler ; DMA1 Channel 6
DCD DMA1_Channel7_IRQHandler ; DMA1 Channel 7
DCD ADC1_2_IRQHandler ; ADC1 & ADC2
DCD USB_HP_CAN1_TX_IRQHandler ; USB High Priority or CAN1 TX
DCD USB_LP_CAN1_RX0_IRQHandler ; USB Low Priority or CAN1 RX0
DCD CAN1_RX1_IRQHandler ; CAN1 RX1
DCD CAN1_SCE_IRQHandler ; CAN1 SCE
DCD EXTI9_5_IRQHandler ; EXTI Line 9..5
DCD TIM1_BRK_IRQHandler ; TIM1 Break
DCD TIM1_UP_IRQHandler ; TIM1 Update
DCD TIM1_TRG_COM_IRQHandler ; TIM1 Trigger and Commutation
DCD TIM1_CC_IRQHandler ; TIM1 Capture Compare
DCD TIM2_IRQHandler ; TIM2
DCD TIM3_IRQHandler ; TIM3
DCD TIM4_IRQHandler ; TIM4
DCD I2C1_EV_IRQHandler ; I2C1 Event
DCD I2C1_ER_IRQHandler ; I2C1 Error
DCD I2C2_EV_IRQHandler ; I2C2 Event
DCD I2C2_ER_IRQHandler ; I2C2 Error
DCD SPI1_IRQHandler ; SPI1
DCD SPI2_IRQHandler ; SPI2
DCD USART1_IRQHandler ; USART1
DCD USART2_IRQHandler ; USART2
DCD USART3_IRQHandler ; USART3
DCD EXTI15_10_IRQHandler ; EXTI Line 15..10
DCD RTCAlarm_IRQHandler ; RTC Alarm through EXTI Line
DCD USBWakeUp_IRQHandler ; USB Wakeup from suspend
DCD TIM8_BRK_IRQHandler ; TIM8 Break
DCD TIM8_UP_IRQHandler ; TIM8 Update
DCD TIM8_TRG_COM_IRQHandler ; TIM8 Trigger and Commutation
DCD TIM8_CC_IRQHandler ; TIM8 Capture Compare
DCD ADC3_IRQHandler ; ADC3
DCD FSMC_IRQHandler ; FSMC
DCD SDIO_IRQHandler ; SDIO
DCD TIM5_IRQHandler ; TIM5
DCD SPI3_IRQHandler ; SPI3
DCD UART4_IRQHandler ; UART4
DCD UART5_IRQHandler ; UART5
DCD TIM6_IRQHandler ; TIM6
DCD TIM7_IRQHandler ; TIM7
DCD DMA2_Channel1_IRQHandler ; DMA2 Channel1
DCD DMA2_Channel2_IRQHandler ; DMA2 Channel2
DCD DMA2_Channel3_IRQHandler ; DMA2 Channel3
DCD DMA2_Channel4_5_IRQHandler ; DMA2 Channel4 & Channel5
__Vectors_End ; __Vectors_End 為向量表結束位址
__Vectors_Size EQU __Vectors_End - __Vectors ;__Vectors 為向量表起始位址, __Vectors_End 為向量表結束位址,兩個相減即可算出向量表大小。
AREA |.text|, CODE, READONLY ;定義一個名稱為.text 的代碼段,可讀
; Reset handler複位程式
Reset_Handler PROC ;PROC 定義子程式,與 ENDP 成對使用,表示子程式結束
EXPORT Reset_Handler [WEAK] ;WEAK表示弱定義
IMPORT __main ;IMPORT類似于extern,表示__main和SystemInit都來自外部檔案,__main 是一個标準的 C 庫函數,主要作用是初始化使用者堆棧,并在函數的最後調用main 函數去到 C 的世界
IMPORT SystemInit ;SystemInit()是一個标準的庫函數,在system_stm32f10x.c這個庫檔案中定義。主要作用是配置系統時鐘
LDR R0, =SystemInit
BLX R0
LDR R0, =__main
BX R0
ENDP
; Dummy Exception Handlers (infinite loops which can be modified無限循環可以被修改)
NMI_Handler PROC
EXPORT NMI_Handler [WEAK]
B . ;跳轉到一個标号。這裡跳轉到一個‘.’,即表示無線循環
ENDP
HardFault_Handler\
PROC
EXPORT HardFault_Handler [WEAK]
B .
ENDP
MemManage_Handler\
PROC
EXPORT MemManage_Handler [WEAK]
B .
ENDP
BusFault_Handler\
PROC
EXPORT BusFault_Handler [WEAK]
B .
ENDP
UsageFault_Handler\
PROC
EXPORT UsageFault_Handler [WEAK]
B .
ENDP
SVC_Handler PROC
EXPORT SVC_Handler [WEAK]
B .
ENDP
DebugMon_Handler\
PROC
EXPORT DebugMon_Handler [WEAK]
B .
ENDP
PendSV_Handler PROC
EXPORT PendSV_Handler [WEAK]
B .
ENDP
SysTick_Handler PROC
EXPORT SysTick_Handler [WEAK]
B .
ENDP
Default_Handler PROC
EXPORT WWDG_IRQHandler [WEAK]
EXPORT PVD_IRQHandler [WEAK]
EXPORT TAMPER_IRQHandler [WEAK]
EXPORT RTC_IRQHandler [WEAK]
EXPORT FLASH_IRQHandler [WEAK]
EXPORT RCC_IRQHandler [WEAK]
EXPORT EXTI0_IRQHandler [WEAK]
EXPORT EXTI1_IRQHandler [WEAK]
EXPORT EXTI2_IRQHandler [WEAK]
EXPORT EXTI3_IRQHandler [WEAK]
EXPORT EXTI4_IRQHandler [WEAK]
EXPORT DMA1_Channel1_IRQHandler [WEAK]
EXPORT DMA1_Channel2_IRQHandler [WEAK]
EXPORT DMA1_Channel3_IRQHandler [WEAK]
EXPORT DMA1_Channel4_IRQHandler [WEAK]
EXPORT DMA1_Channel5_IRQHandler [WEAK]
EXPORT DMA1_Channel6_IRQHandler [WEAK]
EXPORT DMA1_Channel7_IRQHandler [WEAK]
EXPORT ADC1_2_IRQHandler [WEAK]
EXPORT USB_HP_CAN1_TX_IRQHandler [WEAK]
EXPORT USB_LP_CAN1_RX0_IRQHandler [WEAK]
EXPORT CAN1_RX1_IRQHandler [WEAK]
EXPORT CAN1_SCE_IRQHandler [WEAK]
EXPORT EXTI9_5_IRQHandler [WEAK]
EXPORT TIM1_BRK_IRQHandler [WEAK]
EXPORT TIM1_UP_IRQHandler [WEAK]
EXPORT TIM1_TRG_COM_IRQHandler [WEAK]
EXPORT TIM1_CC_IRQHandler [WEAK]
EXPORT TIM2_IRQHandler [WEAK]
EXPORT TIM3_IRQHandler [WEAK]
EXPORT TIM4_IRQHandler [WEAK]
EXPORT I2C1_EV_IRQHandler [WEAK]
EXPORT I2C1_ER_IRQHandler [WEAK]
EXPORT I2C2_EV_IRQHandler [WEAK]
EXPORT I2C2_ER_IRQHandler [WEAK]
EXPORT SPI1_IRQHandler [WEAK]
EXPORT SPI2_IRQHandler [WEAK]
EXPORT USART1_IRQHandler [WEAK]
EXPORT USART2_IRQHandler [WEAK]
EXPORT USART3_IRQHandler [WEAK]
EXPORT EXTI15_10_IRQHandler [WEAK]
EXPORT RTCAlarm_IRQHandler [WEAK]
EXPORT USBWakeUp_IRQHandler [WEAK]
EXPORT TIM8_BRK_IRQHandler [WEAK]
EXPORT TIM8_UP_IRQHandler [WEAK]
EXPORT TIM8_TRG_COM_IRQHandler [WEAK]
EXPORT TIM8_CC_IRQHandler [WEAK]
EXPORT ADC3_IRQHandler [WEAK]
EXPORT FSMC_IRQHandler [WEAK]
EXPORT SDIO_IRQHandler [WEAK]
EXPORT TIM5_IRQHandler [WEAK]
EXPORT SPI3_IRQHandler [WEAK]
EXPORT UART4_IRQHandler [WEAK]
EXPORT UART5_IRQHandler [WEAK]
EXPORT TIM6_IRQHandler [WEAK]
EXPORT TIM7_IRQHandler [WEAK]
EXPORT DMA2_Channel1_IRQHandler [WEAK]
EXPORT DMA2_Channel2_IRQHandler [WEAK]
EXPORT DMA2_Channel3_IRQHandler [WEAK]
EXPORT DMA2_Channel4_5_IRQHandler [WEAK]
WWDG_IRQHandler
PVD_IRQHandler
TAMPER_IRQHandler
RTC_IRQHandler
FLASH_IRQHandler
RCC_IRQHandler
EXTI0_IRQHandler
EXTI1_IRQHandler
EXTI2_IRQHandler
EXTI3_IRQHandler
EXTI4_IRQHandler
DMA1_Channel1_IRQHandler
DMA1_Channel2_IRQHandler
DMA1_Channel3_IRQHandler
DMA1_Channel4_IRQHandler
DMA1_Channel5_IRQHandler
DMA1_Channel6_IRQHandler
DMA1_Channel7_IRQHandler
ADC1_2_IRQHandler
USB_HP_CAN1_TX_IRQHandler
USB_LP_CAN1_RX0_IRQHandler
CAN1_RX1_IRQHandler
CAN1_SCE_IRQHandler
EXTI9_5_IRQHandler
TIM1_BRK_IRQHandler
TIM1_UP_IRQHandler
TIM1_TRG_COM_IRQHandler
TIM1_CC_IRQHandler
TIM2_IRQHandler
TIM3_IRQHandler
TIM4_IRQHandler
I2C1_EV_IRQHandler
I2C1_ER_IRQHandler
I2C2_EV_IRQHandler
I2C2_ER_IRQHandler
SPI1_IRQHandler
SPI2_IRQHandler
USART1_IRQHandler
USART2_IRQHandler
USART3_IRQHandler
EXTI15_10_IRQHandler
RTCAlarm_IRQHandler
USBWakeUp_IRQHandler
TIM8_BRK_IRQHandler
TIM8_UP_IRQHandler
TIM8_TRG_COM_IRQHandler
TIM8_CC_IRQHandler
ADC3_IRQHandler
FSMC_IRQHandler
SDIO_IRQHandler
TIM5_IRQHandler
SPI3_IRQHandler
UART4_IRQHandler
UART5_IRQHandler
TIM6_IRQHandler
TIM7_IRQHandler
DMA2_Channel1_IRQHandler
DMA2_Channel2_IRQHandler
DMA2_Channel3_IRQHandler
DMA2_Channel4_5_IRQHandler
B .
ENDP
ALIGN
;*******************************************************************************
; User Stack and Heap initialization 使用者堆棧初始化
;*******************************************************************************
IF :DEF:__MICROLIB ;判斷是否定義了__MICROLIB
EXPORT __initial_sp;如果定義了這個宏則賦予标号__initial_sp(棧頂位址)、__heap_base(堆起始位址)、__heap_limit(堆結束位址)全局屬性,可供外部檔案調用。
EXPORT __heap_base
EXPORT __heap_limit
ELSE ;如果沒有定義__MICROLIB,則插入标号__use_two_region_memory,這個函數需要使用者自己實作
IMPORT __use_two_region_memory
EXPORT __user_initial_stackheap ;聲明标号__user_initial_stackheap 具有全局屬性,可供外部檔案調用,下面實作這個标号的内容。
__user_initial_stackheap
LDR R0, = Heap_Mem
LDR R1, =(Stack_Mem + Stack_Size)
LDR R2, = (Heap_Mem + Heap_Size)
LDR R3, = Stack_Mem
BX LR
ALIGN
ENDIF
END ;檔案結束
啟動檔案使用的 ARM 彙編指令彙總
【EQU】 給數字常量取一個符号名,相當于 C語言中的 define
【AREA】 彙編一個新的代碼段或者資料段
【SPACE】 配置設定記憶體空間
【PRESERVE8 】目前檔案堆棧需按照 8位元組對齊
【EXPORT】聲明一個标号具有全局屬性,可被外部的檔案使用
【DCD 】以字為機關配置設定記憶體,要求 4位元組對齊,并要求初始化這些記憶體
【PROC 】定義子程式,與 ENDP 成對使用,表示子程式結束
【WEAK 】弱定義,如果外部檔案聲明了一個标号,則優先使用外部檔案定義的标号,如果外部檔案沒有定義也不出錯。要注意的是:這個不是ARM的指令,是編譯器的,這裡放在一起隻是為了友善。
【IMPORT】聲明标号來自外部檔案,跟 C 語言中的 EXTERN關鍵字類似
【B】 跳轉到一個标号
【ALIGN】 編譯器對指令或者資料的存放位址進行對齊,一般需要跟一個立即數,預設表示 4位元組對齊。要注意的是:這個不是 ARM的指令,是編譯器的,這裡放在一起隻是為了友善。
【END】 到達檔案的末尾,檔案結束
【IF,ELSE,ENDIF】彙編的條件分支語句,跟 C 語言的 if ,else 類似
LDR、BLX、BX 是 CM4 核心的指令,可在《CM3 權威指南 CnR2》第四章-指令集裡面查詢到
【LDR】 從存儲器中加載字到一個寄存器中
【BL】 跳轉到由寄存器/标号給出的位址,并把跳轉前的下條指令位址儲存到 LR
【BLX】 跳轉到由寄存器給出的位址,并根據寄存器的 LSE 确定處理器的狀态,還要把跳轉前的下條指令位址儲存到 LR
【BX】 跳轉到由寄存器/标号給出的位址,不用傳回
關于與啟動檔案有關的一些問題思考
-
在啟動檔案裡面已經幫我們寫好所有中斷的中斷服務函數,跟我們平時寫的中斷服務函數不一樣的就是這些函數都是空的,真正的中斷複服務程式需要我們在外部的 C 檔案裡面重新實作,這裡隻是提前占了一個位置而已。
如果我們在使用某個外設的時候,開啟了某個中斷,但是又忘記編寫配套的中斷服務程式或者函數名寫錯,那當中斷來臨的時,程式就會跳轉到啟動檔案預先寫好的空的中斷服務程式中,并且在這個空函數中無線循環,即程式就死在這裡。
B:跳轉到一個标号。這裡跳轉到一個‘.’,即表示無限循環
如果你在調試程式時發現死在了啟動檔案中的B .這個位置,大機率是你使能了某個中斷但沒有編寫中斷函數。
-
棧的作用是用于局部變量,函數調用,函數形參等的開銷,棧的大小不能超過内部SRAM 的大小。如果編寫的程式比較大,定義的局部變量很多,那麼就需要修改棧的大小。如果某一天,你寫的程式出現了莫名奇怪的錯誤,并進入了硬 fault 的時候,這時你就要考慮下是不是棧不夠大,溢出了。
修改啟動檔案中的Stack_Size EQU 0x00000400可以修改棧大小
修改啟動檔案中的Heap_Size EQU 0x00000200可以修改堆大小
-
在3.5版F1标準庫中的啟動檔案還調用了在system_stm32f10x.c檔案中的
SystemInit()函數配置系統時鐘,在舊版本的工程中要使用者進入main函數自己調用SystemInit()函數。
- 無論性能高下,結構簡繁,價格貴賤,每一種微控制器(處理器)都必須有啟動檔案,啟動檔案的作用便是負責執行微控制器從“複位”到“開始執行main函數”中間這段時間(稱為啟動過程)所必須進行的工作。最為常見的51,AVR或MSP430等微控制器當然也有對應的啟動檔案,但開發環境往往自動完整地提供了這個啟動檔案,不需要開發人員再行幹預啟動過程,隻需要從main函數開始進行應用程式的設計即可。
- Cortex-M3核心規定,起始位址必須存放堆頂指針,而第二個位址則必須存放複位中斷入口向量位址,這樣在Cortex-M3核心複位後,會自動從起始位址的下一個32位空間取出複位中斷入口向量,跳轉執行複位中斷服務程式。
-
Cortex-M3核心可通過boot引腳設定中斷向量表的位置(即可以設定從不同位置啟動),有3種情況:
1、 通過boot引腳設定可以将中斷向量表定位于SRAM區,即起始位址為0x2000000,同時複位後PC指針位于0x2000000處;
2、 通過boot引腳設定可以将中斷向量表定位于FLASH區,即起始位址為0x8000000,同時複位後PC指針位于0x8000000處;
3、 通過boot引腳設定可以将中斷向量表定位于内置Bootloader區
參考鳴謝
https://www.cnblogs.com/wenshinlee/p/8859227.html
https://www.cnblogs.com/amanlikethis/p/3719529.html