ABAP 動态生成内表的兩種方法(Two Methods of Dynamic Internal Table Creation)

轉自 ：http://www.cnblogs.com/clsoho/archive/2010/07/23/1783851.html

1.使用modify (p_tabname) from <dyn_wa>. 的時候，一定要确定要更新的字段是不是系統表的關鍵字段，如果是關鍵字段的話，需要先删除這條記錄，delete (p_tabname) from <dyn_wa>.再進行modify,因為modify進行更新的時候如果不存在就新增，這點一定要注意。

2.如果使用UPDATE進行更新，對于非主鍵字段的改變還是可以的，但是對于主鍵字段，隻能用MODIFY了。直接對SAP資料做UPDATE和MODIFY是很危險的，不到萬不得已，最好不要做這些操作。如果萬一出問題，會很嚴重的。這裡就不用更新和删除程式作為測試程式了，直接做一個動态内表ALV顯示的測試程式，道理和更新與删除差不多，希望對有這方面需求的朋友有所幫助！

REPORT ZCL_TEST026.

TYPE-POOLS:abap.

PARAMETERS p_name TYPE tabname.

DATA lt_table TYPE TABLE OF dfies. "字段結構表

DATA ls_table TYPE dfies.

DATA lr_struc TYPE REF TO cl_abap_structdescr.

DATA lr_table TYPE REF TO cl_abap_tabledescr.

DATA lr_type TYPE REF TO cl_abap_typedescr.

DATA lr_data TYPE REF TO cl_abap_datadescr.

DATA lt_comp TYPE abap_component_tab.

DATA ls_comp LIKE LINE OF lt_comp.

DATA dyn_wa TYPE REF TO data.

DATA dyn_table TYPE REF TO data.

DATA l_string TYPE string.

FIELD-SYMBOLS: <dyn_table> TYPE STANDARD TABLE,

<dyn_wa> TYPE ANY.

*1.擷取表中的字段結構

CALL FUNCTION 'DDIF_NAMETAB_GET'

EXPORTING

tabname = p_name

TABLES

dfies_tab = lt_table

EXCEPTIONS

not_found = 1

OTHERS = 2.

IF sy-subrc <> 0.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

ENDIF.

LOOP AT lt_table INTO ls_table.

CONCATENATE ls_table-tabname '-' ls_table-fieldname INTO l_string.

ls_comp-name = ls_table-fieldname.

*讀取字段類型

CALL METHOD cl_abap_datadescr=>describe_by_name

EXPORTING

p_name = l_string

RECEIVING

p_descr_ref = lr_type

EXCEPTIONS

type_not_found = 1

OTHERS = 2.

IF sy-subrc <> 0.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

ENDIF.

ls_comp-type ?= lr_type.

APPEND ls_comp TO lt_comp.

CLEAR ls_comp.

ENDLOOP.

*根據字段目錄建立動态結構類型

CALL METHOD cl_abap_structdescr=>create

EXPORTING

p_components = lt_comp

RECEIVING

p_result = lr_struc.

*根據動态結建構立動态内表類型

CALL METHOD cl_abap_tabledescr=>create

EXPORTING

p_line_type = lr_struc

RECEIVING

p_result = lr_table.

*參照動态結構類型和動态内表類型建立内表與工作區

CREATE DATA dyn_wa TYPE HANDLE lr_struc.

CREATE DATA dyn_table TYPE HANDLE lr_table.

*指定内表與工作區到字段符号

ASSIGN dyn_wa->* TO <dyn_wa>.

ASSIGN dyn_table->* TO <dyn_table>.

*從動态表中取數到動态内表中

SELECT * INTO CORRESPONDING FIELDS OF TABLE <dyn_table> UP TO 100

ROWS FROM (p_name).

*顯示内表中的資料

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'

EXPORTING

i_structure_name = p_name

TABLES

t_outtab = <dyn_table>

EXCEPTIONS

program_error = 1

OTHERS = 2.

IF sy-subrc <> 0.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

ENDIF.

附2：

REPORT ZCL_TEST027.

TYPE-POOLS:abap.

PARAMETERS p_name TYPE tabname.

DATA: d_ref TYPE REF TO data,

lt_alv_cat TYPE TABLE OF lvc_s_fcat,

ls_alv_cat LIKE LINE OF lt_alv_cat.

DATA: lt_table LIKE TABLE OF dntab.

DATA: ls_table TYPE dntab.

FIELD-SYMBOLS : <dyn_table> TYPE table,

<dyn_wa> TYPE ANY,

<dyn_field> TYPE ANY.

*取出表結構的字段目錄

CALL FUNCTION 'NAMETAB_GET'

EXPORTING

langu = sy-langu

tabname = p_name

TABLES

nametab = lt_table

EXCEPTIONS

no_texts_found = 1.

*根據取出的字段目錄生成參考字段目錄

LOOP AT lt_table INTO ls_table.

ls_alv_cat-fieldname = ls_table-fieldname.

ls_alv_cat-ref_table = p_name.

ls_alv_cat-ref_field = ls_table-fieldname.

APPEND ls_alv_cat TO lt_alv_cat.

CLEAR ls_alv_cat.

ENDLOOP.

*内表建立

CALL METHOD cl_alv_table_create=>create_dynamic_table

EXPORTING

it_fieldcatalog = lt_alv_cat

IMPORTING

ep_table = d_ref.

*指定生成的内表到字段符号

ASSIGN d_ref->* TO <dyn_table>.

*從動态表中取數到動态内表中

SELECT * INTO CORRESPONDING FIELDS OF TABLE <dyn_table> UP TO 100

ROWS FROM (p_name).

*顯示内表中的資料

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'

EXPORTING

i_structure_name = p_name

TABLES

t_outtab = <dyn_table>

EXCEPTIONS

program_error = 1

OTHERS = 2.

IF sy-subrc <> 0.

MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno

WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.

ENDIF.