S3C2440定時器

這是改動後的啟動檔案

@******************************************************************************
@ File：head.S
@ 功能：初始化，設定中斷模式、管理模式的棧，設定好中斷處理函數
@******************************************************************************       

.extern     main
.text 
.global _start 
_start:
@******************************************************************************       
@ 中斷向量，本程式中，除Reset和HandleIRQ外，其它異常都沒有使用
@******************************************************************************       
    b   Reset

@ 0x04: 未定義指令中止模式的向量位址
HandleUndef:
    b   HandleUndef 

@ 0x08: 管理模式的向量位址，通過SWI指令進入此模式
HandleSWI:
    b   HandleSWI

@ 0x0c: 指令預取終止導緻的異常的向量位址
HandlePrefetchAbort:
    b   HandlePrefetchAbort

@ 0x10: 資料通路終止導緻的異常的向量位址
HandleDataAbort:
    b   HandleDataAbort

@ 0x14: 保留
HandleNotUsed:
    b   HandleNotUsed

@ 0x18: 中斷模式的向量位址
    b   HandleIRQ

@ 0x1c: 快中斷模式的向量位址
HandleFIQ:
    b   HandleFIQ

Reset:                  
    ldr sp, =4096           @ 設定棧指針，以下都是C函數，調用前需要設好棧
    bl  disable_watch_dog   @ 關閉WATCHDOG，否則CPU會不斷重新開機

    bl  clock_init

    msr cpsr_c, #0xd2       @ 進入中斷模式
    ldr sp, =3072           @ 設定中斷模式棧指針

    msr cpsr_c, #0xd3       @ 進入管理模式
    ldr sp, =4096           @ 設定管理模式棧指針，
                            @ 其實複位之後，CPU就處于管理模式，
                            @ 前面的“ldr sp, =4096”完成同樣的功能，此句可省略

    bl  init_led            @ 初始化LED的GPIO管腳

    bl  timer0_init

    bl  init_irq            @ 調用中斷初始化函數，在init.c中
    msr cpsr_c, #0x53       @ 設定I-bit=0，開IRQ中斷

    ldr lr, =halt_loop      @ 設定傳回位址
    ldr pc, =main           @ 調用main函數
halt_loop:
    b   halt_loop

HandleIRQ:
    sub lr, lr, #4                  @ 計算傳回位址
    stmdb   sp!,    { r0-r12,lr }   @ 儲存使用到的寄存器
                                    @ 注意，此時的sp是中斷模式的sp
                                    @ 初始值是上面設定的3072

    ldr lr, =int_return             @ 設定調用ISR即EINT_Handle函數後的傳回位址  
    ldr pc, =Timer0_Handle            @ 調用中斷服務函數，在interrupt.c中
int_return:
    ldmia   sp!,    { r0-r12,pc }^  @ 中斷傳回, ^表示将spsr的值複制到cpsr

           

這是修改後的makefile

objs := head.o init.o interrupt.o main.o

timer.bin: $(objs)
    arm-linux-ld -Ttext  -o timer_linux $^
    arm-linux-objcopy -O binary -S timer_linux $@
    arm-linux-objdump -D -m arm timer_linux > timer.dis

%.o:%.c
    arm-linux-gcc -Wall -O2 -c -o $@ $<

%.o:%.S
    arm-linux-gcc -Wall -O2 -c -o $@ $<

clean:
    rm -f timer.bin timer_linux timer.dis *.o