基于Arduino的多功能數字時鐘

實作功能：

顯示時間、日期和星期
斷電儲存時間
通過按鈕設定時間、日期
整點響鈴
自定義鬧鐘
顯示溫度
自定義報警溫度
按鍵功能：按選擇鍵進入設定時間功能；同時按 + - 鍵進入鬧鐘和報警溫度設定功能；
再按選擇鍵光标跳動，光标跳到哪目前的參數即可通過加減鍵修改。

實驗所需器件：

Arduino開發闆或Atmega328P晶片、DS1302時鐘晶片、溫度傳感器DS18b20、蜂鳴器、不帶鎖開關、LCD1602、10K可調電阻、10K電阻（可不接，即DS18b20端口的電阻可去掉，不影響讀數）

Proteus ISIS 仿真圖：

基于Arduino的多功能數字時鐘

依賴庫下載下傳:

DS1302

OneWire

DallasTemperature

依賴庫的安裝方法，如不清楚，可以參考官方文檔

程式如下：

/* * 
 * LCD RS pin to digital pin 12
 * LCD Enable pin to digital pin 11
 * LCD D4 pin to digital pin 5
 * LCD D5 pin to digital pin 4
 * LCD D6 pin to digital pin 3
 * LCD D7 pin to digital pin 2
 * LCD R/W pin to ground
 * LCD VSS pin to ground
 * LCD VCC pin to 5V 
 * */
#include <DS1302.h>    
#include <LiquidCrystal.h>       //LCD1602顯示頭檔案
#include <OneWire.h> 
#include <DallasTemperature.h>  //溫度傳感器DS18B20頭檔案
#define ONE_WIRE_BUS A3            //DS18B20 信号端口 
OneWire oneWire(ONE_WIRE_BUS); 
DallasTemperature sensors(&oneWire);
LiquidCrystal lcd(12, 11, 5, 4, 3, 2); 
#define choose  A0   //選擇端口
#define add  A1      //加
#define minus  A2    //減
#define Tone 13      //蜂鳴器端口
uint8_t CE_PIN   = 8;   //DS1302 RST端口
uint8_t IO_PIN   = 9;   //DS1302 DAT端口
uint8_t SCLK_PIN = 10;  //DS1302 CLK端口
DS1302 rtc(CE_PIN, IO_PIN, SCLK_PIN);  //建立 DS1302 對象
unsigned long seconds;
int s = 0, m = 0, h = 0, d = 0, mon = 0, y = 0;   //時間進位
int second = 0, minute = 0, hour = 0, day = 0, month = 0, year = 0;  //目前時間
int SECOND = 0, MINUTE = 0, HOUR = 0, DAY = 0, MONTH = 0, YEAR = 0;  //初始時間
int chose = 0, alarm_choose = 0 ,ButtonDelay = 10, frequence = 2093;
int alarm_hour = 7, alarm_minute = 30, alarm_second = 0;  //鬧鐘時間
double Temperatures, Temp_Alarm = 30 ; 

void setup(){    
    for(int i = 2;i <= 13; i++){
        pinMode(i,OUTPUT); 
    }                
    digitalWrite(add, HIGH);
    digitalWrite(minus, HIGH);
    digitalWrite(choose, HIGH);  
    lcd.begin(16, 2);  //初始化LCD1602 
    sensors.begin();   //初始化溫度傳感器DS18B20  
    //Time t(2015, 5, 16, 0, 2, 20, 1);  
    //rtc.time(t);  //設定DS1302晶片初始時間
    //由于當初遺留的一些問題，本方案有些不完美。我這裡使用的方案是通電讀取DS1302晶片的時間，然後再根據運作時間讓時間走動。
    //如果對時間精确性比較敏感，可以改成始終從DS1302晶片讀取時間。
    set(rtc.year(), rtc.month(), rtc.date(), rtc.hour(), rtc.minutes(), rtc.seconds());  
    rtc.write_protect(false);  // 關閉DS1302晶片寫保護
    rtc.halt(false);           //為true時DS1302暫停
}

/** 格式化輸出 */
void FormatDisplay(int col, int row,int num){
    lcd.setCursor(col, row); 
    if(num < 10)   lcd.print("0");
    lcd.print(num);   
}

/** 計算時間 */
void time() {    
    second = (SECOND + seconds) % 60;   //計算秒
    m = (SECOND + seconds) / 60;        //分鐘進位
    FormatDisplay(6,1,second);
    
    minute = (MINUTE + m) % 60;  //計算分鐘
    h = (MINUTE + m) / 60;       //小時進位
    FormatDisplay(3,1,minute);      

    hour = (HOUR + h) % 24;   //計算小時
    d = (HOUR + h) / 24;      //天數進位
    FormatDisplay(0,1,hour); 
    
    lcd.setCursor(2, 1);   
    lcd.print(":");   
    lcd.setCursor(5, 1);   
    lcd.print(":");  
}

/** 根據年月計算當月天數 */
int Days(int year, int month){
    int days = 0;
    if (month != 2){
        switch(month){
            case 1: case 3: case 5: case 7: case 8: case 10: case 12: days = 31;  break;
            case 4: case 6: case 9: case 11:  days = 30;  break;
        }
    }else{   //閏年    
        if(year % 4 == 0 && year % 100 != 0 || year % 400 == 0){
            days = 29;          
        }    
        else{
            days = 28;  
        }     
    }  
    return days;   
}

/** 計算當月天數 */ 
void Day(){     
    int days = Days(year,month);
    int days_up;
    if(month == 1){
        days_up = Days(year - 1, 12); 
    }   
    else{
        days_up = Days(year, month - 1);
    }  
    day = (DAY + d) % days;
    if(day == 0){
        day = days;  
    }     
    if((DAY + d) == days + 1 ){
        DAY -= days;
        mon++;
    }
    if((DAY + d) == 0){
        DAY += days_up;
        mon--;
    }
    FormatDisplay(8,0,day); 
}

/** 計算月份 */
void Month(){  
    month = (MONTH + mon) % 12;
    if(month == 0){
        month = 12;
    }  
    y = (MONTH + mon - 1) / 12;
    FormatDisplay(5,0,month); 
    lcd.setCursor(7, 0);   
    lcd.print('-'); 
}

/** 計算年份 */
void Year(){ 
    year = ( YEAR + y ) % 9999;
    if(year == 0){
        year = 9999;
    } 
    lcd.setCursor(0, 0); 
    if(year < 1000){ 
        lcd.print("0"); 
    }
    if(year < 100){ 
        lcd.print("0"); 
    }
    if(year < 10){ 
        lcd.print("0"); 
    }
    lcd.print(year);
    lcd.setCursor(4, 0);   
    lcd.print('-'); 
}

/** 根據年月日計算星期幾 */
void Week(int y,int m, int d){           
    if(m == 1){
        m = 13;
    }
    if(m == 2){
        m = 14;
    } 
    int week = (d+2*m+3*(m+1)/5+y+y/4-y/100+y/400)%7+1; 
    String weekstr = "";
    switch(week){
        case 1: weekstr = "Mon. ";   break;
        case 2: weekstr = "Tues. ";  break;
        case 3: weekstr = "Wed. ";   break;
        case 4: weekstr = "Thur. ";  break;
        case 5: weekstr = "Fri. ";   break;
        case 6: weekstr = "Sat. ";   break;
        case 7: weekstr = "Sun. ";   break;
    }    
    lcd.setCursor(11, 0);  
    lcd.print(weekstr);
}

/** 顯示時間、日期、星期 */
void Display() { 
    time();
    Day();  
    Month();
    Year();
    Week(year,month,day);  
}

/** 顯示光标 */
void DisplayCursor(int rol, int row) {
    lcd.setCursor(rol, row);   
    lcd.cursor();
    delay(100);     
    lcd.noCursor();
    delay(100);    
}

/** 設定初始時間 */
void set(int y, int mon, int d, int h, int m, int s){
    YEAR = y;
    MONTH = mon;
    DAY = d;  
    HOUR = h;
    MINUTE = m;
    SECOND = s;  
}

/** 通過按鍵設定時間 */
void Set_Time(int rol, int row, int &Time){
    DisplayCursor(rol, row); 
    if(digitalRead(add) == LOW){
        delay(ButtonDelay);
        if(digitalRead(add) == LOW){
            Time ++;
        }           
        Display();      
    }  
    if(digitalRead(minus) == LOW){
        delay(ButtonDelay);
        if(digitalRead(minus) == LOW){
            Time --; 
        }            
        Display();  
    }
}

/** 按鍵選擇 */
void Set_Clock(){
    if(digitalRead(choose)==LOW){  
        lcd.setCursor(9, 1);  
        lcd.print("SetTime");
        while(1){       
            if(digitalRead(choose) == LOW){
                delay(ButtonDelay);
                if(digitalRead(choose) ==LOW){
                    chose++;  
                }
                    
            } 
            seconds = millis()/1000; 
            Display(); 
            if(chose == 1){
                Set_Time(1, 1, HOUR);      //SetHour
            }else if(chose == 2){ 
                Set_Time(4, 1, MINUTE);    //SetMinute
            }else if(chose == 3){
                Set_Time(7, 1, SECOND);    //SetSecond
            }else if(chose == 4){
                Set_Time(9, 0, DAY);       //SetDay
            }else if(chose == 5){
                Set_Time(6, 0, MONTH);     // SetMonth
            }else if(chose == 6){            
                Set_Time(3, 0, YEAR);      //SetYear
            }else if(chose >= 7) {
                chose = 0; 
                break;
            }
        }
    }  
}

/** 設定鬧鐘小時 */
void Set_Alarm_Hour(){
   DisplayCursor(1, 1);   
   if(digitalRead(add) == LOW){
       delay(ButtonDelay);
       if(digitalRead(add) == LOW){
           alarm_hour ++;
           if(alarm_hour == 24){
               alarm_hour = 0;
           }   
           FormatDisplay(0,1,alarm_hour);   
       }
   }
    if(digitalRead(minus) == LOW){
            delay(ButtonDelay);
            if(digitalRead(minus) == LOW){                
                alarm_hour --;
                if(alarm_hour == -1){
                    alarm_hour = 23;
                }   
                FormatDisplay(0,1,alarm_hour); 
            }
    }
}

/** 設定鬧鐘分鐘 */
void Set_Alarm_Minute(){
   DisplayCursor(4, 1); 
   if(digitalRead(add) == LOW) {
       delay(ButtonDelay);
       if(digitalRead(add) == LOW){
            alarm_minute ++;
            if(alarm_minute == 60){
                alarm_minute = 0;
            }  
            FormatDisplay(3,1,alarm_minute); 
       }
   }
    if(digitalRead(minus) == LOW){
            delay(ButtonDelay);
            if(digitalRead(minus) == LOW){                
                alarm_minute --;
                if(alarm_minute == -1){
                    alarm_minute = 59;
                }  
                FormatDisplay(3,1,alarm_minute); 
            } 
    }  
}

/** 設定報警溫度 */
void Set_Alarm_Temp(){  
    DisplayCursor(10, 1); 
    if(digitalRead(add) == LOW) {
        delay(ButtonDelay);
        if(digitalRead(add) == LOW){
            Temp_Alarm ++; 
        }             
    }
    if(digitalRead(minus) == LOW){
        delay(ButtonDelay);
        if(digitalRead(minus) == LOW){
            Temp_Alarm --; 
        }   
    }
}

/** 進入報警設定 */
void Set_Alarm(){
    if(digitalRead(add) == LOW && digitalRead(minus) == LOW){
        alarm_hour = hour;
        alarm_minute = minute;
        //alarm_choose  = 1;
        lcd.setCursor(0, 0);   
        lcd.print("set alarm       ");  
        lcd.setCursor(6, 1);   
        lcd.print("00");         //鬧鐘秒數      
        while(1){
            if(digitalRead(choose) == LOW){
                delay(ButtonDelay);
                if(digitalRead(choose) == LOW){
                    alarm_choose++; 

                }                    
            }
            lcd.setCursor(9, 1);   
            lcd.print(Temp_Alarm);
            lcd.setCursor(14, 1);  
            lcd.print((char)223);    //顯示o符号
            lcd.setCursor(15, 1);  
            lcd.print("C");          //顯示字母C     
            if(alarm_choose == 1){
                Set_Alarm_Hour();
            }else if(alarm_choose == 2){
                Set_Alarm_Minute();        
            }else if(alarm_choose == 3){
                Set_Alarm_Temp(); 
            }else if(alarm_choose >= 4){
                alarm_choose = 0;
                break;
            }       
        }
    }
} 

/** 正點蜂鳴 */
void Point_Time_Alarm(){
    if(minute == 0 && second == 0){
        tone(Tone,frequence); 
        delay(500);
        noTone(Tone);   
    }    
}

/** 鬧鐘 指定時間蜂鳴 */
void Clock_Alarm(){
  if(hour == alarm_hour && minute == alarm_minute && second == alarm_second){
        tone(Tone,frequence); 
        delay(5000);
        noTone(Tone);   
  }
} 

/** 擷取DS18B20溫度 */
void GetTemperatures(){
    sensors.requestTemperatures(); // Send the command to get temperatures
    Temperatures = sensors.getTempCByIndex(0);
    lcd.setCursor(9, 1) ;    
    lcd.print(Temperatures); //擷取溫度
    lcd.setCursor(14, 1);  
    lcd.print((char)223); //顯示o符号
    lcd.setCursor(15, 1);  
    lcd.print("C"); //顯示字母C     
}

/** 超過指定溫度報警 */
void Temperatures_Alarm(){
    if(Temperatures >= Temp_Alarm){
        tone(Tone,frequence); 
        delay(500);
        noTone(Tone);       
    }
}

void loop() { 
    seconds = millis()/1000;    //擷取單片機目前運作時間 
    Display();       //顯示時間
    Set_Clock();     //設定時間  
    Set_Alarm();     //設定鬧鐘
    Point_Time_Alarm();    //正點蜂鳴
    Clock_Alarm();         //鬧鐘時間蜂鳴
    GetTemperatures();     //擷取DS18B20溫度
    Temperatures_Alarm();  //超過指定溫度報警
    Time t(year, month, day, hour, minute, second, 1);  //斷電将單片機的目前時間寫到DS1302晶片中
    rtc.time(t);
}

基于Arduino的多功能數字時鐘

繼續閱讀

實踐基于 Arduino I2C讀取 MPU6050 三軸陀螺儀資料

【Arduino和高中通用技術】——九、使用SW來設計模型

24.USB鍵盤模拟實驗

Arduino Leonardo 模拟鍵盤

android 自定義時鐘圓盤

android 自定義view實作時鐘

SysTick、SYSCLK、HCLK、HSI，HSE，LSE

arduino 參考資料

u8g2庫漢字速查表 u8g2漢字速查表

[arduino][u8g2][12864] oled—u8g2庫使用說明(例子是12864液晶屏)

《Arduino》開發之用 u8g2 庫給 0.96OLED 顯示一個變量

基于QuartusII的verilog數字時鐘設計

【arduino--8266】----系列傳感器和子產品實驗目錄清單

這款地震監測器不僅能夠更靈敏地檢測微小的地震，還能利用GPS定位系統準确定位震源地經緯度。它由GPS定位器、Arduin

樹莓派安裝python3.8

Arduino Uno 實驗14——聲音傳感器