在VBScript中使用類（三）

我們來分析一下（2）中的程式：

Class TVProgram

               Public StartTime

               Public internal_ProgramDate

               Public Property Get ProgramDate

                       ProgramDate = Day(internal_ProgramDate) & _

                               " " & MonthName(Month(internal_ProgramDate)) & _

                               " " & Year(internal_ProgramDate)

               End Property

               Public ProgramTitle

        End Class

        Dim objTVShow

        Set objTVShow = New TVProgram

        objTVShow.StartTime = CDate(" 17:30 ")

        objTVShow.internal_ProgramDate = DateSerial(1999,9,17)

        objTVShow.ProgramTitle = "The Jerry Springer Show"

        Response.Write objTVShow.ProgramTitle & " is on at " & _

       objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

當調用對象的屬性ProgramDate時，實際上執行了函數ProgramDate，即如上定義的函數，而很快你也将習慣這種在聲明部分使用Public或Private關鍵字的方式。關鍵字“Property”，告知了編譯器如同調用屬性一樣在外部調用函數。接着的“Get”，表明該函數是輸出還是獲得一個值。

Get的意思是“允許外部代碼去‘擷取’一個值”，與其類似的關鍵字還有“Let”和“Set”，但這兩個比較複雜，因而我們以後再讨論。

接下去的代碼看來有點難度的，給objectname.internal_ProgramDate指派并通過objectname.ProgramDate來調用它。如果可以使用相同關鍵字同時為其指派并獲得它的值不是更好嗎？當然，那也可以。

如果定義Get和Let屬性的名稱相同，可以将它們當作對象相同的屬性，但這隻限于它們定義了相同數量的成員。（以下代碼看來不太相同，僅作為執行個體參考）

Class TVProgram

               Public StartTime

               Public internal_ProgramDate

               Public Property Get ProgramDate

                       ProgramDate = Day(internal_ProgramDate) & " " _

                               & MonthName(Month(internal_ProgramDate)) & _

                               " " & Year(internal_ProgramDate)

               End Property

               Public Property Let ProgramDate(ByVal varDateIn)

                       internal_ProgramDate = CDate(varDateIn)

               End Property

               Public ProgramTitle

        End Class

        Dim objTVShow

        Set objTVShow = New TVProgram

        objTVShow.StartTime = CDate(" 17:30 ")

        objTVShow.ProgramDate = " 17 Sept 99 "

        objTVShow.ProgramTitle = "The Jerry Springer Show"

    Response.Write objTVShow.ProgramTitle & " is on at " & _

       objTVShow.StartTime & " on " & objTVShow.ProgramDate & "."

以上代碼中Let的聲明部分看來似乎是一個多餘的元素，當我第一次看到時研究了很長時間。每次我使用“0”作為變量用在每個屬性上，我總是得到這個錯誤資訊，“元素數量必須相等”。“它們确實相等！”抓狂之後，我回過頭去看程式才覺得自己的愚蠢！：）

原因是，當你試圖為ProgramDate指派時，你會使用這樣一行程式：

objTVShow.ProgramDate = dtmMyDate

為了友善，等号右邊的值（這裡指dtmMyDate）作為了一個程元賦給了函數。是以編譯器可能會認為在Get ProgramDate行有0程元，而Let ProgramDate卻多一個！配置設定的值總是被略過而作為屬性的最後一個程元，是以即使你使用其他程元，所賦的值總是作為最後一個程元。

現在看程式。無論通過ProgramDate設定日期為文本形式，還是用internal_ProgramDate譯成日期變量，程式都沒有問題。但能不能隻使用一個入口呢？

如果internal_ProgramDate隻能在内部有效，而使用Let ProgramDate檢查傳輸的資料類型，我們就可以作出選擇。例如：

Class TVProgram

               Public StartTime

               Private internal_ProgramDate

               Public Property Get ProgramDate

                       ProgramDate = Day(internal_ProgramDate) & " " & _

                               MonthName(Month(internal_ProgramDate)) & _

                               " " & Year(internal_ProgramDate)

               End Property

               Public Property Let ProgramDate(ByVal varDateIn)

                       If IsDate(varDateIn) Then

                               internal_ProgramDate = varDateIn

                       Else

                               'Place some error handling code in here.

                       End If

               End Property

               Public ProgramTitle

        End Class

并同樣聲明StartTime屬性：

Class TVProgram

               Private internal_StartTime

               Public Property Get StartTime

                       StartTime = Hour(internal_StartTime) & ":" _

                               & Minute(internal_StartTime)

               End Property

               Public Property Let StartTime(ByVal varTimeIn)

                       If IsDate(varTimeIn) Then

                               internal_StartTime = varTimeIn

                       End If

               End Property

               Private internal_ProgramDate

               Public Property Get ProgramDate

                       ProgramDate = Day(internal_ProgramDate) & " " _

                               & MonthName(Month(internal_ProgramDate)) & _

                               " " & Year(internal_ProgramDate)

               End Property

               Public Property Let ProgramDate(ByVal varDateIn)

                       If IsDate(varDateIn) Then

                               internal_ProgramDate = varDateIn

                       End If

               End Property

               Public ProgramTitle

        End Class

        ...

    現在的代碼離我們想要的還是有些不太實用，我們将在其他頁使用類TVProgram，是以最好将其獨立定義，以便所有也面都可以調用。我們将在第四部分讨論這點。