Unity3D Shader 入門

什麼是Shader

Shader（着色器）是一段能夠針對3D對象進行操作、并被GPU所執行的程式，它負責将輸入的Mesh（網格）以指定的方式和輸入的貼圖或者顔色等組合作用，然後輸出。繪圖單元可以依據這個輸出來将圖像繪制到螢幕上。輸入的貼圖或者顔色等，加上對應的Shader，以及對Shader的特定的參數設定，将這些内容（Shader及輸入參數）打包存儲在一起，得到的就是一個Material（材質）。之後，我們便可以将材質賦予合适的renderer（渲染器）來進行渲染（輸出）了。Shader并不是一個統一的标準，不同的圖形接口的Shader并不相同。OpenGL的着色語言是GLSL， NVidia開發了Cg，而微軟的Direct3D使用進階着色器語言（HLSL）。而Unity的Shader 是将傳統的圖形接口的Shader（由 Cg / HLSL編寫）嵌入到獨有的描述性結構中而形成的一種代碼生成架構，最終會自動生成各硬體平台自己的Shader，進而實作跨平台。

Shader種類

OpenGL和Direct3D都提供了三類着色器：

• 頂點着色器：處理每個頂點，将頂點的空間位置投影在螢幕上，即計算頂點的二維坐标。同時，它也負責頂點的深度緩沖（Z-Buffer）的計算。頂點着色器可以掌控頂點的位置、顔色和紋理坐标等屬性，但無法生成新的頂點。頂點着色器的輸出傳遞到流水線的下一步。如果有之後定義了幾何着色器，則幾何着色器會處理頂點着色器的輸出資料，否則，光栅化器繼續流水線任務。
• 像素着色器(Direct3D)，常常又稱為片斷着色器(OpenGL)：處理來自光栅化器的資料。光栅化器已經将多邊形填滿并通過流水線傳送至像素着色器，後者逐像素計算顔色。像素着色器常用來處理場景光照和與之相關的效果，如凸凹紋理映射和調色。名稱片斷着色器似乎更為準确，因為對于着色器的調用和螢幕上像素的顯示并非一一對應。舉個例子，對于一個像素，片斷着色器可能會被調用若幹次來決定它最終的顔色，那些被遮擋的物體也會被計算，直到最後的深度緩沖才将各物體前後排序。
• 幾何着色器：可以從多邊形網格中增删頂點。它能夠執行對CPU來說過于繁重的生成幾何結構和增加模型細節的工作。Direct3D版本10增加了支援幾何着色器的API, 成為Shader Model 4.0的組成部分。OpenGL隻可通過它的一個插件來使用幾何着色器。

Shader大體上可以分為兩類，簡單來說

• 表面着色器（Surface Shader） - 為你做了大部分的工作，隻需要簡單的技巧即可實作很多不錯的效果。類比卡片機，上手以後不太需要很多努力就能拍出不錯的效果。
• 片段着色器（Fragment Shader） - 可以做的事情更多，但是也比較難寫。使用片段着色器的主要目的是可以在比較低的層級上進行更複雜（或者針對目标裝置更高效）的開發。

Shader程式結構

基本的表面着色器示例：

Shader "Custom/Diffuse Texture" {
  Properties {
      _MainTex ("Base (RGB)", 2D) = "white" {}
  }
  SubShader {
      Tags { "RenderType"="Opaque" }
      LOD 200
      
      CGPROGRAM
      #pragma surface surf Lambert

      sampler2D _MainTex;

      struct Input {
          float2 uv_MainTex;
      };

      void surf (Input IN, inout SurfaceOutput o) {
          half4 c = tex2D (_MainTex, IN.uv_MainTex);
          o.Albedo = c.rgb;
          o.Alpha = c.a;
      }
      ENDCG
  }
  FallBack "Diffuse"
}      

基本的頂點片段着色器示例：　　

Shader "VertexInputSimple" {
  SubShader {
    Pass {
      CGPROGRAM
      #pragma vertex vert
      #pragma fragment frag
      #include "UnityCG.cginc"

      struct v2f {
          float4 pos : SV_POSITION;
          fixed4 color : COLOR;
      };

      v2f vert (appdata_base v)
      {
          v2f o;
          o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
          o.color.xyz = v.normal * 0.5 + 0.5;
          o.color.w = 1.0;
          return o;
      }

      fixed4 frag (v2f i) : SV_Target { return i.color; }
      ENDCG
    }
  } 
}      

下面主要介紹表面着色器

在

Properties{}

中定義着色器屬性，在這裡定義的屬性将被作為輸入提供給所有的子着色器。每一條屬性的定義的文法是這樣的：

_Name("Display Name", type) = defaultValue[{options}]

• _Name - 屬性的名字，簡單說就是變量名，在之後整個Shader代碼中将使用這個名字來擷取該屬性的内容
• Display Name - 這個字元串将顯示在Unity的材質編輯器中作為Shader的使用者可讀的内容
• type - 這個屬性的類型，可能的type所表示的内容有以下幾種：

關鍵字	類型	對應Cg類型	例
Float	浮點數 (任意一個浮點數)	float	_MyFloat (“My float”, Float) = 0.5
Range	浮點數 (在指定範圍内) (一個介于最小值和最大值之間的浮點數，一般用來當作調整Shader某些特性的參數（比如透明度渲染的截止值可以是從0至1的值等）)		_MyRange (“My Range”, Range(0.01, 0.5)) = 0.1
Color	浮點四元組 ( 一種顔色，由RGBA（紅綠藍和透明度）四個量來定義)	float4	_MyColor (“Some Color”, Color) = (1,1,1,1)
Vector	浮點四元組 (一個四維數)		_MyVector(“Some Vector”,Vector) = (1,1,1,1)
2D	2的階數大小的貼圖 (一張2的階數大小（256，512之類）的貼圖。這張貼圖将在采樣後被轉為對應基于模型UV的每個像素的顔色，最終被顯示出來)	sampler2D	_MyTexture (“Texture”, 2D) = “white” {}
Rect	非2的階數大小的貼圖 (一個非2階數大小的貼圖)		_MyRect(“My Rect”, Rect) = “white” {}
CUBE	CubeMap (即Cube map texture（立方體紋理），簡單說就是6張有聯系的2D貼圖的組合，主要用來做反射效果（比如天空盒和動态反射），也會被轉換為對應點的采樣)	samplerCUBE	_MyCubemap (“Cubemap”, CUBE) = “” {}

• defaultValue 定義了這個屬性的預設值，通過輸入一個符合格式的預設值來指定對應屬性的初始值（某些效果可能需要某些特定的參數值來達到需要的效果，雖然這些值可以在之後在進行調整，但是如果預設就指定為想要的值的話就省去了一個個調整的時間，友善很多）。
  • Color - 以0～1定義的rgba顔色，比如(1,1,1,1)；
  • 2D/Rect/Cube - 對于貼圖來說，預設值可以為一個代表預設tint顔色的字元串，可以是空字元串或者”white”,”black”,”gray”,”bump”中的一個
  • Float，Range - 某個指定的浮點數
  • Vector - 一個4維數，寫為 (x,y,z,w)
• option它隻對2D，Rect或者Cube貼圖有關，在寫輸入時我們最少要在貼圖之後寫一對什麼都不含的空白的{}，當我們需要打開特定選項時可以把其寫在這對花括号内。如果需要同時打開多個選項，可以使用空白分隔。可能的選擇有ObjectLinear, EyeLinear, SphereMap, CubeReflect, CubeNormal中的一個，這些都是OpenGL中TexGen的模式。

是以，一組屬性的申明看起來也許會是這個樣子的

//Define a color with a default value of semi-transparent blue
_MainColor ("Main Color", Color) = (0,0,1,0.5)
//Define a texture with a default of white
_Texture ("Texture", 2D) = "white" {}      

Tag

SubShader可以被若幹的标簽（tags）所修飾，而硬體将通過判定這些标簽來決定什麼時候調用該着色器。 比如我們的例子中SubShader的第一句：

Tags { "RenderType"="Opaque" }      

比較常見的标簽有：

• Queue 

  這個标簽很重要，它定義了一個整數，決定了Shader的渲染的次序，數字越小就越早被渲染，早渲染就意味着可能被後面渲染的東西覆寫掉看不見。 

  預定義的Queue有：

  名字	值	描述
  Background	1000	最早被調用的渲染，用來渲染天空盒或者背景
  Geometry	2000	這是預設值，用來渲染非透明物體（普通情況下，場景中的絕大多數物體應該是非透明的）
  AlphaTest	2450	用來渲染經過Alpha Test的像素，單獨為AlphaTest設定一個Queue是出于對效率的考慮
  Transparent	3000	以從後往前的順序渲染透明物體
  Overlay	4000	用來渲染疊加的效果，是渲染的最後階段（比如鏡頭光暈等特效）

• RenderType 

  “Opaque”或”Transparent”是兩個常用的RenderType。如果輸出中都是非透明物體，那寫在Opaque裡；如果想渲染透明或者半透明的像素，那應該寫在Transparent中。這個Tag主要用ShaderReplacement，一般情況下這Tag好像也沒什麼作用。

另外比較有用的标簽還有

"IgnoreProjector"="True"

（不被Projectors影響），

"ForceNoShadowCasting"="True"

（從不産生陰影）以及

"Queue"="xxx"

（指定渲染順序隊列）。

LOD

LOD是 Level of Detail的簡寫，确切地說是Shader Level of Detail的簡寫，因為Unity中還有一個模型的LOD概念，這是兩個不同的東西。我們這裡隻介紹Shader中LOD，模型的LOD請參考這裡。

Shader LOD 就是讓我們設定一個數值，這個數值決定了我們能用什麼樣的Shader。可以通過Shader.maximumLOD或者Shader.globalMaximumLOD 設定允許的最大LOD，當設定的LOD小于SubShader所指定的LOD時，這個SubShader将不可用。通過LOD，我們就可以為某個材質寫一組SubShader，指定不同的LOD，LOD越大則渲染效果越好，當然對硬體的要求也可能越高，然後根據不同的終端硬體配置來設定 globalMaximumLOD來達到兼顧性能的最佳顯示效果。

Unity内建Shader定義了一組LOD的數值，我們在實作自己的Shader的時候可以将其作為參考來設定自己的LOD數值

• VertexLit及其系列 = 100
• Decal, Reflective VertexLit = 150
• Diffuse = 200
• Diffuse Detail, Reflective Bumped Unlit, Reflective Bumped VertexLit = 250
• Bumped, Specular = 300
• Bumped Specular = 400
• Parallax = 500
• Parallax Specular = 600

Shader本體

前面雜項說完了，終于可以開始看看最主要的部分了，也就是将輸入轉變為輸出的代碼部分。為了友善看，請容許我把上面的SubShader的主題部分抄寫一遍

CGPROGRAM
#pragma surface surf Lambert

sampler2D _MainTex;

struct Input {
    float2 uv_MainTex;
};

void surf (Input IN, inout SurfaceOutput o) {
    half4 c = tex2D (_MainTex, IN.uv_MainTex);
    o.Albedo = c.rgb;
    o.Alpha = c.a;
}
ENDCG      

首先是CGPROGRAM。這是一個開始标記，表明從這裡開始是一段CG程式（我們在寫Unity的Shader時用的是Cg/HLSL語言）。最後一行的ENDCG與CGPROGRAM是對應的，表明CG程式到此結束。

接下來是是一個編譯指令：

#pragma surface surf Lambert

，它聲明了我們要寫一個表面Shader，并指定了光照模型。它的寫法是這樣的

#pragma surface surfaceFunction lightModel [optionalparams]

• surface - 聲明的是一個表面着色器
• surfaceFunction - 着色器代碼的方法的名字
• lightModel - 使用的光照模型。

是以在我們的例子中，我們聲明了一個表面着色器，實際的代碼在surf函數中（在下面能找到該函數），使用Lambert（也就是普通的diffuse）作為光照模型。

接下來一句

sampler2D _MainTex;

，sampler2D是個啥？其實在CG中，sampler2D就是和texture所綁定的一個資料容器接口。等等..這個說法還是太複雜了，簡單了解的話，所謂加載以後的texture（貼圖）說白了不過是一塊記憶體存儲的，使用了RGB（也許還有A）通道，且每個通道8bits的資料。而具體地想知道像素與坐标的對應關系，以及擷取這些資料，我們總不能一次一次去自己計算記憶體位址或者偏移，是以可以通過sampler2D來對貼圖進行操作。更簡單地了解，sampler2D就是GLSL中的2D貼圖的類型，相應的，還有sampler1D，sampler3D，samplerCube等等格式。

解釋通了sampler2D是什麼之後，還需要解釋下為什麼在這裡需要一句對

_MainTex

的聲明，之前我們不是已經在

Properties

裡聲明過它是貼圖了麼。答案是我們用來執行個體的這個shader其實是由兩個相對獨立的塊組成的，外層的屬性聲明，復原等等是Unity可以直接使用和編譯的ShaderLab；而現在我們是在

CGPROGRAM...ENDCG

這樣一個代碼塊中，這是一段CG程式。對于這段CG程式，要想通路在

Properties

中所定義的變量的話，必須使用和之前變量相同的名字進行聲明。于是其實

sampler2D _MainTex;

做的事情就是再次聲明并連結了_MainTex，使得接下來的CG程式能夠使用這個變量。

接下來是一個struct結構體。相信大家對于結構體已經很熟悉了，我們先跳過，直接看下面的的surf函數。上面的#pragma段已經指出了我們的着色器代碼的方法的名字叫做surf，就是這段代碼是我們的着色器的工作核心。我們已經說過不止一次，着色器就是給定了輸入，然後給出輸出進行着色的代碼。CG規定了聲明為表面着色器的方法（就是我們這裡的surf）的參數類型和名字，是以我們沒有權利決定surf的輸入輸出參數的類型，隻能按照規定寫。這個規定就是第一個參數是一個Input結構，第二個參數是一個inout的SurfaceOutput結構。

Input其實是需要我們去定義的結構，這給我們提供了一個機會，可以把所需要參與計算的資料都放到這個Input結構中，傳入surf函數使用；SurfaceOutput是已經定義好了裡面類型輸出結構，但是一開始的時候内容暫時是空白的，我們需要向裡面填寫輸出，這樣就可以完成着色了。先仔細看看INPUT吧，現在可以跳回來看上面定義的INPUT結構體了：

struct Input {
    float2 uv_MainTex;
};      

作為輸入的結構體必須命名為Input，這個結構體中定義了一個float2的變量，表示浮點數的float後面緊跟一個數字2，float和vec都可以在之後加入一個2到4的數字，來表示被打包在一起的2到4個同類型數。比如下面的這些定義：

//Define a 2d vector variable
vec2 coordinate;
//Define a color variable
float4 color;
//Multiply out a color
float3 multipliedColor = color.rgb * coordinate.x;      

在通路這些值時，我們即可以隻使用名稱來獲得整組值，也可以使用下标的方式（比如.xyzw，.rgba或它們的部分比如.x等等）來獲得某個值。

在這個例子裡，我們聲明了一個叫做

uv_MainTex

的包含兩個浮點數的變量。

如果你對3D開發稍有耳聞的話，一定不會對uv這兩個字母感到陌生。UV mapping的作用是将一個2D貼圖上的點按照一定規則映射到3D模型上，是3D渲染中最常見的一種頂點處理手段。在CG程式中，我們有這樣的約定，在一個貼圖變量（在我們例子中是

_MainTex

）之前加上uv兩個字母，就代表提取它的uv值（其實就是兩個代表貼圖上點的二維坐标 ）。我們之後就可以在surf程式中直接通過通路uv_MainTex來取得這張貼圖目前需要計算的點的坐标值了。

回到surf函數，它的兩有參數，第一個是Input：在計算輸出時Shader會多次調用surf函數，每次給入一個貼圖上的點坐标，來計算輸出。第二個參數是一個可寫的SurfaceOutput，SurfaceOutput是預定義的輸出結構，我們的surf函數的目标就是根據輸入把這個輸出結構填上。SurfaceOutput結構體的定義如下

struct SurfaceOutput {
    half3 Albedo;     //像素的顔色
    half3 Normal;     //像素的法向值
    half3 Emission;   //像素的發散顔色
    half Specular;    //像素的鏡面高光
    half Gloss;       //像素的發光強度
    half Alpha;       //像素的透明度
};      

這裡的half和我們常見float與double類似，都表示浮點數，隻不過精度不一樣。也許你很熟悉單精度浮點數（float或者single）和雙精度浮點數（double），這裡的half指的是半精度浮點數，精度最低，運算性能相對比高精度浮點數高一些，是以被大量使用。

在例子中，我們做的事情非常簡單：

half4 c = tex2D (_MainTex, IN.uv_MainTex);
o.Albedo = c.rgb;
o.Alpha = c.a;      

這裡用到了一個

tex2d

函數，這是CG程式中用來在一張貼圖中對一個點進行采樣的方法，傳回一個float4。這裡對_MainTex在輸入點上進行了采樣，并将其顔色的rbg值賦予了輸出的像素顔色，将a值賦予透明度。于是，着色器就明白了應當怎樣工作：即找到貼圖上對應的uv點，直接使用顔色資訊來進行着色。

接下來…

我想現在你已經能讀懂一些最簡單的Shader了，接下來我推薦的是參考Unity的Surface Shader Examples多接觸一些各種各樣的基本Shader。

原文連結