天天看點
傳回

實戰以太坊智能合約測試【Truffle】

Truffle開發架構提供了以太坊智能合約測試的兩種方法：區塊鍊級别的Solidity測試和DApp級别的JavaScript測試。在這個教程中，我們将介紹這兩種以太坊智能合約測試方法的用途、差別與應用場景，并通過一個具體的示例來學習如何綜合利用Solitiy測試用例和JavaScript測試用例對以太坊智能

合約進行單元測試和內建測試。

七種開發語言的以太坊教程： Java | Php Python .Net / C# Golang Node.JS Flutter / Dart

1、以太坊智能合約測試概述

作為軟體開發者，我們都知道要讓代碼正常運作，測試是非常重要的一個環節。基于區塊鍊的去中心化軟體也不例外，而且由于區塊鍊的不可修改特性，測試對于區塊鍊軟體來說就更重要了。

總體上來說有兩種類型的軟體測試：單元測試和內建測試。單元測試聚焦于單個函數的測試，而內建測試的目标則是確定各部分代碼組合起來也可以按期望的方式運作。

Truffle是應用最廣的以太坊智能合約與DApp開發架構，它提供了兩種用于測試以太坊智能合約的方法：Solidity測試和JavaScript測試。問題是，我們應該選擇哪一種方法？

答案是都需要。

實戰以太坊智能合約測試【Truffle】

用Solidity編寫智能合約的測試用例讓我們可以在區塊鍊層級進行測試。這種測試用例可以調用合約方法，就像用例部署在區塊鍊裡一樣。為了測試智能合約的内部行為，我們可以：

  • 編寫Solidity單元測試來檢查智能合約函數的傳回值以及狀态變量的值
  • 編寫Solidity內建測試來檢查智能合約之間的互動。這些內建測試可以確定像繼承或者 依賴注入這樣的機制的運作符合預期

我們也需要確定智能合約能夠表現出正确的外部行為。為了從區塊鍊外部測試智能合約，我們在JavaScript測試用例中使用web3.js，就像在開發DApp時一樣。我們需要對DApp前端可以正确調用智能合約建立信心。這方面的測試屬于內建測試。

是以，簡單地說，Solidity測試用例主要用于智能合約内部實作邏輯的驗證，可以用于單元測試和內建測試；而JavaScript用例則主要用于智能合約外部行為的驗證，通常用于內建測試。

2、以太坊智能合約測試的示例項目

假設我們有兩個以太坊智能合約需要測試：Background和Entrypoint。

Background是一個内部合約，我們的DApp前端不會直接和它互動。EntryPoint則是專門供DApp互動的智能合約，在EntryPoint合約内部會通路Background合約。

下面是Background合約的solidity代碼：

pragma solidity >=0.5.0;

contract Background {
    uint[] private values;

    function storeValue(uint value) public {
        values.push(value);
    }

    function getValue(uint initial) public view returns(uint) {
        return values[initial];
    }

    function getNumberOfValues() public view returns(uint) {
        return values.length;
    }
}

在上面，我們看到Background合約提供了三個函數：

  • storeValue(uint)：寫入值
  • getValue(uint) ：讀取值
  • getNumberOfValues()：擷取值的數量

這三個合約函數都很簡單，是以也很容易進行單元測試。

下面是EntryPoint合約的Solidity代碼：

pragma solidity >=0.5.0;

import "./Background.sol";

contract EntryPoint {
    address public backgroundAddress;

    constructor(address _background) public{
        backgroundAddress = _background;
    }

    function getBackgroundAddress() public view returns (address) {
        return backgroundAddress;
    }

    function storeTwoValues(uint first, uint second) public {
        Background(backgroundAddress).storeValue(first);
        Background(backgroundAddress).storeValue(second);
    }

    function getNumberOfValues() public view returns (uint) {
        return Background(backgroundAddress).getNumberOfValues();
    }
}

在EntryPoint合約的構造函數中，我們注入了Background合約的部署位址，并将其存入一個狀态變量backgroundAddress。EntryPoint合約暴露出三個函數：

  • getBackgroundAddress()：傳回Background合約的部署位址
  • storeTwoValues(uint, uint)：儲存兩個值
  • getNumberOfValues()：傳回值的數量

由于storeTwoValues(uint, uint)函數兩次調用Background合約中的一個函數，是以對這個函數進行單元測試比較困難。getNumberOfValues()也有同樣的問題，是以這兩個函數更适合進行內建測試。

3、以太坊智能合約測試的Solidity用例

在這一部分，我們學習如何為智能合約編寫Solidity單元測試用例和內建測試用例。讓我們先從簡單一點的單元測試開始。

下面是TestBackground測試的代碼：

pragma solidity >=0.5.0;

import "truffle/Assert.sol";
import "truffle/DeployedAddresses.sol";
import "../../../contracts/Background.sol";

contract TestBackground {

    Background public background;

    // Run before every test function
    function beforeEach() public {
        background = new Background();
    }

    // Test that it stores a value correctly
    function testItStoresAValue() public {
        uint value = 5;
        background.storeValue(value);
        uint result = background.getValue(0);
        Assert.equal(result, value, "It should store the correct value");
    }

    // Test that it gets the correct number of values
    function testItGetsCorrectNumberOfValues() public {
        background.storeValue(99);
        uint newSize = background.getNumberOfValues();
        Assert.equal(newSize, 1, "It should increase the size");
    }

    // Test that it stores multiple values correctly
    function testItStoresMultipleValues() public {
        for (uint8 i = 0; i < 10; i++) {
            uint value = i;
            background.storeValue(value);
            uint result = background.getValue(i);
            Assert.equal(result, value, "It should store the correct value for multiple values");
        }
    }
}

這個單元測試的目的是確定Background合約可以：

  • 在values數組中儲存新的值
  • 按索引傳回values
  • 在values數組中儲存多個值
  • 傳回values數組的大小

下面的TestEntryPoint測試中包含了一個單元測試testItHasCorrectBackground() 用于驗證EntryPoint合約的功能符合預期：

pragma solidity >=0.5.0;

import "truffle/Assert.sol";
import "truffle/DeployedAddresses.sol";
import "../../../contracts/Background.sol";
import "../../../contracts/EntryPoint.sol";

contract TestEntryPoint {

    // Ensure that dependency injection working correctly
    function testItHasCorrectBackground() public {
        Background backgroundTest = new Background();
        EntryPoint entryPoint = new EntryPoint(address(backgroundTest));
        address expected = address(backgroundTest);
        address target = entryPoint.getBackgroundAddress();
        Assert.equal(target, expected, "It should set the correct background");
    }

}

這個函數對依賴注入進行測試。如前所述，EntryPoint合約中的其他函數需要與Background合約互動，是以我們沒有辦法單獨測試這些函數，需要在內建測試中進行驗證。下面是內建測試的代碼：

pragma solidity >=0.5.0;

import "truffle/Assert.sol";
import "truffle/DeployedAddresses.sol";
import "../../../contracts/Background.sol";
import "../../../contracts/EntryPoint.sol";

contract TestIntegrationEntryPoint {

    BackgroundTest public backgroundTest;
    EntryPoint public entryPoint;

    // Run before every test function
    function beforeEach() public {
        backgroundTest = new BackgroundTest();
        entryPoint = new EntryPoint(address(backgroundTest));
    }

    // Check that storeTwoValues() works correctly.
    // EntryPoint contract should call background.storeValue()
    // so we use our mock extension BackgroundTest contract to
    // check that the integration workds
    function testItStoresTwoValues() public {
        uint value1 = 5;
        uint value2 = 20;
        entryPoint.storeTwoValues(value1, value2);
        uint result1 = backgroundTest.values(0);
        uint result2 = backgroundTest.values(1);
        Assert.equal(result1, value1, "Value 1 should be correct");
        Assert.equal(result2, value2, "Value 2 should be correct");
    }

    // Check that entry point calls our mock extension correctly
    // indicating that the integration between contracts is working
    function testItCallsGetNumberOfValuesFromBackground() public {
        uint result = entryPoint.getNumberOfValues();
        Assert.equal(result, 999, "It should call getNumberOfValues");
    }
}

// Extended from Background because values is private in actual Background
// but we're not testing background in this unit test
contract BackgroundTest is Background {
    uint[] public values;

    function storeValue(uint value) public {
        values.push(value);
    }

    function getNumberOfValues() public view returns(uint) {
        return 999;
    }
}

我們可以看到TestIntegrationEntryPoint使用了一個Background的擴充，即定義在第43行的BackgroundTest，以其作為我們的模拟合約，這可以讓我們的測試用例檢查EntryPoint是否調用了部署在backgroundAddress位址處的合約的正确的函數。

4、以太坊智能合約測試的JavaScript用例

我們用JavaScript編寫內建測試來確定合約的外部行為滿足預期要求，這樣我們就有資訊基于這些智能合約開發DApp了。

下面是我們的JavaScript測試檔案entryPoint.test.js：

const EntryPoint = artifacts.require("./EntryPoint.sol");

require('chai')
    .use(require('chai-as-promised'))
    .should();

contract("EntryPoint", accounts => {
    describe("Storing Values", () => {
        it("Stores correctly", async () => {
            const entryPoint = await EntryPoint.deployed();

            let numberOfValues = await entryPoint.getNumberOfValues();
            numberOfValues.toString().should.equal("0");

            await entryPoint.storeTwoValues(2,4);
            numberOfValues = await entryPoint.getNumberOfValues();
            numberOfValues.toString().should.equal("2");
        });
    });
});

使用EntryPoint合約中的函數，JavaScript測試可以確定我們可以将區塊鍊外部的值利用交易傳入智能合約，這是通過調用合約的storeTwoValues(uint,uint)函數（第15行）實作的。

5、以太坊智能合約測試教程小節

當談到智能合約的測試時，可以說越多越好，應當盡可能覆寫所有可能的執行路徑都傳回預期的結果。Truffle提供了兩種辦法：區塊鍊層的Solidity單元測試和內建測試，以及DApp級别的JavaScript內建測試，我們在實際的工作中需要根據智能合約的代碼實作綜合運用這兩種測試方法來保證智能合約的運作符合預期。

原文連結：

以太坊智能合約測試的兩種方法 — 彙智網
開發架構 Dart 前端開發 javascript java 測試技術 go 區塊鍊 c# Python java檢索 java企業技術選型開發 linux java調用slf4j sort使用java java使用start
上一篇: 敲黑闆：純技術分享阿裡雲RPA機器人的一天
下一篇: 區塊鍊如何在新冠病毒危機中為醫療供應鍊纾困？

繼續閱讀